Operar con noticias de manera sencilla (Parte 1): Creando una base de datos
190
0
Introducción
En este artículo aprenderemos a crear una base de datos en la que almacenaremos los datos del calendario económico de MQL5. Estos datos pueden utilizarse más tarde, en próximos artículos, para negociar en las noticias. También exploraremos cómo ejecutar consultas SQL básicas para recuperar cierta información organizada de esta base de datos. Todo el proceso se realizará en el IDE de MQL5.
Los operadores siguen de cerca las fuentes de noticias en busca de información que pueda afectar a los mercados. Esto incluye acontecimientos geopolíticos, anuncios de beneficios empresariales, acontecimientos políticos e informes económicos como el crecimiento del PIB o las cifras de empleo. Los operadores actúan con rapidez para responder a las noticias importantes y beneficiarse de los cambios resultantes en el mercado. Dependiendo de cómo se interpreten las noticias, puede ser necesario comprar o vender activos. En este artículo nos centraremos en los eventos económicos, ya que los tenemos fácilmente disponibles a través del Calendario económico de MQL5.
¿Por qué crear una base de datos?
Una base de datos es una colección estructurada de datos que se almacena electrónicamente y a la que se puede acceder. Las bases de datos pueden gestionar y almacenar grandes cantidades de datos de forma eficaz, lo que permite realizar diversas actividades como el análisis, el almacenamiento y la gestión de datos. En MQL5, trabajamos con bases de datos SQLite que son creadas y gestionadas por el motor de bases de datos SQLite. Las bases de datos SQLite pueden tener cualquier extensión de archivo, pero normalmente son archivos de disco único con extensiones .sqlite, .sqlite3 o .db. Estos archivos contienen todos los datos y la estructura presentes en las bases de datos, incluyendo tablas, desencadenadores, índices y otros metadatos.
Las bases de datos son perfectas para manejar grandes conjuntos de datos y simplifican el proceso de recuperación de datos a partir de una fecha o evento concretos, sin necesidad de bucles complejos. Además, el calendario económico de MQL5 es inaccesible en el probador de estrategias. Así que, si quieres probar tu estrategia basándote en las noticias, ¿cómo lo harías?
La respuesta es usar una base de datos. Para más información sobre bases de datos, consulta estas diapositivas de clase y, preferiblemente, este artículo de MQL5. Además, añadiré un excelente tutorial de SQLite.
Divisas en el calendario económico de MQL5
| N.º | Símbolo | Nombre |
|---|---|---|
| 1. | NZD | Dólar neozelandés |
| 2. | EUR | Euro |
| 3. | JPY | Yen japonés |
| 4. | CAD | Dólar canadiense |
| 5. | AUD | Dólar australiano |
| 6. | CNY | Yuan chino |
| 7. | SGD | Dólar singapurense |
| 8. | BRL | Real brasileño |
| 9. | MXN | Peso mexicano |
| 10. | ZAR | Rand sudafricano |
| 11. | HKD | Dólar hongkonés |
| 12. | INR | Rupia india |
| 13. | NOK | Corona noruega |
| 14. | USD | Dólar estadounidense |
| 15. | GBP | Libra esterlina |
| 16. | CHF | Franco suizo |
| 17. | KRW | Won surcoreano |
| 18. | SEK | Corona sueca |
La tabla anterior no sigue ningún orden en particular.
Hay varias monedas disponibles en el calendario de MQL5, pero algunas de ellas no son de uso común por los corredores o de fácil acceso para los comerciantes. Por ejemplo, el real brasileño y el won surcoreano no están muy extendidos. Incluso si consigue encontrar un corredor que opere con estas divisas exóticas, los diferenciales suelen ser desfavorables para la negociación. Hablo por experiencia propia.
Creación de la base de datos
Antes de crear la base de datos, debemos tener en cuenta el horario de verano y por qué afectaría a nuestro back-testing. El horario de verano (DST) es la práctica de adelantar el reloj una hora durante los meses más cálidos del año, normalmente de primavera a otoño, para aprovechar mejor la luz del día y conservar energía.
En las zonas donde se aplica el horario de verano, la hora local puede cambiar una hora durante los periodos de transición de primavera y otoño. Esto puede influir en las horas de apertura y cierre de los mercados financieros. Por ejemplo, si comienza el horario de verano y los relojes se adelantan una hora, el mercado puede abrir antes en la hora local. Por el contrario, cuando finaliza el horario de verano y los relojes se retrasan una hora (hora normal), la hora de apertura del mercado puede aparecer más tarde en la hora local. También hay que tener en cuenta que las distintas regiones del mundo podrían tener su propio horario de verano para adaptarse a sus propias estaciones.
Por ejemplo, EE.UU. tiene su propio horario de verano, que suele comenzar el segundo domingo de marzo de cada año y terminar el primer domingo de noviembre del mismo año. Los países europeos también son conocidos por tener su propio DST que suele comenzar el último domingo de marzo de cada año y termina el último domingo de octubre del mismo año. Australia es otro país conocido por practicar también el DST, su horario suele comenzar el primer domingo de octubre y terminar el primer domingo de abril del año siguiente.
Para tener en cuenta los ajustes del horario de verano, algunas bolsas y mercados financieros pueden modificar sus horarios de negociación o su huso horario. Las bolsas pueden publicar horarios de negociación revisados para tener en cuenta los cambios de hora locales o ajustar su zona horaria según el horario DST que practiquen, garantizando a los participantes en el mercado uniformidad y claridad.
Por lo que he observado si un broker por ejemplo practica el DST de EEUU la zona horaria antes del DST para ilustración sería GMT+2, entonces cuando el DST de EEUU empiece la zona horaria cambiará a GMT+3. No notará la diferencia horaria entre los comunicados de prensa de EE.UU. en el servidor del corredor antes o durante el horario de verano de EE.UU., ya que estarán sincronizados entre sí. Digamos que las NFP se publican a las 14:00 horas en el servidor del corredor antes del horario de verano de EE.UU. La hora seguirá siendo la misma a las 14:00 horas durante el horario de verano de EE.UU. aunque la zona horaria haya cambiado a GMT+3.
Por otro lado, si el comunicado de prensa sobre el empleo en el Reino Unido se produce a las 8 de la mañana antes de que comience el horario de verano en el Reino Unido y en los Estados Unidos, cuando el corredor cambia la zona horaria al comenzar el horario de verano en los Estados Unidos, y el comunicado de prensa sobre el empleo en el Reino Unido se produce antes de que comience el horario de verano en el Reino Unido (UE), el comunicado de prensa sobre el empleo en el Reino Unido se produciría a las 7 de la mañana en el horario del corredor. Cuando comience el horario de verano en el Reino Unido y coincida con el horario de verano en Estados Unidos, las noticias sobre empleo en el Reino Unido volverán a publicarse a las 8 de la mañana.
Sé que todo esto es muy confuso, por suerte para nosotros lo implementaremos en nuestra base de datos para tener fechas exactas de cuándo ocurren los eventos para hacer pruebas retrospectivas más adelante. Tendremos que determinar si el corredor utiliza el horario de verano (DST) de EE.UU., Reino Unido (UE), Australia o si no utiliza el horario de verano en absoluto. También crearemos tablas del calendario económico para cada tipo de horario de verano (DST) para que podamos cambiar el horario al realizar pruebas retrospectivas con fines educativos.
Implementación
Tendremos tres clases de DaylightSavings:
- DaylightSavings_AU
- DaylightSavings_UK
- DaylightSavings_US
class CDaylightSavings_AU:CObject { private: CTimeManagement Time; CDaylightSavings_AU(datetime startdate,datetime enddate); CObject *List() { return savings;}//Gets the list of Daylight savings time datetime StartDate; datetime EndDate; CArrayObj *savings; CArrayObj *getSavings; CDaylightSavings_AU *dayLight; public: CDaylightSavings_AU(void); ~CDaylightSavings_AU(void); bool isDaylightSavings(datetime Date);//This function checks if a given date falls within Daylight Savings Time. bool DaylightSavings(int Year,datetime &startDate,datetime &endDate);//Check if Daylight Savings Dates are available for a certain Year void adjustDaylightSavings(datetime EventDate,string &AdjustedDate);//Will adjust the date's time zone depending on Daylight Savings };
Crearemos una clase llamada:
CDaylightSavings_AU
Que hereda de:
CObject
Esta clase consistirá en crear una lista que almacenará todas las fechas de horario de verano a partir de 2007 ya que es la fecha más antigua almacenada en el calendario económico de MQL5.
CDaylightSavings_AU::CDaylightSavings_AU(void) { savings = new CArrayObj(); //Daylight savings dates to readjust dates in the database for accurate testing in the strategy tester savings.Add(new CDaylightSavings_AU(D'2006.10.29 03:00:00',D'2007.03.25 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2007.10.28 03:00:00',D'2008.04.06 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2008.10.05 03:00:00',D'2009.04.05 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2009.10.04 03:00:00',D'2010.04.04 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2010.10.03 03:00:00',D'2011.04.03 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2011.10.02 03:00:00',D'2012.04.01 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2012.10.07 03:00:00',D'2013.04.07 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2013.10.06 03:00:00',D'2014.04.06 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2014.10.05 03:00:00',D'2015.04.05 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2015.10.04 03:00:00',D'2016.04.03 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2016.10.02 03:00:00',D'2017.04.02 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2017.10.01 03:00:00',D'2018.04.01 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2018.10.07 03:00:00',D'2019.04.07 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2019.10.06 03:00:00',D'2020.04.05 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2020.10.04 03:00:00',D'2021.04.04 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2021.10.03 03:00:00',D'2022.04.03 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2022.10.02 03:00:00',D'2023.04.02 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2023.10.01 03:00:00',D'2024.04.07 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2024.10.06 03:00:00',D'2025.04.06 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2025.10.05 03:00:00',D'2026.04.05 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2026.10.04 03:00:00',D'2027.04.04 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2027.10.03 03:00:00',D'2028.04.02 02:00:00')); savings.Add(new CDaylightSavings_AU(D'2028.10.01 03:00:00',D'2029.04.01 02:00:00')); }
Utilizaremos la función booleana:
bool isDaylightSavings(datetime Date);//This function checks if a given date falls within Daylight Savings Time.
Para determinar si un parámetro de fecha está dentro de las fechas del horario de verano.
bool CDaylightSavings_AU::isDaylightSavings(datetime Date) { // Initialize a list to store daylight savings periods. getSavings = List(); // Iterate through all the periods in the list. for(int i=0; i<getSavings.Total(); i++) { // Access the current daylight savings period. dayLight = getSavings.At(i); // Check if the given date is within the current daylight savings period. if(Time.DateIsInRange(dayLight.StartDate,dayLight.EndDate,Date)) { // If yes, return true indicating it is daylight savings time. return true; } } // If no period matches, return false indicating it is not daylight savings time. return false; }
También haremos uso de otra función booleana.
bool DaylightSavings(int Year,datetime &startDate,datetime &endDate);//Adjusts time when it is daylight savings an hour behind if outside
Para determinar si el año se encuentra dentro de la lista de fechas de horario de verano que inicializamos previamente, agregaremos la fecha de inicio y la fecha de finalización a las variables startDate y endDate.
bool CDaylightSavings_US::DaylightSavings(int Year,datetime &startDate,datetime &endDate) { // Initialize a list to store daylight savings periods. getSavings = List(); bool startDateDetected=false,endDateDetected=false; // Iterate through all the periods in the list. for(int i=0; i<getSavings.Total(); i++) { dayLight = getSavings.At(i); if(Year==Time.ReturnYear(dayLight.StartDate))//Check if a certain year's date is available within the Daylight Savings start dates in the List { startDate = dayLight.StartDate; startDateDetected = true; } if(Year==Time.ReturnYear(dayLight.EndDate))//Check if a certain year's date is available within the Daylight Savings end dates in the List { endDate = dayLight.EndDate; endDateDetected = true; } if(startDateDetected&&endDateDetected)//Check if both Daylight Savings start and end dates are found for a certain Year { return true; } } startDate = D'1970.01.01 00:00:00';//Set a default start date if no Daylight Saving date is found endDate = D'1970.01.01 00:00:00';//Set a default end date if no Daylight Saving date is found return false; }
Nuestra última función pública en esta clase:
void adjustDaylightSavings(datetime EventDate,string &AdjustedDate);//Will adjust the date's time -zone depending on Daylight Savings
Modificaremos una variable de tipo string llamada 'AdjustedDate' por referencia con la 'EventDate'.
void CDaylightSavings_AU::adjustDaylightSavings(datetime EventDate,string &AdjustedDate) { if(isDaylightSavings(TimeTradeServer()))//Check if the current trade server time is already within the Daylight Savings Period { if(isDaylightSavings(EventDate))//Checks if the event time is during daylight savings { AdjustedDate = TimeToString(EventDate);//storing normal event time } else { AdjustedDate = TimeToString((datetime)(EventDate-Time.HoursS()));//storing event time and removing an hour for DST } } else { if(isDaylightSavings(EventDate))//Checks if the event time is during daylight savings { AdjustedDate = TimeToString((datetime)(Time.HoursS()+EventDate));//storing event time and adding an hour for DST } else { AdjustedDate = TimeToString(EventDate);//storing normal event time } } }
Ahora pasaremos a nuestro próximo archivo de encabezado en este proyecto, dedicado a las manipulaciones de tiempo.
CTimeManagement
El cual es una clase en el mismo proyecto.
class CTimeManagement { private: MqlDateTime today;//private variable MqlDateTime timeFormat;//private variable public: bool DateIsInRange(datetime FirstTime,datetime SecondTime,datetime compareTime);//Checks if a date is within two other dates bool DateIsInRange(datetime Start,datetime End,datetime CompareStart,datetime CompareEnd);//Check if two dates(Start&End) are within CompareStart & CompareEnd bool DateisToday(datetime TimeRepresented);//Checks if a date is within the current day int SecondsS(int multiple=1);//Returns seconds int MinutesS(int multiple=1);//Returns Minutes in seconds int HoursS(int multiple=1);//Returns Hours in seconds int DaysS(int multiple=1);//Returns Days in seconds int WeeksS(int multiple=1);//Returns Weeks in seconds int MonthsS(int multiple=1);//Returns Months in seconds int YearsS(int multiple=1);//Returns Years in seconds int ReturnYear(datetime time);//Returns the Year for a specific date datetime TimeMinusOffset(datetime standardtime,int timeoffset);//Will return a datetime type of a date with an subtraction offset in seconds datetime TimePlusOffset(datetime standardtime,int timeoffset);//Will return a datetime type of a date with an addition offset in seconds };
La función llamada anteriormente:
Time.DateIsInRange(dayLight.StartDate,dayLight.EndDate,Date)
Es una función sencilla que comprueba si una fecha está comprendida entre otras dos.
bool CTimeManagement::DateIsInRange(datetime FirstTime,datetime SecondTime,datetime compareTime) { if(FirstTime<=compareTime&&SecondTime>compareTime) { return true; } return false; }
El mismo nombre de función con diferentes parámetros.
bool DateIsInRange(datetime Start,datetime End,datetime CompareStart,datetime CompareEnd);
Es igualmente simple, esta función comprobará si dos fechas están entre otras dos fechas.
bool CTimeManagement::DateIsInRange(datetime Start,datetime End,datetime CompareStart,datetime CompareEnd) { if(Start<=CompareStart&&CompareEnd<End) { return true; } return false; }
Necesitaremos una función para saber si una determinada fecha es hoy, por eso he declarado:
bool DateisToday(datetime TimeRepresented);//Checks if a date is within the current day
La cual comparará el año, mes y día de la hora actual con el objeto datetime 'TimeRepresented'.
bool CTimeManagement::DateisToday(datetime TimeRepresented) { MqlDateTime TiM; TimeToStruct(TimeRepresented,TiM); TimeCurrent(today); if(TiM.year==today.year&&TiM.mon==today.mon&&TiM.day==today.day) { return true; } return false; }
Para obtener una fecha y hora con un desfase tenemos dos funciones:
datetime TimeMinusOffset(datetime standardtime,int timeoffset);//Will return a datetime type of a date with an subtraction offset in seconds
Y:
datetime TimePlusOffset(datetime standardtime,int timeoffset);//Will return a datetime type of a date with an addition offset in seconds
Cuando queramos obtener una fecha con un desfase negativo de una hora (o de cualquier unidad de tiempo) utilizaremos:
datetime CTimeManagement::TimeMinusOffset(datetime standardtime,int timeoffset) { standardtime-=timeoffset; return standardtime; }
Por otro lado si queremos una fecha con un desfase positivo utilizaremos:
datetime CTimeManagement::TimePlusOffset(datetime standardtime,int timeoffset) { standardtime+=timeoffset; return standardtime; }
Decidí crear un archivo de inclusión que almacenará variables y estructuras globales, así como tipos de enumeración en el futuro, para ser utilizados en diferentes clases y en el experto.
Este archivo de inclusión se llama CommonVariables y almacenará variables comunes.
string broker=AccountInfoString(ACCOUNT_COMPANY);//Getting brokers name via AccountInfoString int Str = StringReplace(broker," ","");//Removing or replacing any spaces in the broker's name with an empty string int Str1 = StringReplace(broker,".","");//Removing or replacing any dots in the broker's name with an empty string int Str2 = StringReplace(broker,",","");//Removing or replacing any commas in the broker's name with an empty string #define BROKER_NAME broker//Broker's Name #define NEWS_TRADING_FOLDER "NewsTrading"//Name of main folder in common/files #define NEWS_CALENDAR_FOLDER StringFormat("%s\\NewsCalendar",NEWS_TRADING_FOLDER)//name of subfolder in NewsTrading #define NEWS_CALENDAR_BROKER_FOLDER StringFormat("%s\\%s",NEWS_CALENDAR_FOLDER,BROKER_NAME)//Name of subfolder in NewsCalendar #define NEWS_DATABASE_FILE StringFormat("%s\\Calendar.sqlite",NEWS_CALENDAR_BROKER_FOLDER)//Name of sqlite file in subfolder in "Broker's Name" #define NEWS_TEXT_FILE StringFormat("%s\\CalendarOpen.txt",NEWS_CALENDAR_BROKER_FOLDER)//Name of text file to indicate Calendar is open. struct Calendar { ulong EventId;//Event Id string CountryName;//Event Country string EventName;//Event Name string EventType;//Event Type string EventImportance;//Event Importance string EventDate;//Event Date string EventCurrency;//Event Currency string EventCode;//Event Code string EventSector;//Event Sector string EventForecast;//Event Forecast Value string EventPreval;//Event Previous Value string EventImpact;//Event Impact string EventFrequency;//Event Frequency }; enum DST_type { US_DST,//US Daylight Savings UK_DST,//UK(EU) Daylight Savings AU_DST,//AU Daylight Savings DST_NONE//No Daylight Savings Available };
Cuando creamos archivos en la carpeta 'Common files', me gustaría organizarlos en subcarpetas para que sea más fácil navegar y coordinar el contenido dentro de dicha carpeta.
Así que he creado una clase:
class CFolders Lo cual creará las carpetas en la carpeta "Common files" en la siguiente secuencia: NewsTrading/NewsCalendar/Broker. Haremos que el constructor de la clase realice esta tarea.
class CFolders { private: bool CreateFolder(string FolderPath);//Will create a folder with the FolderPath string parameter public: CFolders(void);//Class's constructor };
Dentro del constructor:
CFolders::CFolders(void) { if(CreateFolder(NEWS_TRADING_FOLDER))//Will create the NewsTrading Folder { if(CreateFolder(NEWS_CALENDAR_FOLDER))//Will create the NewsCalendar Folder { if(!CreateFolder(NEWS_CALENDAR_BROKER_FOLDER))//Will create the Broker Folder { Print("Something went wrong with creating folder: ",NEWS_CALENDAR_BROKER_FOLDER); } } } }
Función que se llama en el constructor para crear las carpetas individuales:
bool CFolders::CreateFolder(string FolderPath) { //--- attempt to create a folder relative to the MQL5\Files path if(FolderCreate(FolderPath,FILE_COMMON)) { //--- successful execution return true; } else { PrintFormat("Failed to create the folder %s. Error code %d",FolderPath,GetLastError()); } //--- execution failed return false; }
Las velas son muy importantes, tendremos que recopilar información sobre los precios máximos, mínimos, de apertura y cierre de una vela en particular. Para ello crearemos otra clase que nos recoja esta información cuando la necesitemos en cualquier otro programa del proyecto. El nombre de las clases será:
class CCandleProperties Ahora declararemos las funciones de esta clase.
class CCandleProperties { private: CTimeManagement Time; public: double Open(int CandleIndex,ENUM_TIMEFRAMES Period=PERIOD_CURRENT,string SYMBOL=NULL);//Retrieve Candle OpenPrice double Close(int CandleIndex,ENUM_TIMEFRAMES Period=PERIOD_CURRENT,string SYMBOL=NULL);//Retrieve Candle ClosePrice double High(int CandleIndex,ENUM_TIMEFRAMES Period=PERIOD_CURRENT,string SYMBOL=NULL);//Retrieve Candle HighPrice double Low(int CandleIndex,ENUM_TIMEFRAMES Period=PERIOD_CURRENT,string SYMBOL=NULL);//Retrieve Candle LowPrice bool IsLargerThanPreviousAndNext(datetime CandleTime,int Offset,string SYMBOL);//Determine if one candle is larger than two others };
Vamos a echar un vistazo rápido a:
double Open(int CandleIndex,ENUM_TIMEFRAMES Period=PERIOD_CURRENT,string SYMBOL=NULL);//Retrieve Candle Open Price
En esta función, devolveremos el precio de apertura de una vela basado en el parámetro entero `CandleIndex`, el marco de tiempo de la vela, así como el símbolo de la vela.
double CCandleProperties::Open(int CandleIndex,ENUM_TIMEFRAMES Period=PERIOD_CURRENT,string SYMBOL=NULL) { return iOpen(((SYMBOL==NULL)?Symbol():SYMBOL),Period,CandleIndex);//return candle open price }
Para verificar si un evento económico ocurrió en una fecha específica, dado que los corredores pueden cambiar sus zonas horarias. Obtenemos la fecha de un evento económico y, con esta fecha, examinamos la vela M15 para ese momento, luego calculamos la altura de la vela (`iHigh - iLow`) y comparamos esta altura con la vela M15 una hora antes del evento y una hora después. Dado que los acontecimientos económicos son normalmente muy volátiles en los precios del mercado, deberíamos notar una vela muy larga cuando el acontecimiento se produce. Utilizaremos la vela M15, para probablemente dar al mercado tiempo suficiente para formar esta vela larga. Si el broker cambió su zona horaria, la fecha del evento almacenada en el calendario económico de MQL5 puede no coincidir con la volatilidad de la vela en el momento específico de la vela del broker, pero esta volatilidad puede estar presente una hora más tarde o una hora antes de la fecha especificada. La función que utilizaremos para realizar esta comprobación de validación será:
bool IsLargerThanPreviousAndNext(datetime CandleTime,int Offset,string SYMBOL);//Determine if one candle is larger than two others
Esta función comprobará si la altura de la vela en una fecha específica es mayor que la vela con un desfase temporal anterior y posterior a esta fecha especificada.
bool CCandleProperties::IsLargerThanPreviousAndNext(datetime CandleTime,int Offset,string SYMBOL) { int CandleIndex = iBarShift(SYMBOL,PERIOD_M15,CandleTime);//Assign candle index of candletime int CandleIndexMinusOffset = iBarShift(SYMBOL,PERIOD_M15,Time.TimeMinusOffset(CandleTime,Offset));//Assign candle index of candletime minus time offset int CandleIndexPlusOffset = iBarShift(SYMBOL,PERIOD_M15,Time.TimePlusOffset(CandleTime,Offset));//Assign candle index of candletime plus time offset double CandleHeight = High(CandleIndex,PERIOD_M15,SYMBOL)-Low(CandleIndex,PERIOD_M15,SYMBOL);//Assign height of M15 candletime in pips double CandleHeightMinusOffset = High(CandleIndexMinusOffset,PERIOD_M15,SYMBOL)-Low(CandleIndexMinusOffset,PERIOD_M15,SYMBOL);//Assign height of M15 candletime minus offset in Pips double CandleHeightPlusOffset = High(CandleIndexPlusOffset,PERIOD_M15,SYMBOL)-Low(CandleIndexPlusOffset,PERIOD_M15,SYMBOL);//Assign height of M15 candletime plus offset in Pips //--Determine if candletime height is greater than candletime height minus offset and candletime height plus offset if(CandleHeight>CandleHeightMinusOffset&&CandleHeight>CandleHeightPlusOffset) { return true;//Candletime is likely when the news event occurred } return false;//Candletime is unlikely when the real news data was released }
Pasaremos a la clase 'News' (Noticias). Esta clase trabajará directamente con la obtención de valores del calendario económico MQL5.
Esto almacenará los valores en una base de datos para pruebas y, eventualmente, para operaciones de trading.
class CNews { //Private Declarations Only accessible by this class/header file private: CTimeManagement Time;//TimeManagement Object declaration CDaylightSavings_UK Savings_UK;//DaylightSavings Object for the UK and EU CDaylightSavings_US Savings_US;//DaylightSavings Object for the US CDaylightSavings_AU Savings_AU;//DaylightSavings Object for the AU CCandleProperties Candle;//CandleProperties Object string CurrencyBase,CurrencyProfit,EURUSD;//String variables declarations for working with EURUSD bool EurusdIsSelected,EurusdIsFound,is_Custom;//Boolean variables declarations for working with EURUSD bool timeIsShifted;//Boolean variable declaration will be used to determine if the broker changes it's time zone datetime DaylightStart,DaylightEnd;//Datetime variables declarations for start and end dates for Daylight Savings //Structure Declaration for DST struct DST { bool result; datetime date; }; bool AutoDetectDST(DST_type &dstType);//Function will determine Broker DST DST_type DSTType;//variable of DST_type enumeration declared in the CommonVariables class/header file bool InsertIntoTable(int db,DST_type Type,Calendar &Evalues[]);//Function for inserting Economic Data in to a database's table void CreateAutoDST(int db);//Function for creating and inserting Recommend DST for the Broker into a table bool CreateTable(int db,string tableName,bool &tableExists);//Function for creating a table in a database void CreateRecords(int db);//Creates a table to store records of when last the Calendar database was updated/created bool UpdateRecords();//Checks if the main Calendar database needs an update or not void EconomicDetails(Calendar &NewsTime[]);//Gets values from the MQL5 economic Calendar //Public declarations accessable via a class's Object public: ~CNews(void);//Deletes a text file created when the Calendar database is being worked on void CreateEconomicDatabase();//Creates the Calendar database for a specific Broker datetime GetLastestNewsDate();//Gets the latest/newest date in the Calendar database };
Hay mucho que desentrañar aquí, primero echaremos un vistazo a:
bool AutoDetectDST(DST_type &dstType);//Function will determine Broker DST
Por el nombre de esta función, su objetivo principal es obtener el horario DST que utiliza el broker, recuperaremos esta información a través de la enumeración.
enum DST_type { US_DST,//US Daylight Savings UK_DST,//UK(EU) Daylight Savings AU_DST,//AU Daylight Savings DST_NONE//No Daylight Savings Available };
Pasado por referencia en la función AutoDectectDST, esta función devolverá false si el horario DST del broker es conocido o no ha podido ser reconocido.
bool CNews::AutoDetectDST(DST_type &dstType) { MqlCalendarValue values[];//Single array of MqlCalendarValue type string eventtime[];//Single string array variable to store NFP(Nonfarm Payrolls) dates for the 'United States' from the previous year int lastyear = Time.ReturnYear(Time.TimeMinusOffset(iTime(Symbol(),PERIOD_CURRENT,0),Time.YearsS()));//Will store the previous year into an integer datetime lastyearstart = StringToTime(StringFormat("%s.01.01 00:00:00",(string)lastyear));//Will store the start date for the previous year datetime lastyearend = StringToTime(StringFormat("%s.12.31 23:59:59",(string)lastyear));//Will store the end date for the previous year if(CalendarValueHistory(values,lastyearstart,lastyearend,"US"))//Getting last year's calendar values for CountryCode = 'US' { for(int x=0; x<(int)ArraySize(values); x++) { if(values[x].event_id==840030016)//Get only NFP Event Dates { ArrayResize(eventtime,eventtime.Size()+1,eventtime.Size()+2);//Increasing the size of eventtime array by 1 eventtime[eventtime.Size()-1] = TimeToString(values[x].time);//Storing the dates in an array of type string } } } datetime ShiftStart=D'1970.01.01 00:00:00',ShiftEnd=D'1970.01.01 00:00:00';//datetime variables to store the broker's time zone shift(change) DST previousresult,currentresult;//Variables of structure type DST declared at the beginning of the class EURUSD="";//String variable assigned empty string EurusdIsSelected = false;//Boolean variable assigned value false EurusdIsFound = false;//Boolean variable assigned value false for(int i=0;i<SymbolsTotal(true);i++)//Will loop through all the Symbols inside the Market Watch { string SymName = SymbolName(i,true);//Assign the Symbol Name of index 'i' from the list of Symbols inside the Market Watch CurrencyBase = SymbolInfoString(SymName,SYMBOL_CURRENCY_BASE);//Assign the Symbol's Currency Base CurrencyProfit = SymbolInfoString(SymName,SYMBOL_CURRENCY_PROFIT);//Assign the Symbol's Currency Profit SymbolExist(SymName,is_Custom);//Get the boolean value into 'is_Custom' for whether the Symbol Name is a Custom Symbol(Is not from the broker) //-- Check if the Symbol outside the Market Watch has a SYMBOL_CURRENCY_BASE of EUR //-- and a SYMBOL_CURRENCY_PROFIT of USD, and this Symbol is not a Custom Symbol(Is not from the broker) if(CurrencyBase=="EUR"&&CurrencyProfit=="USD"&&!is_Custom) { EURUSD = SymName;//Assigning the name of the EURUSD Symbol found inside the Market Watch EurusdIsFound = true;//EURUSD Symbol was found in the Trading Terminal for your Broker break;//Will end the for loop } } if(!EurusdIsFound)//Check if EURUSD Symbol was already Found in the Market Watch { for(int i=0; i<SymbolsTotal(false); i++)//Will loop through all the available Symbols outside the Market Watch { string SymName = SymbolName(i,false);//Assign the Symbol Name of index 'i' from the list of Symbols outside the Market Watch CurrencyBase = SymbolInfoString(SymName,SYMBOL_CURRENCY_BASE); CurrencyProfit = SymbolInfoString(SymName,SYMBOL_CURRENCY_PROFIT); SymbolExist(SymName,is_Custom);//Get the boolean value into 'is_Custom' for whether the Symbol Name is a Custom Symbol(Is not from the broker) //-- Check if the Symbol outside the Market Watch has a SYMBOL_CURRENCY_BASE of EUR //-- and a SYMBOL_CURRENCY_PROFIT of USD, and this Symbol is not a Custom Symbol(Is not from the broker) if(CurrencyBase=="EUR"&&CurrencyProfit=="USD"&&!is_Custom) { EurusdIsSelected = SymbolSelect(SymName,true);//Adding the EURUSD Symbol to the Market Watch if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { EURUSD = SymName;//Assigning the name of the EURUSD Symbol found outside the Market Watch EurusdIsFound = true;//EURUSD Symbol was found in the Trading Terminal for your Broker break;//Will end the for loop } } } } if(!EurusdIsFound)//Check if EURUSD Symbol was Found in the Trading Terminal for your Broker { Print("Cannot Find EURUSD!"); Print("Cannot Create Database!"); Print("Server DST Cannot be Detected!"); dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return false;//Returning False, Broker's DST schedule was not found } for(uint i=0;i<eventtime.Size();i++) { currentresult.result = Candle.IsLargerThanPreviousAndNext((datetime)eventtime[i],Time.HoursS(),EURUSD);//Store the result of if the event date is the larger candlestick currentresult.date = (datetime)eventtime[i];//Store the eventdate from eventtime[i] timeIsShifted = ((currentresult.result!=previousresult.result&&i>0)?true:false);//Check if there is a difference between the previous result and the current result //--- Print Event Dates and if the event date's candle is larger than the previous candle an hour ago and the next candle an hour ahead Print("Date: ",eventtime[i]," is Larger: ",Candle.IsLargerThanPreviousAndNext((datetime)eventtime[i],Time.HoursS(),EURUSD)," Shifted: ",timeIsShifted); if(timeIsShifted)//Check if the Larger candle has shifted from the previous event date to the current event date in eventtime[i] array { if(ShiftStart==D'1970.01.01 00:00:00')//Check if the ShiftStart variable has not been assigned a relevant value yet { ShiftStart=currentresult.date;//Store the event date for when the time shift began } ShiftEnd=previousresult.date;//Store the event date timeshift } previousresult.result = currentresult.result;//Store the previous result of if the event date is the larger candlestick previousresult.date = currentresult.date;//Store the event date from eventtime[i] } if(ShiftStart==D'1970.01.01 00:00:00'&&eventtime.Size()>0)//Check if the ShiftStart variable has not been assigned a relevant value and the event dates are more than zero { Print("Broker ServerTime unchanged!"); dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return true;//Returning True, Broker's DST schedule was found successfully } if(Savings_AU.DaylightSavings(lastyear,DaylightStart,DaylightEnd)) { if(Time.DateIsInRange(DaylightStart,DaylightEnd,ShiftStart,ShiftEnd)) { Print("Broker ServerTime Adjusted For AU DST"); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = AU_DST;//Assigning enumeration value AU_DST, Broker has AU DST(Daylight Savings Time) return true;//Returning True, Broker's DST schedule was found successfully } } else { Print("Something went wrong!"); Print("Cannot Find Daylight-Savings Date For AU"); Print("Year: %d Cannot Be Found!",lastyear); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return false;//Returning False, Broker's DST schedule was not found } if(Savings_UK.DaylightSavings(lastyear,DaylightStart,DaylightEnd)) { if(Time.DateIsInRange(DaylightStart,DaylightEnd,ShiftStart,ShiftEnd)) { Print("Broker ServerTime Adjusted For UK DST"); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = UK_DST;//Assigning enumeration value UK_DST, Broker has UK/EU DST(Daylight Savings Time) return true;//Returning True, Broker's DST schedule was found successfully } } else { Print("Something went wrong!"); Print("Cannot Find Daylight-Savings Date For UK"); Print("Year: %d Cannot Be Found!",lastyear); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return false;//Returning False, Broker's DST schedule was not found } if(Savings_US.DaylightSavings(lastyear,DaylightStart,DaylightEnd)) { if(Time.DateIsInRange(DaylightStart,DaylightEnd,ShiftStart,ShiftEnd)) { Print("Broker ServerTime Adjusted For US DST"); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = US_DST;//Assigning enumeration value US_DST, Broker has US DST(Daylight Savings Time) return true;//Returning True, Broker's DST schedule was found successfully } } else { Print("Something went wrong!"); Print("Cannot Find Daylight-Savings Date For US"); Print("Year: %d Cannot Be Found!",lastyear); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return false;//Returning False, Broker's DST schedule was not found } if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } Print("Cannot Detect Broker ServerTime Configuration!"); dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return false;//Returning False, Broker's DST schedule was not found }
Vale, la función anterior es larga, vamos a desglosarla. En la primera parte, recopilaremos las fechas de los eventos económicos para NFP del año anterior, por lo que si el año actual es 2024, recopilaremos todas las fechas de 2023, ya que necesitamos analizar todo el año para determinar con éxito el probable horario de DST del corredor. Estas fechas se almacenarán en nuestro único array de tipo string `eventtime`.
MqlCalendarValue values[];//Single array of MqlCalendarValue type string eventtime[];//Single string array variable to store NFP(Nonfarm Payrolls) dates for the 'United States' from the previous year int lastyear = Time.ReturnYear(Time.TimeMinusOffset(iTime(Symbol(),PERIOD_CURRENT,0),Time.YearsS()));//Will store the previous year into an integer datetime lastyearstart = StringToTime(StringFormat("%s.01.01 00:00:00",(string)lastyear));//Will store the start date for the previous year datetime lastyearend = StringToTime(StringFormat("%s.12.31 23:59:59",(string)lastyear));//Will store the end date for the previous year if(CalendarValueHistory(values,lastyearstart,lastyearend,"US"))//Getting last year's calendar values for CountryCode = 'US' { for(int x=0; x<(int)ArraySize(values); x++) { if(values[x].event_id==840030016)//Get only NFP Event Dates { ArrayResize(eventtime,eventtime.Size()+1,eventtime.Size()+2);//Increasing the size of event time array by 1 eventtime[eventtime.Size()-1] = TimeToString(values[x].time);//Storing the dates in an array of type string } } }
Luego necesitaremos usar estas fechas en el símbolo EURUSD, porque XAUUSD (ORO) y otros índices como el US30 (Dow Jones) son muy volátiles incluso sin eventos de noticias. El EURUSD es mayormente estable y se vuelve realmente volátil durante eventos económicos, lo que facilita la detección de cuándo ocurrió un evento económico, ya que es probable que el mercado experimente un spike debido al evento. Esta es también la razón por la que nos centraremos en los eventos NFP, ya que regularmente crean estos picos de mercado en los precios. Con esta información, necesitaremos el símbolo EURUSD. Primero, revisaremos todos los símbolos disponibles en el corredor para encontrar y seleccionar EURUSD. Si no encontramos EURUSD, devolveremos `false`.
EURUSD="";//String variable assigned empty string EurusdIsSelected = false;//Boolean variable assigned value false EurusdIsFound = false;//Boolean variable assigned value false for(int i=0;i<SymbolsTotal(true);i++)//Will loop through all the Symbols inside the Market Watch { string SymName = SymbolName(i,true);//Assign the Symbol Name of index 'i' from the list of Symbols inside the Market Watch CurrencyBase = SymbolInfoString(SymName,SYMBOL_CURRENCY_BASE);//Assign the Symbol's Currency Base CurrencyProfit = SymbolInfoString(SymName,SYMBOL_CURRENCY_PROFIT);//Assign the Symbol's Currency Profit SymbolExist(SymName,is_Custom);//Get the boolean value into 'is_Custom' for whether the Symbol Name is a Custom Symbol(Is not from the broker) //-- Check if the Symbol outside the Market Watch has a SYMBOL_CURRENCY_BASE of EUR //-- and a SYMBOL_CURRENCY_PROFIT of USD, and this Symbol is not a Custom Symbol(Is not from the broker) if(CurrencyBase=="EUR"&&CurrencyProfit=="USD"&&!is_Custom) { EURUSD = SymName;//Assigning the name of the EURUSD Symbol found inside the Market Watch EurusdIsFound = true;//EURUSD Symbol was found in the Trading Terminal for your Broker break;//Will end the for loop } } if(!EurusdIsFound)//Check if EURUSD Symbol was already Found in the Market Watch { for(int i=0; i<SymbolsTotal(false); i++)//Will loop through all the available Symbols outside the Market Watch { string SymName = SymbolName(i,false);//Assign the Symbol Name of index 'i' from the list of Symbols outside the Market Watch CurrencyBase = SymbolInfoString(SymName,SYMBOL_CURRENCY_BASE); CurrencyProfit = SymbolInfoString(SymName,SYMBOL_CURRENCY_PROFIT); SymbolExist(SymName,is_Custom);//Get the boolean value into 'is_Custom' for whether the Symbol Name is a Custom Symbol(Is not from the broker) //-- Check if the Symbol outside the Market Watch has a SYMBOL_CURRENCY_BASE of EUR //-- and a SYMBOL_CURRENCY_PROFIT of USD, and this Symbol is not a Custom Symbol(Is not from the broker) if(CurrencyBase=="EUR"&&CurrencyProfit=="USD"&&!is_Custom) { EurusdIsSelected = SymbolSelect(SymName,true);//Adding the EURUSD Symbol to the Market Watch if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { EURUSD = SymName;//Assigning the name of the EURUSD Symbol found outside the Market Watch EurusdIsFound = true;//EURUSD Symbol was found in the Trading Terminal for your Broker break;//Will end the for loop } } } } if(!EurusdIsFound)//Check if EURUSD Symbol was Found in the Trading Terminal for your Broker { Print("Cannot Find EURUSD!"); Print("Cannot Create Database!"); Print("Server DST Cannot be Detected!"); dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return false;//Returning False, Broker's DST schedule was not found }
Después de encontrar EURUSD iteraremos a través de todas las fechas de NFP y encontraremos las velas M15 para cada fecha individual y compararemos la altura de la vela con las fechas de desplazamiento de una hora antes y después del evento para detectar que el evento probablemente ocurrió. Si las fechas de los eventos no coinciden con la volatilidad en las velas almacenaremos en las variables ShiftStart y ShiftEnd la fecha del primer evento cuando se produce este desajuste y cuando finaliza.
for(uint i=0;i<eventtime.Size();i++) { currentresult.result = Candle.IsLargerThanPreviousAndNext((datetime)eventtime[i],Time.HoursS(),EURUSD);//Store the result of if the event date is the larger candlestick currentresult.date = (datetime)eventtime[i];//Store the event date from eventtime[i] timeIsShifted = ((currentresult.result!=previousresult.result&&i>0)?true:false);//Check if there is a difference between the previous result and the current result //--- Print Event Dates and if the event date's candle is larger than the previous candle an hour ago and the next candle an hour ahead Print("Date: ",eventtime[i]," is Larger: ",Candle.IsLargerThanPreviousAndNext((datetime)eventtime[i],Time.HoursS(),EURUSD)," Shifted: ",timeIsShifted); if(timeIsShifted)//Check if the Larger candle has shifted from the previous event date to the current event date in eventtime[i] array { if(ShiftStart==D'1970.01.01 00:00:00')//Check if the ShiftStart variable has not been assigned a relevant value yet { ShiftStart=currentresult.date;//Store the event date for when the time shift began } ShiftEnd=previousresult.date;//Store the event date timeshift } previousresult.result = currentresult.result;//Store the previous result of if the event date is the larger candlestick previousresult.date = currentresult.date;//Store the event date from eventtime[i] }
Una vez que tenemos las fechas ShiftStart y ShiftEnd comprobaremos si las fechas se corresponden con alguna de las fechas de inicio y fin de DST, si hay coincidencia asignaremos el horario DST en la variable dstType y devolveremos true. Si no tenemos una fecha ShiftStart (ShiftStart=D'1970.01.01 00:00:00') y el tamaño del array 'eventtime' es mayor que cero, sabemos que el broker no sigue ningún horario DST.
if(ShiftStart==D'1970.01.01 00:00:00'&&eventtime.Size()>0)//Check if the ShiftStart variable has not been assigned a relevant value and the event dates are more than zero { Print("Broker ServerTime unchanged!"); dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return true;//Returning True, Broker's DST schedule was found successfully } if(Savings_AU.DaylightSavings(lastyear,DaylightStart,DaylightEnd)) { if(Time.DateIsInRange(DaylightStart,DaylightEnd,ShiftStart,ShiftEnd)) { Print("Broker ServerTime Adjusted For AU DST"); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = AU_DST;//Assigning enumeration value AU_DST, Broker has AU DST(Daylight Savings Time) return true;//Returning True, Broker's DST schedule was found successfully } } else { Print("Something went wrong!"); Print("Cannot Find Daylight-Savings Date For AU"); Print("Year: %d Cannot Be Found!",lastyear); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return false;//Returning False, Broker's DST schedule was not found } if(Savings_UK.DaylightSavings(lastyear,DaylightStart,DaylightEnd)) { if(Time.DateIsInRange(DaylightStart,DaylightEnd,ShiftStart,ShiftEnd)) { Print("Broker ServerTime Adjusted For UK DST"); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = UK_DST;//Assigning enumeration value UK_DST, Broker has UK/EU DST(Daylight Savings Time) return true;//Returning True, Broker's DST schedule was found successfully } } else { Print("Something went wrong!"); Print("Cannot Find Daylight-Savings Date For UK"); Print("Year: %d Cannot Be Found!",lastyear); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return false;//Returning False, Broker's DST schedule was not found } if(Savings_US.DaylightSavings(lastyear,DaylightStart,DaylightEnd)) { if(Time.DateIsInRange(DaylightStart,DaylightEnd,ShiftStart,ShiftEnd)) { Print("Broker ServerTime Adjusted For US DST"); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = US_DST;//Assigning enumeration value US_DST, Broker has US DST(Daylight Savings Time) return true;//Returning True, Broker's DST schedule was found successfully } } else { Print("Something went wrong!"); Print("Cannot Find Daylight-Savings Date For US"); Print("Year: %d Cannot Be Found!",lastyear); if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return false;//Returning False, Broker's DST schedule was not found } if(EurusdIsSelected)//Check if this program added EURUSD Symbol to Market Watch { SymbolSelect(EURUSD,false);//Remove EURUSD Symbol from Market Watch } Print("Cannot Detect Broker ServerTime Configuration!"); dstType = DST_NONE;//Assigning enumeration value DST_NONE, Broker has no DST(Daylight Savings Time) return false;//Returning False, Broker's DST schedule was not found }
Una vez que hemos detectado el calendario DST tenemos que almacenar esta información para su posterior aplicación cuando realicemos las pruebas sobre los eventos económicos sabremos que calendario utilizar.
void CreateAutoDST(int db);//Function for creating and inserting Recommend DST for the Broker into a table
Se almacenará un único registro en la tabla AutoDST.
void CNews::CreateAutoDST(int db) { bool failed=false;//boolean variable if(!DatabaseTableExists(db,"AutoDST"))//Checks if the table 'AutoDST' exists in the databse 'Calendar' { //--- create the table AutoDST if(!DatabaseExecute(db,"CREATE TABLE AutoDST(DST STRING NOT NULL);"))//Will attempt to create the table 'AutoDST' { Print("DB: create the AutoDST table failed with code ", GetLastError()); DatabaseClose(db);//Close the database return;//Exits the function if creating the table failed } } else { return;//Exits the function if the table AutoDST table already exists } //Sql query/request to insert the recommend DST for the Broker using the DSTType variable to determine which string data to insert string request_text=StringFormat("INSERT INTO 'AutoDST'(DST) VALUES ('%s')",((DSTType==US_DST)?"Data_US": (DSTType==UK_DST)?"Data_UK":(DSTType==AU_DST)?"Data_AU":"Data_None")); if(!DatabaseExecute(db, request_text))//Will attempt to run this sql request/query { Print(GetLastError()); PrintFormat("INSERT INTO 'AutoDST'(DST) VALUES ('%s')",((DSTType==US_DST)?"Data_US": (DSTType==UK_DST)?"Data_UK":(DSTType==AU_DST)?"Data_AU":"Data_None"));//Will print the sql query if failed failed=true;//assign true if the request failed } if(failed) { //--- roll back all transactions and unlock the database DatabaseTransactionRollback(db); PrintFormat("%s: DatabaseExecute() failed with code %d", __FUNCTION__, GetLastError()); } }
Necesitamos una función que cree nuestras tablas de calendarios, de modo que podamos reutilizar esta función para hacer que nuestros calendarios individuales se ajusten a diferentes horarios DST.
bool CreateTable(int db,string tableName,bool &tableExists);//Function for creating a table in a database
En esta función `CreateTable`, simplemente crearemos las tablas 'Data_UK' para el horario de verano del Reino Unido, 'Data_US' para el horario de verano de EE.UU., 'Data_AU' para el horario de verano de Australia y 'Data_None' para cuando no se utiliza horario de verano. La cadena 'tableName' será el parámetro para el nombre del sufijo de la tabla ejemplo 'US'.
bool CNews::CreateTable(int db,string tableName,bool &tableExists) { if(DatabaseTableExists(db,StringFormat("Data_%s",tableName)))//Checks if a table 'Data_%s' exists in the database 'Calendar' { tableExists=true;//Assigns true to tableExists variable if(!DatabaseExecute(db,StringFormat("DROP TABLE Data_%s",tableName)))//We will drop the table if the table already exists { //If the table failed to be dropped/deleted PrintFormat("Failed to drop table Data_%s with code %d",tableName,GetLastError()); DatabaseClose(db);//Close the database return false;//will terminate execution of the rest of the code below and return false, when the table cannot be dropped } } if(!DatabaseTableExists(db,StringFormat("Data_%s",tableName)))//If the database table 'Data_%s' doesn't exist { //--- create the table 'Data' with the following columns if(!DatabaseExecute(db,StringFormat("CREATE TABLE Data_%s(" "ID INT NOT NULL," "EVENTID INT NOT NULL," "COUNTRY STRING NOT NULL," "EVENTNAME STRING NOT NULL," "EVENTTYPE STRING NOT NULL," "EVENTIMPORTANCE STRING NOT NULL," "EVENTDATE STRING NOT NULL," "EVENTCURRENCY STRING NOT NULL," "EVENTCODE STRING NOT NULL," "EVENTSECTOR STRING NOT NULL," "EVENTFORECAST STRING NOT NULL," "EVENTPREVALUE STRING NOT NULL," "EVENTIMPACT STRING NOT NULL," "EVENTFREQUENCY STRING NOT NULL," "PRIMARY KEY(ID));",tableName)))//Checks if the table was successfully created { Print("DB: create the Calendar table failed with code ", GetLastError()); DatabaseClose(db);//Close the database return false;//Function returns false if creating the table failed } } return true;//Function returns true if creating the table was successful }
Ahora necesitamos insertar datos en estas tablas que hemos creado, pero primero necesitamos obtener estos datos. Nuestra próxima función:
void EconomicDetails(Calendar &NewsTime[]);//Gets values from the MQL5 economic Calendar
Se recuperarán todos los eventos económicos disponibles por referencia en el array `NewsTime` del calendario.
void CNews::EconomicDetails(Calendar &NewsTime[]) { int Size=0;//to keep track of the size of the events in the NewsTime array MqlCalendarCountry countries[]; int count=CalendarCountries(countries);//Get the array of country names available in the Calendar string Country_code=""; for(int i=0; i<count; i++) { MqlCalendarValue values[]; datetime date_from=0;//Get date from the beginning datetime date_to=(datetime)(Time.MonthsS()+iTime(Symbol(),PERIOD_D1,0));//Date of the next month from the current day if(CalendarValueHistory(values,date_from,date_to,countries[i].code)) { for(int x=0; x<(int)ArraySize(values); x++) { MqlCalendarEvent event; ulong event_id=values[x].event_id;//Get the event id if(CalendarEventById(event_id,event)) { ArrayResize(NewsTime,Size+1,Size+2);//Readjust the size of the array to +1 of the array size StringReplace(event.name,"'","");//Removing or replacing single quotes(') from event name with an empty string NewsTime[Size].CountryName = countries[i].name;//storing the country's name from the specific event NewsTime[Size].EventName = event.name;//storing the event's name NewsTime[Size].EventType = EnumToString(event.type);//storing the event type from (ENUM_CALENDAR_EVENT_TYPE) to a string NewsTime[Size].EventImportance = EnumToString(event.importance);//storing the event importance from (ENUM_CALENDAR_EVENT_IMPORTANCE) to a string NewsTime[Size].EventId = event.id;//storing the event id NewsTime[Size].EventDate = TimeToString(values[x].time);//storing normal event time NewsTime[Size].EventCurrency = countries[i].currency;//storing event currency NewsTime[Size].EventCode = countries[i].code;//storing event code NewsTime[Size].EventSector = EnumToString(event.sector);//storing event sector from (ENUM_CALENDAR_EVENT_SECTOR) to a string if(values[x].HasForecastValue())//Checks if the event has a forecast value { NewsTime[Size].EventForecast = (string)values[x].forecast_value;//storing the forecast value into a string } else { NewsTime[Size].EventForecast = "None";//storing 'None' as the forecast value } if(values[x].HasPreviousValue())//Checks if the event has a previous value { NewsTime[Size].EventPreval = (string)values[x].prev_value;//storing the previous value into a string } else { NewsTime[Size].EventPreval = "None";//storing 'None' as the previous value } NewsTime[Size].EventImpact = EnumToString(values[x].impact_type);//storing the event impact from (ENUM_CALENDAR_EVENT_IMPACT) to a string NewsTime[Size].EventFrequency = EnumToString(event.frequency);//storing the event frequency from (ENUM_CALENDAR_EVENT_FREQUENCY) to a string Size++;//incrementing the Calendar array NewsTime } } } } }
Una vez que tengamos nuestros datos, ahora necesitamos insertarlos en las tablas del calendario.
bool InsertIntoTable(int db,DST_type Type,Calendar &Evalues[]);//Function for inserting Economic Data in to a database's table
La función 'InsertIntoTable' le ayudará a realizar esta tarea. Tiene tres parámetros.
1. Este parámetro de entrada es el valor entero de la base de datos.
int db 2. Este parámetro de entrada es el horario de verano (DST).
DST_type Type
3. Esta referencia de matriz es una entrada de los eventos del calendario que habríamos recuperado de nuestra función anterior EconomicDetails.
Calendar &Evalues[]
En esta función, cambiaremos las fechas de los eventos individuales si están dentro del horario de verano (DST). Agregaremos una hora a la fecha del evento. Si la hora actual del servidor está dentro del horario de verano, le restaremos una hora a la fecha del evento. Luego, almacenaremos todos los datos de los eventos económicos en la tabla del calendario `Data_%s`.
bool CNews::InsertIntoTable(int db,DST_type Type,Calendar &Evalues[]) { string tableName;//will store the table name suffix for(uint i=0; i<Evalues.Size(); i++)//Looping through all the Economic Events { string Date;//Will store the date for the economic event switch(Type)//Switch statement to check all possible 'case' scenarios for the variable Type { case DST_NONE://if(Type==DST_NONE) then run code below Date = Evalues[i].EventDate;//Assign the normal Economic EventDate tableName = "None";//Full table name will be 'Data_None' break;//End switch statement case US_DST://if(Type==US_DST) then run code below Savings_US.adjustDaylightSavings(StringToTime(Evalues[i].EventDate),Date);//Assign by Reference the Economic EventDate adjusted for US DST(Daylight Savings Time) tableName = "US";//Full table name will be 'Data_US' break;//End switch statement case UK_DST://if(Type==UK_DST) then run code below Savings_UK.adjustDaylightSavings(StringToTime(Evalues[i].EventDate),Date);//Assign by Reference the Economic EventDate adjusted for UK DST(Daylight Savings Time) tableName = "UK";//Full table name will be 'Data_UK' break;//End switch statement case AU_DST://if(Type==AU_DST) then run code below Savings_AU.adjustDaylightSavings(StringToTime(Evalues[i].EventDate),Date);//Assign by Reference the Economic EventDate adjusted for AU DST(Daylight Savings Time) tableName = "AU";//Full table name will be 'Data_AU' break;//End switch statement default://if(Type==(Unknown value)) then run code below Date = Evalues[i].EventDate;//Assign the normal Economic EventDate tableName = "None";//Full table name will be 'Data_None' break;//End switch statement } string request_text = StringFormat("INSERT INTO 'Data_%s'(ID,EVENTID,COUNTRY,EVENTNAME,EVENTTYPE,EVENTIMPORTANCE,EVENTDATE,EVENTCURRENCY,EVENTCODE," "EVENTSECTOR,EVENTFORECAST,EVENTPREVALUE,EVENTIMPACT,EVENTFREQUENCY)" "VALUES (%d,%d,'%s','%s', '%s', '%s', '%s','%s','%s','%s','%s','%s','%s','%s')", tableName, i, Evalues[i].EventId, Evalues[i].CountryName, Evalues[i].EventName, Evalues[i].EventType, Evalues[i].EventImportance, Date, Evalues[i].EventCurrency, Evalues[i].EventCode, Evalues[i].EventSector, Evalues[i].EventForecast, Evalues[i].EventPreval, Evalues[i].EventImpact, Evalues[i].EventFrequency);//Inserting all the columns for each event record if(!DatabaseExecute(db, request_text))//Checks whether the event was inserted into the table 'Data_%s' { Print(GetLastError()); PrintFormat("INSERT INTO 'Data_%s'(ID,EVENTID,COUNTRY,EVENTNAME,EVENTTYPE,EVENTIMPORTANCE,EVENTDATE,EVENTCURRENCY,EVENTCODE," "EVENTSECTOR,EVENTFORECAST,EVENTPREVALUE,EVENTIMPACT,EVENTFREQUENCY)" "VALUES (%d,%d,'%s','%s', '%s', '%s', '%s','%s','%s','%s','%s','%s','%s','%s')", tableName, i, Evalues[i].EventId, Evalues[i].CountryName, Evalues[i].EventName, Evalues[i].EventType, Evalues[i].EventImportance, Date, Evalues[i].EventCurrency, Evalues[i].EventCode, Evalues[i].EventSector, Evalues[i].EventForecast, Evalues[i].EventPreval, Evalues[i].EventImpact, Evalues[i].EventFrequency);//Will print the sql query to check for any errors or possible defaults in the query/request return false;//Will end the loop and return false, as values failed to be inserted into the table } } return true;//Will return true, all values were inserted into the table successfully }
Una vez que hayamos creado nuestras tablas e insertado los datos económicos en ellas, necesitaremos una marca de tiempo que indique cuándo se realizó esta acción. Esto es para saber cuándo actualizar la tabla.
void CreateRecords(int db);//Creates a table to store records of when last the Calendar database was updated/created
Crearemos una tabla llamada 'Records' y almacenaremos la hora actual del servidor en esta tabla cada vez que creemos o actualicemos las tablas del calendario.
void CNews::CreateRecords(int db) { bool failed=false; if(!DatabaseTableExists(db,"Records"))//Checks if the table 'Records' exists in the databse 'Calendar' { //--- create the table if(!DatabaseExecute(db,"CREATE TABLE Records(RECORDEDTIME INT NOT NULL);"))//Will attempt to create the table 'Records' { Print("DB: create the Records table failed with code ", GetLastError()); DatabaseClose(db);//Close the database return;//Exits the function if creating the table failed } } //Sql query/request to insert the current time into the 'RECORDEDTIME' column in the table 'Records' string request_text=StringFormat("INSERT INTO 'Records'(RECORDEDTIME) VALUES (%d)",(int)TimeCurrent()); if(!DatabaseExecute(db, request_text))//Will attempt to run this sql request/query { Print(GetLastError()); PrintFormat("INSERT INTO 'Records'(RECORDEDTIME) VALUES (%d)",(int)TimeCurrent()); failed=true;//assign true if the request failed } if(failed) { //--- roll back all transactions and unlock the database DatabaseTransactionRollback(db); PrintFormat("%s: DatabaseExecute() failed with code %d", __FUNCTION__, GetLastError()); } }
Ahora básicamente tenemos todas nuestras funciones listas, quedan tres más en las que quiero centrarme. La primera:
bool UpdateRecords();//Checks if the main Calendar database needs an update or not
Esta función devolverá `false` cuando el registro máximo en la tabla llamada `Records` esté dentro de la fecha actual (lo que significa que las tablas del calendario ya fueron creadas o actualizadas en el día actual y no se necesitan realizar más actualizaciones hoy). La función devolverá `true` si las tablas del calendario no existen, si la base de datos del calendario no existe, o si el registro máximo en la tabla llamada `Records` no está dentro de la fecha actual (día).
bool CNews::UpdateRecords() { //--- open/create int db=DatabaseOpen(NEWS_DATABASE_FILE, DATABASE_OPEN_READONLY|DATABASE_OPEN_COMMON);//try to open database Calendar if(db==INVALID_HANDLE)//Checks if the database was able to be opened { //if opening the database failed if(!FileIsExist(NEWS_DATABASE_FILE,FILE_COMMON))//Checks if the database Calendar exists in the common folder { return true;//Returns true when the database was failed to be opened and the file doesn't exist in the common folder } } if(!DatabaseTableExists(db,"Records"))//If the database table 'Records' doesn't exist { DatabaseClose(db); return true; } int recordtime=0;//will store the maximum date recorded in the database table 'Records' string request_text="SELECT MAX(RECORDEDTIME) FROM Records";//Sql query to determine the lastest or maximum date recorded int request=DatabasePrepare(db,request_text);//Creates a handle of a request, which can then be executed using DatabaseRead() if(request==INVALID_HANDLE)//Checks if the request failed to be completed { Print("DB: ",NEWS_DATABASE_FILE, " request failed with code ", GetLastError()); DatabaseClose(db); return true; } for(int i=0; DatabaseRead(request); i++)//Will read all the results from the sql query/request { if(!DatabaseColumnInteger(request, 0, recordtime))//Will assign the first column value to the variable 'recordtime' { Print(i, ": DatabaseRead() failed with code ", GetLastError()); DatabaseFinalize(request);//Removes a request created in DatabasePrepare() DatabaseClose(db);//Closes the database return true; } } DatabaseFinalize(request);//Removes a request created in DatabasePrepare() DatabaseClose(db);//Closes the database if(!Time.DateisToday((datetime)recordtime))//Checks if the recorded time/date is today(current day) { return true; } return false; }
La segunda función en la que quiero enfocarme es:
datetime GetLastestNewsDate();//Gets the lastest/newest date in the Calendar database
Esta función es similar a la última llamada `UpdateRecords`, pero la diferencia es que `GetLatestNewsDate` solo devolverá la hora máxima registrada en la tabla `Records`. Esto se usará más adelante para notificar al usuario si intentan probar una fecha en el probador de estrategias que sea posterior a esta fecha. Le diríamos al usuario/operador que no hay eventos económicos que comprobar más allá de esta fecha.
datetime CNews::GetLastestNewsDate() { //--- open the database 'Calendar' in the common folder int db=DatabaseOpen(NEWS_DATABASE_FILE, DATABASE_OPEN_READONLY|DATABASE_OPEN_COMMON); if(db==INVALID_HANDLE)//Checks if 'Calendar' failed to be opened { if(!FileIsExist(NEWS_DATABASE_FILE,FILE_COMMON))//Checks if 'Calendar' database exists { return 0;//Will return the earliest date which is 1970.01.01 00:00:00 } } string eventtime="1970.01.01 00:00:00";//string variable with the first/earliest possible date in MQL5 //Sql query to determine the lastest or maximum recorded time from which the database was updated. string request_text="SELECT MAX(RECORDEDTIME) FROM Records"; int request=DatabasePrepare(db,request_text); if(request==INVALID_HANDLE) { Print("DB: ",NEWS_DATABASE_FILE, " request failed with code ", GetLastError()); DatabaseClose(db); return true; } for(int i=0; DatabaseRead(request); i++)//Will read all the results from the sql query/request { if(!DatabaseColumnText(request, 0,eventtime))//Will assign the first column(column 0) value to the variable 'eventtime' { Print(i, ": DatabaseRead() failed with code ", GetLastError()); DatabaseFinalize(request);//Finalize request DatabaseClose(db);//Closes the database 'Calendar' return 0;//Will end the for loop and will return the earliest date which is 1970.01.01 00:00:00 } } DatabaseFinalize(request); DatabaseClose(db);//Closes the database 'Calendar' return StringToTime(eventtime);//Returns the string eventtime converted to datetime }
Y ahora pasaremos a la función que creará la base de datos del calendario, así como a llamar a todas las otras funciones que hemos creado anteriormente para crear las tablas en esta base de datos e insertar valores en estas tablas.
void CreateEconomicDatabase();//Creates the Calendar database for a specific Broker
Esta es la función que llamaremos cuando el asesor experto se adjunte al gráfico para crear nuestra base de datos:
void CNews::CreateEconomicDatabase() { Print("Please wait..."); if(FileIsExist(NEWS_DATABASE_FILE,FILE_COMMON))//Check if the database exists { if(!UpdateRecords())//Check if the database is up to date { return;//will terminate execution of the rest of the code below } } else { if(!AutoDetectDST(DSTType))//Check if AutoDetectDST went through all the right procedures { return;//will terminate execution of the rest of the code below } } if(FileIsExist(NEWS_TEXT_FILE,FILE_COMMON))//Check if the database is open { return;//will terminate execution of the rest of the code below } Calendar Evalues[];//Creating a Calendar array variable bool failed=false,tableExists=false; int file=INVALID_HANDLE; datetime lastestdate=D'1970.01.01 00:00:00'; //--- open/create the database 'Calendar' int db=DatabaseOpen(NEWS_DATABASE_FILE, DATABASE_OPEN_READWRITE | DATABASE_OPEN_CREATE| DATABASE_OPEN_COMMON);//will try to open/create in the common folder if(db==INVALID_HANDLE)//Checks if the database 'Calendar' failed to open/create { Print("DB: ",NEWS_DATABASE_FILE, " open failed with code ", GetLastError()); return;//will terminate execution of the rest of the code below } else { file=FileOpen(NEWS_TEXT_FILE,FILE_WRITE|FILE_ANSI|FILE_TXT|FILE_COMMON);//try to create a text file 'NewsDatabaseOpen' in common folder if(file==INVALID_HANDLE) { DatabaseClose(db);//Closes the database 'Calendar' if the News text file failed to be created return;//will terminate execution of the rest of the code below } } DatabaseTransactionBegin(db);//Starts transaction execution Print("Please wait..."); //-- attempt to create the calendar tables if(!CreateTable(db,"None",tableExists)||!CreateTable(db,"US",tableExists) ||!CreateTable(db,"UK",tableExists)||!CreateTable(db,"AU",tableExists)) { FileClose(file);//Closing the file 'NewsDatabaseOpen.txt' FileDelete(NEWS_TEXT_FILE,FILE_COMMON);//Deleting the file 'NewsDatabaseOpen.txt' return;// } EconomicDetails(Evalues);//Retrieving the data from the Economic Calendar if(tableExists)//Checks if there is an existing table within the Calendar Database { //if there is an existing table we will notify the user that we are updating the table. PrintFormat("Updating %s",NEWS_DATABASE_FILE); } else { //if there isn't an existing table we will notify the user that we about to create one PrintFormat("Creating %s",NEWS_DATABASE_FILE); } //-- attempt to insert economic event data into the calendar tables if(!InsertIntoTable(db,DST_NONE,Evalues)||!InsertIntoTable(db,US_DST,Evalues) ||!InsertIntoTable(db,UK_DST,Evalues)||!InsertIntoTable(db,AU_DST,Evalues)) { failed=true;//Will assign true if inserting economic vaules failed in any of the Data tables } if(failed)//Checks if the event/s failed to be recorded/inserted into the database table 'Data_%s' { //--- roll back all transactions and unlock the database DatabaseTransactionRollback(db); PrintFormat("%s: DatabaseExecute() failed with code %d", __FUNCTION__, GetLastError()); FileClose(file);//Close the text file 'NEWS_TEXT_FILE' FileDelete(NEWS_TEXT_FILE,FILE_COMMON);//Delete the text file, as we are reverted/rolled-back the database ArrayRemove(Evalues,0,WHOLE_ARRAY);//Removes the values in the array } else//if all the events were recorded or inserted into the tables 'Data_%s' { if(tableExists) { //Let the user/trader know that the database was updated PrintFormat("%s Updated",NEWS_DATABASE_FILE); } else { //Let the user/trader know that the database was created PrintFormat("%s Created",NEWS_DATABASE_FILE); } CreateRecords(db);//Will create the 'Records' table and insert the current time CreateAutoDST(db);//Will create the 'AutoDST' table and insert the broker's DST schedule FileClose(file);//Close the text file 'NEWS_TEXT_FILE' FileDelete(NEWS_TEXT_FILE,FILE_COMMON);//Delete the text file, as we are about to close the database ArrayRemove(Evalues,0,WHOLE_ARRAY);//Removes the values in the array } //--- all transactions have been performed successfully - record changes and unlock the database DatabaseTransactionCommit(db); DatabaseClose(db);//Close the database }
Ahora pasamos al asesor experto, que ejecutará todo el código que creamos en las diferentes clases y archivos que desarrollamos en este proyecto.
//+------------------------------------------------------------------+ //| NewsTrading.mq5 | //| Copyright 2024, MetaQuotes Ltd. | //| https://www.mql5.com | //+------------------------------------------------------------------+ #include "News.mqh" CNews NewsObject; #include "TimeManagement.mqh" CTimeManagement CTM; #include "WorkingWithFolders.mqh" CFolders Folder();//Calling the class's constructor //+------------------------------------------------------------------+ //| Expert initialization function | //+------------------------------------------------------------------+ int OnInit() { //--- if(!MQLInfoInteger(MQL_TESTER))//Checks whether the program is in the strategy tester { //Checks whether the database file exists and whether it has been modified in the current date if((!CTM.DateisToday((datetime)FileGetInteger(NEWS_DATABASE_FILE,FILE_MODIFY_DATE,true)))||(!FileIsExist(NEWS_DATABASE_FILE,FILE_COMMON))) { /* In the Do while loop below, the code will check if the terminal is connected to the internet. If the the program is stopped the loop will break, if the program is not stopped and the terminal is connected to the internet the function CreateEconomicDatabase will be called from the News.mqh header file's object called NewsObject and the loop will break once called. */ bool done=false; do { if(IsStopped()) { done=true; } if(!TerminalInfoInteger(TERMINAL_CONNECTED)) { Print("Waiting for connection..."); Sleep(500); continue; } else { Print("Connection Successful!"); NewsObject.CreateEconomicDatabase();//calling the database create function done=true; } } while(!done); } } else { //Checks whether the database file exists if(!FileIsExist(NEWS_DATABASE_FILE,FILE_COMMON)) { Print("Necessary Files Do not Exist!"); Print("Run Program outside of the Strategy Tester"); Print("Necessary Files Should be Created First"); return(INIT_FAILED); } //Checks whether the lastest database date includes the time and date being tested datetime lastestdate = CTM.TimePlusOffset(NewsObject.GetLastestNewsDate(),CTM.DaysS());//Day after the lastest recorded time in the database if(lastestdate<TimeCurrent()) { Print("Necessary Files OutDated!"); Print("Database Dates End at: ",lastestdate); Print("Dates after %s will not be available for backtest",lastestdate); Print("To Update Files:"); Print("Run Program outside of the Strategy Tester"); } } //--- return(INIT_SUCCEEDED); } //+------------------------------------------------------------------+ //| Expert deinitialization function | //+------------------------------------------------------------------+ void OnDeinit(const int reason) { //--- } //+------------------------------------------------------------------+ //| Expert tick function | //+------------------------------------------------------------------+ void OnTick() { //--- } //+------------------------------------------------------------------+
Lo único que queda ahora es compilar los archivos, así como el asesor experto, agregar el asesor experto a un gráfico y comenzar el análisis de lo que hemos codificado.
Y lo que es más importante, vea lo que le ofrece el calendario económico.
Estos son los archivos de nuestro proyecto:
Desglose del calendario económico de MQL5.
Una vez que todo esté compilado, abriremos el terminal de trading, localizaremos la ventana de Navegador y abriremos nuestra carpeta `NewsTrading`.
Ahora adjuntaremos el Asesor Experto a un gráfico de tu elección. No habilitaremos "Permitir trading automático" en este artículo, ya que no se realizará ninguna operación. Simplemente presiona OK y adjunta el Asesor Experto.
Una vez que el Experto está conectado al gráfico, debería ver un texto impreso en la pestaña Expertos, en la parte inferior del terminal, informando al usuario de que la base de datos se ha creado correctamente.
Ahora tendrás que localizar el botón IDE en la sección superior del terminal de trading. Una vez que hayas localizado el botón, presiónalo y verás que se abre otra ventana separada del
terminal de trading. Ubica el botón de "Archivo" en la sección superior izquierda del IDE y selecciona "Abrir carpeta de datos compartida".
Su directorio de archivos debe parecerse a esta imagen de arriba, que le mostrará los archivos en esta carpeta llamada 'Files'.
Verás que la carpeta NewsTrading fue creada, junto con muchas otras.
Una vez abiertas todas las carpetas, encontrará la base de datos SQLite del calendario separado de su corredor.
Ahora volveremos al IDE MQL5.
Selecciona el ícono de carpeta en la parte superior izquierda del IDE y deberías ser dirigido a la carpeta común de MetaQuotes.
Luego localizaremos la base de datos SQLite del calendario del corredor y la abriremos.
Deberías ver el contenido de la base de datos en la ventana del Navegador. Haremos clic derecho en la primera tabla y seleccionaremos "Abrir tabla".
La tabla se abrirá y todos los registros (*) de 'AutoDST' se mostrarán. Solo habrá un registro en esta tabla, ya que esta será nuestra tabla recomendada de calendario de DST del corredor.
Una vez que abrimos la tabla 'Data_AU' la tabla mostrará todos los registros de esta tabla así como todas las columnas.
Consulta SQL:
SELECT None.EVENTNAME, DATE(REPLACE(None.EVENTDATE,'.','-')) as Date, TIME(REPLACE(None.EVENTDATE,'.','-')) as Time_None, TIME(REPLACE(US.EVENTDATE,'.','-')) as Time_US, TIME(REPLACE(UK.EVENTDATE,'.','-')) as Time_UK, TIME(REPLACE(AU.EVENTDATE,'.','-')) as Time_AU FROM 'Data_None' None INNER JOIN 'Data_US' US on US.ID=None.ID INNER JOIN 'Data_UK' UK on UK.ID=None.ID INNER JOIN 'Data_AU' AU on AU.ID=None.ID WHERE Date BETWEEN '2023-01-01' AND '2024-01-01' AND None.EVENTID='840100001';
Propósito: Esta consulta es para mostrar el nombre del evento con el 'event_id = 840100001' y la fecha del evento como 'Date' y la hora como 'Time_None' para las fechas entre 2023-01-01 y 2024-01-01 de la tabla 'Data_None', así como seleccionar el mismo 'event_id' de las tablas 'Data_UK', 'Data_US', 'Data_AU', pero solo mostrando la hora de los eventos de estas tablas como 'Time_UK', 'Time_US', 'Time_AU'. En esta consulta queremos mostrar la diferencia de tiempo entre las diferentes tablas de calendario para el mismo evento para todo el año 2023.
En la consulta SQL anterior le damos a la tabla 'Data_None' un alias llamado 'None', le damos a la tabla 'Data_US' un alias llamado 'US', también le damos a la tabla 'Data_UK' un alias llamado 'UK', y a la tabla 'Data_AU' le damos un alias 'AU'.
Seleccionamos:
None.EVENTNAME
De la tabla 'Datos_Ninguno'.
En la función SQL.
REPLACE(None.EVENTDATE,'.','-')
Los caracteres de punto ('.') en el valor de `None.EVENTDATE` se reemplazan por caracteres de guion ('-'). Esto se debe a que la función SQL:
DATE()
Solo acepta fechas en formato datetime con guiones como separadores de caracteres y no fechas en formato datetime con puntos como separadores de caracteres. Esta función convierte 'datetime' en fecha.
TIME()
Esta función SQL convierte la fecha en hora.
Consulta SQL:
SELECT Distinct(COUNTRY) FROM 'Data_None';
Propósito: Esta consulta nos proporciona todos los países únicos que tienen registros en la tabla del calendario `Data_None`.
Si deseas conservar los resultados de tus consultas SQL para un análisis posterior, simplemente haz clic derecho en uno de los resultados y selecciona "Exportar" para guardar el archivo en formato CSV, el cual puede ser convertido a un archivo de Excel.
De ese modo podrás realizar un análisis más detallado.
Consulta SQL:
SELECT * FROM 'Data_None' where COUNTRY='New Zealand';
Propósito: Esta consulta nos proporciona todos los registros para un país específico. En este caso se trata de Nueva Zelanda.
Consulta SQL:
SELECT Distinct(EVENTID), COUNTRY, EVENTNAME,EVENTTYPE, EVENTSECTOR, EVENTIMPORTANCE, EVENTFREQUENCY, EVENTCURRENCY, EVENTCODE FROM 'Data_None' where COUNTRY='New Zealand';
Propósito: Esta consulta recupera todas las ID's de eventos únicos para un país específico y selecciona columnas específicas tales como " EVENTNAME " y " EVENTSECTOR " y así sucesivamente.
Pero, específicamente, no `"EVENTDATE"`, ya que cada `"EVENTID"` tiene una `"EVENTDATE"` distinta. Intentar incluir `EVENTDATE` en esta consulta generará errores.
Consulta SQL:
SELECT Distinct(EVENTID), COUNTRY, EVENTNAME, EVENTTYPE, EVENTIMPORTANCE FROM 'Data_None' where COUNTRY='New Zealand' and EVENTSECTOR='CALENDAR_SECTOR_PRICES';
Propósito: Esta consulta recupera todas las ID's de eventos únicos para un "COUNTRY" y "EVENTSECTOR" específicos.
Consulta SQL:
SELECT COUNTRY,EVENTNAME, EVENTIMPORTANCE FROM 'Data_None' where EVENTIMPORTANCE='CALENDAR_IMPORTANCE_HIGH' UNION SELECT COUNTRY,EVENTNAME, EVENTIMPORTANCE FROM 'Data_None' where EVENTIMPORTANCE='CALENDAR_IMPORTANCE_HIGH';
Propósito: Esta consulta recupera todos los registros únicos para la importancia del evento que es `"CALENDAR_IMPORTANCE_HIGH"`.
Conclusión
Hay mucho que aprender de este artículo, espero que haya aprendido algo nuevo y haya obtenido algunas ideas nuevas después de leerlo. En este artículo repasamos por qué utilizar una base de datos fue la elección correcta y algunas ventajas de utilizar una base de datos. También repasamos todas las monedas que proporciona el calendario económico de MQL5, y el concepto de DST(Daylight Saving Time). Además codificamos varios archivos esenciales para crear la base de datos del calendario y comprobar si se debe actualizar o crear la base de datos.
Por último, buscamos los archivos de la base de datos una vez creados y extrajimos datos específicos utilizando consultas SQL básicas para manipular la tabla. En el próximo artículo abordaremos la gestión de riesgos. Hasta la próxima.
Traducción del inglés realizada por MetaQuotes Ltd.
Artículo original: https://www.mql5.com/en/articles/14324
Desarrollo de asesores expertos autooptimizantes en MQL5
Operaciones angulares para tráders
Multibot en MetaTrader (Parte II): Plantilla dinámica mejorada
Aprendizaje automático y Data Science (Parte 20): Elección entre LDA y PCA en tareas de trading algorítmico en MQL5
- Aplicaciones de trading gratuitas
- 8 000+ señales para copiar
- Noticias económicas para analizar los mercados financieros
Usted acepta la política del sitio web y las condiciones de uso