DokumentationKategorien
Nachschlagewerk MQL5Datum und ZeitTimeGMT 

TimeGMT

Gibt die Zeit GMT zurück, die im Hinblick auf den Übergang zur Sommer- oder Winterzeit je nach der Lokalzeit des Computers, auf dem das eingesetzten Client-Terminal läuft, berechnet wird. Es gibt 2 Varianten der Funktion.

Aufruf ohne Parameter

datetime  TimeGMT();

Aufruf mit Parameter des Typs  MqlDateTime

datetime  TimeGMT(
   MqlDateTime&  dt_struct      // die Strukturvariable der Zeit
   );

Parameter

dt_struct

[out]  die Strukturvariable der Zeit MqlDateTime.

Rückgabewert

Zeitwert vom Typs datetime

Hinweis

Wenn als Parameter die Strukturvariable des Typs MqlDateTime übergeben wurde, wird sie entsprechend ausgefüllt.

Um die Zähler und hochauflösende Timer zu arrangieren, verwenden Sie die Funktion GetTickCount(), die den Wert in Millisekunden gibt.

Im Strategietester ist die TimeGMT() Zeit immer gleich der modellierten Serverzeit TimeTradeServer().

Beispiel:

void OnStart()
  {
//--- Deklaration der Variablen MqlDateTime, die mit Datums-/Zeitdaten gefüllt werden soll und so die lokale PC-Zeit und GMT ermittelt wird
   MqlDateTime tm={};
   datetime    time1=TimeLocal();            // erste Form des Aufrufs: Lokalzeit des PC
   datetime    time2=TimeGMT(tm);            // zweite Form des Aufrufs: GMT berechnet aus der PC-Ortszeit mit dem Ausfüllen der MqlDateTime-Struktur
   int         shift=int(time1-time2)/3600;  // lokaler Zeit-Offset zu GMT
   
//--- Ausgabe von Lokalzeit und GMT mit den Daten der gefüllten MqlDateTime-Struktur im Protokoll
   PrintFormat("Time Local: %s\nTime GMT: %s\n- Year: %u\n- Month: %02u\n- Day: %02u\n"+
               "- Hour: %02u\n- Min: %02u\n- Sec: %02u\n- Day of Year: %03u\n- Day of Week: %u (%s)\nLocal time offset relative to GMT: %+d",
               (string)time1, (string)time2, tm.year, tm.mon, tm.day, tm.hour, tm.min, tm.sec, tm.day_of_year, tm.day_of_week,
               EnumToString((ENUM_DAY_OF_WEEK)tm.day_of_week), shift);
  /*
  Ergebnis:
   Time Local: 2024.04.18 19:37:23
   Time GMT: 2024.04.18 12:37:23
   - Year: 2024
   - Month: 04
   - Day: 18
   - Hour: 12
   - Min: 37
   - Sec: 23
   - Day of Year: 108
   - Day of Week: 4 (THURSDAY)
   Local time offset relative to GMT: +7
  */
  }