SymbolInfoSessionQuote

bool  SymbolInfoSessionQuote(
   string            name,                // nome simbolo
   ENUM_DAY_OF_WEEK  day_of_week,         // giorno della settimana
   uint              session_index,       // indice della sessione
   datetime&         from,                // orario di inizio della sessione
   datetime&         to                   // orario di fine della sessione
   );

#define SYMBOL_NAME   Symbol()
#define SESSION_INDEX 0
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//-- stampa l'intestazione con un simbolo e SESSION_INDEX e
//--- in un ciclo per giorno della settimana da Lun a Ven, stampa gli orari di inizio e fine sessione delle quotazioni nel journal
   PrintFormat("Symbol %s, Quote session %d:", SYMBOL_NAME, SESSION_INDEX);
   for(int i=MONDAY; i<SATURDAY; i++)
      SymbolInfoSessionQuotePrint(SYMBOL_NAME, (ENUM_DAY_OF_WEEK)i, SESSION_INDEX);
   /*
   risultato:
   Symbol RU000A103661, Quote session 0:
   - Monday     06:45 - 00:00
   - Tuesday    06:45 - 00:00
   - Wednesday  06:45 - 00:00
   - Thursday   06:45 - 00:00
   - Friday     06:45 - 00:00
   */
  }
//+--------------------------------------------------------------------------------------+
//| Invia gli orari di inizio e fine sessione di quotazione specificata |
//| per il simbolo specificato e il giorno della settimana al journal |
//+--------------------------------------------------------------------------------------+
void SymbolInfoSessionQuotePrint(const string symbol, const ENUM_DAY_OF_WEEK day_of_week, const uint session_index)
  {
//--- dichiara le variabili per registrare l'inizio e la fine della sessione di quotazione
   datetime date_from;  // ora di inizio sessione
   datetime date_to;    // ora di fine sessione
   
//--- ottenere i dati dalla sessione di quotazione per simbolo e giorno della settimana
   if(!SymbolInfoSessionQuote(symbol, day_of_week, session_index, date_from, date_to))
     {
      Print("SymbolInfoSessionQuote() failed. Error ", GetLastError());
      return;
     }
     
//--- creare il nome del giorno della settimana dalla costante di enumerazione
   string week_day=EnumToString(day_of_week);
   if(week_day.Lower())
      week_day.SetChar(0, ushort(week_day.GetChar(0)-32));
 
//-- inviare i dati per la sessione di quotazione specificata al journal
   PrintFormat("- %-10s %s - %s", week_day, TimeToString(date_from, TIME_MINUTES), TimeToString(date_to, TIME_MINUTES));
  }