SymbolInfoSessionQuote

bool  SymbolInfoSessionQuote(
   string            name,                // sembol ismi
   ENUM_DAY_OF_WEEK  day_of_week,         // haftanın günü
   uint              session_index,       // seans indisi
   datetime&         from,                // seans başlangıç zamanı
   datetime&         to                   // seans bitiş zamanı
   );

#define SYMBOL_NAME   Symbol()
#define SESSION_INDEX 0
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- başlığı sembol adı ve SESSION_INDEX ile yazdır ve
//--- pazartesiden cumaya kadar haftanın günlerine göre bir döngü içerisinde, kotasyon seansının başlangıç ve bitiş saatlerini günlüğe yazdır
   PrintFormat("Symbol %s, Quote session %d:", SYMBOL_NAME, SESSION_INDEX);
   for(int i=MONDAY; i<SATURDAY; i++)
      SymbolInfoSessionQuotePrint(SYMBOL_NAME, (ENUM_DAY_OF_WEEK)i, SESSION_INDEX);
   /*
  sonuç:
   Symbol RU000A103661, Quote session 0:
   - Monday     06:45 - 00:00
   - Tuesday    06:45 - 00:00
   - Wednesday  06:45 - 00:00
   - Thursday   06:45 - 00:00
   - Friday     06:45 - 00:00
   */
  }
//+------------------------------------------------------------------+
//| Belirtilen sembol ve haftanın günü için belirtilen kotasyon      |
//| seansının başlangıç ve bitiş saatlerini günlüğe gönder           |
//+------------------------------------------------------------------+
void SymbolInfoSessionQuotePrint(const string symbol, const ENUM_DAY_OF_WEEK day_of_week, const uint session_index)
  {
//--- kotasyon seansının başlangıcını ve sonunu kaydetmek için değişkenler bildir
   datetime date_from;  // seans başlangıç saati
   datetime date_to;    // seans sonu saati
   
//--- sembol ve haftanın gününe göre kotasyon seansına ilişkin verileri al
   if(!SymbolInfoSessionQuote(symbol, day_of_week, session_index, date_from, date_to))
     {
      Print("SymbolInfoSessionQuote() failed. Error ", GetLastError());
      return;
     }
     
//--- numaralandırma sabitinden hafta günü adını oluştur
   string week_day=EnumToString(day_of_week);
   if(week_day.Lower())
      week_day.SetChar(0, ushort(week_day.GetChar(0)-32));
 
//--- belirtilen kotasyon seansı için verileri günlüğe gönder
   PrintFormat("- %-10s %s - %s", week_day, TimeToString(date_from, TIME_MINUTES), TimeToString(date_to, TIME_MINUTES));
  }