SymbolInfoSessionQuote

bool  SymbolInfoSessionQuote(
   string            name,                // Symbolname 
   ENUM_DAY_OF_WEEK  day_of_week,         // Wochentag
   uint              session_index,       // Nummer der Notierungssitzung
   datetime&         from,                // Anfang der Notierungssitzung
   datetime&         to                   // Ende der Notierungssitzung
   );

#define SYMBOL_NAME   Symbol()
#define SESSION_INDEX 0
 
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- Ausdruck der Kopfzeile mit einem Symbol und dem SESSION_INDEX und
//--- die Ausgabe in einer Schleife von jedem Wochentag von Mo. bis Fr. und der Anfangs- und Endzeit der Notierungssitzung im Journal ausgeben
   PrintFormat("Symbol %s, Quote session %d:", SYMBOL_NAME, SESSION_INDEX);
   for(int i=MONDAY; i<SATURDAY; i++)
      SymbolInfoSessionQuotePrint(SYMBOL_NAME, (ENUM_DAY_OF_WEEK)i, SESSION_INDEX);
   /*
  Ergebnis:
   Symbol RU000A103661, Quote session 0:
   - Monday     06:45 - 00:00
   - Tuesday    06:45 - 00:00
   - Wednesday  06:45 - 00:00
   - Thursday   06:45 - 00:00
   - Friday     06:45 - 00:00
   */
  }
//+------------------------------------------------------------------+
//| Sende Anfang und Ende der angegebenen Notierungssitzung          |
//| des angegebenen Symbols und Wochentags an das Journal            |
//+------------------------------------------------------------------+
void SymbolInfoSessionQuotePrint(const string symbol, const ENUM_DAY_OF_WEEK day_of_week, const uint session_index)
  {
//--- Deklarieren der Variablen, um den Beginn und das Ende der Notierungssitzung aufzuzeichnen
   datetime date_from;  // Anfang der Sitzung
   datetime date_to;    // Ende der Sitzung
   
//--- Abrufen der Daten aus der Kurssitzung nach Symbol und Wochentag
   if(!SymbolInfoSessionQuote(symbol, day_of_week, session_index, date_from, date_to))
     {
      Print("SymbolInfoSessionQuote() failed. Error ", GetLastError());
      return;
     }
     
//--- den Namen des Wochentags aus dem Enumerationswert erstellen
   string week_day=EnumToString(day_of_week);
   if(week_day.Lower())
      week_day.SetChar(0, ushort(week_day.GetChar(0)-32));
 
//--- Daten für die angegebene Notierungssitzung an das Journal senden
   PrintFormat("- %-10s %s - %s", week_day, TimeToString(date_from, TIME_MINUTES), TimeToString(date_to, TIME_MINUTES));
  }