SymbolInfoSessionQuote

bool  SymbolInfoSessionQuote(
   string            name,                // 심볼 이름
   ENUM_DAY_OF_WEEK  day_of_week,         // 요일
   uint              session_index,       // 세션 인덱스
   datetime&         from,                // 세션 시작 시간
   datetime&         to                   // 세션 종료 시간
   );

#define SYMBOL_NAME   Symbol()
#define SESSION_INDEX 0
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 심볼과 SESSION_INDEX로 헤더를 인쇄하고
//--- 월요일부터 금요일까지 요일별 루프에서 시세 쿼트 세션의 시작 및 종료 시간을 저널에 인쇄합니다.
   PrintFormat("Symbol %s, Quote session %d:", SYMBOL_NAME, SESSION_INDEX);
   for(int i=MONDAY; i<SATURDAY; i++)
      SymbolInfoSessionQuotePrint(SYMBOL_NAME, (ENUM_DAY_OF_WEEK)i, SESSION_INDEX);
   /*
  결과:
   Symbol RU000A103661, Quote session 0:
   - Monday     06:45 - 00:00
   - Tuesday    06:45 - 00:00
   - Wednesday  06:45 - 00:00
   - Thursday   06:45 - 00:00
   - Friday     06:45 - 00:00
   */
  }
//+------------------------------------------------------------------+
//| 지정된 쿼트 세션의 시작 및 종료 시간 보내기                           |
//| 지정된 심볼 및 요일에 대한 저널                                     |
//+------------------------------------------------------------------+
void SymbolInfoSessionQuotePrint(const string symbol, const ENUM_DAY_OF_WEEK day_of_week, const uint session_index)
  {
//--- 쿼트 세션의 시작과 끝을 기록하는 변수를 선언합니다.
   datetime date_from;  // 세션 시작 시간
   datetime date_to;    // 세션 종료 시간
   
//--- 심볼 및 요일별로 쿼트 세션에서 데이터를 가져옵니다.
   if(!SymbolInfoSessionQuote(symbol, day_of_week, session_index, date_from, date_to))
     {
      Print("SymbolInfoSessionQuote() failed. Error ", GetLastError());
      return;
     }
     
//--- 열거형 상수로부터 요일 이름을 생성합니다.
   string week_day=EnumToString(day_of_week);
   if(week_day.Lower())
      week_day.SetChar(0, ushort(week_day.GetChar(0)-32));
 
//--- 지정된 쿼트 세션에 대한 데이터를 저널로 보냅니다.
   PrintFormat("- %-10s %s - %s", week_day, TimeToString(date_from, TIME_MINUTES), TimeToString(date_to, TIME_MINUTES));
  }