DocumentaciónSecciones
Manual de referencia de MQL5Fecha y horaTimeGMT 

TimeGMT

Devuelve la hora GMT que se calcula, teniendo en cuenta el cambio de horarios de verano o de invierno, según la hora local del ordenador en el que está funcionando el terminal de cliente. Existen 2 variantes de la función.

Llamada sin parámetros

datetime  TimeGMT();

Llamada con el parámetro del tipo MqlDateTime

datetime  TimeGMT(
   MqlDateTime&  dt_struct      // variable del tipo de estructura
   );

Parámetros

dt_struct

[out]  Variable del tipo de estructura MqlDateTime.

Valor devuelto

Valor del tipo datetime

Nota

Si la variable del tipo de estructura MqlDateTime ha sido pasada como un parámetro, entonces ella se rellena de modo correspondiente.

Para organizar los contadores y temporizadores de alta resolución, se debe utilizar la función GetTickCount() que ofrece los valores en millisegundos.

Durante el trabajo en el Probador de Estrategias, la hora TimeGMT() siempre es igual a la hora modelada del servidor TimeTradeServer().

Ejemplo:

void OnStart()
  {
//--- declaramos la variable MqlDateTime para llenarla con los datos de fecha/hora y obtenemos la hora local del ordenador y la hora GMT
   MqlDateTime tm={};
   datetime    time1=TimeLocal();            // primera forma de llamada: hora local del ordenador
   datetime    time2=TimeGMT(tm);            // segunda forma de llamada: hora GMT calculada por la hora del ordenador local rellenando la estructura MqlDateTime
   int         shift=int(time1-time2)/3600;  // desfase de la hora local con respecto a la hora GMT
   
//--- mostramos en el registro la hora local y la hora GMT con los datos de la estructura MqlDateTime rellenada
   PrintFormat("Time Local: %s\nTime GMT: %s\n- Year: %u\n- Month: %02u\n- Day: %02u\n"+
               "- Hour: %02u\n- Min: %02u\n- Sec: %02u\n- Day of Year: %03u\n- Day of Week: %u (%s)\nLocal time offset relative to GMT: %+d",
               (string)time1, (string)time2, tm.year, tm.mon, tm.day, tm.hour, tm.min, tm.sec, tm.day_of_year, tm.day_of_week,
               EnumToString((ENUM_DAY_OF_WEEK)tm.day_of_week), shift);
   /*
  Resultado
   Time Local: 2024.04.18 19:37:23
   Time GMT: 2024.04.18 12:37:23
   - Year: 2024
   - Month: 04
   - Day: 18
   - Hour: 12
   - Min: 37
   - Sec: 23
   - Day of Year: 108
   - Day of Week: 4 (THURSDAY)
   Local time offset relative to GMT: +7
   */
  }