SymbolInfoSessionTrade

bool  SymbolInfoSessionTrade(
   string            name,                // Symbolname
   ENUM_DAY_OF_WEEK  day_of_week,         // Wochentag
   uint              session_index,       // Nummer der Handelssitzung
   datetime&         from,                // Anfang der Handelssitzung
   datetime&         to                   // Ende der Handelssitzung
   );

#define SYMBOL_NAME   Symbol()
#define SESSION_INDEX 0
 
//+------------------------------------------------------------------+
//| Skript Programm Start Funktion                                   |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- Ausdruck der Kopfzeile mit einem Symbol und dem SESSION_INDEX und
//--- die Ausgabe in einer Schleife von jedem Wochentag von Mo bis Fr und der Anfangs- und Endzeit der Handelssitzung im Journal ausgeben
   PrintFormat("Symbol %s, Trade session %d:", SYMBOL_NAME, SESSION_INDEX);
   for(int i=MONDAY; i<SATURDAY; i++)
      SymbolInfoSessionTradePrint(SYMBOL_NAME, (ENUM_DAY_OF_WEEK)i, SESSION_INDEX);
   /*
  Ergebnis:
   Symbol GBPUSD, Trade session 0:
   - Monday     00:15 - 23:55
   - Tuesday    00:15 - 23:55
   - Wednesday  00:15 - 23:55
   - Thursday   00:15 - 23:55
   - Friday     00:15 - 23:55
   */
  }
//+------------------------------------------------------------------+
//| Sende die Start- und Endzeiten der angegebenen Handelssitzung    |
//| des angegebenen Symbols und Wochentags an das Journal            |
//+------------------------------------------------------------------+
void SymbolInfoSessionTradePrint(const string symbol, const ENUM_DAY_OF_WEEK day_of_week, const uint session_index)
  {
//--- Deklarieren der Variablen, um den Beginn und das Ende der Handelssitzung aufzuzeichnen
   datetime date_from;  // Anfang der Sitzung
   datetime date_to;    // Ende der Sitzung
   
//--- Abrufen der Daten aus der Handelssitzung nach Symbol und Wochentag
   if(!SymbolInfoSessionTrade(symbol, day_of_week, session_index, date_from, date_to))
     {
      Print("SymbolInfoSessionTrade() failed. Error ", GetLastError());
      return;
     }
     
//--- den Namen des Wochentags aus dem Enumerationswert erstellen
   string week_day=EnumToString(day_of_week);
   if(week_day.Lower())
      week_day.SetChar(0, ushort(week_day.GetChar(0)-32));
 
//--- Daten für die angegebene Handelssitzung an das Journal senden
   PrintFormat("- %-10s %s - %s", week_day, TimeToString(date_from, TIME_MINUTES), TimeToString(date_to, TIME_MINUTES));
  }