SymbolInfoSessionQuote

bool  SymbolInfoSessionQuote(
   string            name,                // 交易品种名称
   ENUM_DAY_OF_WEEK  day_of_week,         // 一周中的每天
   uint              session_index,       // 期指
   datetime&         from,                // 期始时间
   datetime&         to                   // 期末时间
   );

#define SYMBOL_NAME   Symbol()
#define SESSION_INDEX 0
 
//+------------------------------------------------------------------+
//| EA交易初始化函数                                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 记录带有交易品种和SESSION_INDEX的标题
//--- 从周一到周五循环，在日志中记录报价时段的开始和结束时间
   PrintFormat("Symbol %s, Quote session %d:", SYMBOL_NAME, SESSION_INDEX);
   for(int i=MONDAY; i<SATURDAY; i++)
      SymbolInfoSessionQuotePrint(SYMBOL_NAME, (ENUM_DAY_OF_WEEK)i, SESSION_INDEX);
   /*
   result:
   Symbol RU000A103661, Quote session 0:
   - Monday     06:45 - 00:00
   - Tuesday    06:45 - 00:00
   - Wednesday  06:45 - 00:00
   - Thursday   06:45 - 00:00
   - Friday     06:45 - 00:00
   */
  }
//+------------------------------------------------------------------+
//| 发送指定报价时段的开始和结束时间                                      |
//| 到日志（指定交易品种，工作日）                                          |
//+------------------------------------------------------------------+
void SymbolInfoSessionQuotePrint(const string symbol, const ENUM_DAY_OF_WEEK day_of_week, const uint session_index)
  {
//--- 声明变量来记录报价时段的开始和结束
   datetime date_from;  // 时段开始时间
   datetime date_to;    // 时段结束时间
   
//--- 从报价时段按交易品种和星期几获取数据
   if(!SymbolInfoSessionQuote(symbol, day_of_week, session_index, date_from, date_to))
     {
      Print("SymbolInfoSessionQuote() failed. Error ", GetLastError());
      return;
     }
     
//--- 从枚举常量创建星期名称
   string week_day=EnumToString(day_of_week);
   if(week_day.Lower())
      week_day.SetChar(0, ushort(week_day.GetChar(0)-32));
 
//--- 将指定报价时段的数据发送到日志
   PrintFormat("- %-10s %s - %s", week_day, TimeToString(date_from, TIME_MINUTES), TimeToString(date_to, TIME_MINUTES));
  }