DocumentaçãoSeções
Referência MQL5Data e HoraTimeGMT 

TimeGMT

Retorna a hora GMT, que é calculada levando em consideração o ajuste ao horário de verão pela hora local no computador de onde o terminal cliente está executando. Existem 2 variantes da função.

Chamar sem parâmetros

datetime  TimeGMT();

Chamar com parâmetro de tipo MqlDateTime

datetime  TimeGMT(
   MqlDateTime&  dt_struct      // Variável de tipo estrutura
   );

Parâmetros

dt_struct

[out]  Variável de tipo estrutura MqlDateTime.

Valor do Retorno

Valor de tipo datetime

Observação

Se uma variável de tipo estrutura MqlDateTime for passada como parâmetro, ela é preenchida de acordo.

Para obter contadores e timer de alta-resolução, use a função GetTickCount(), que produz valores em milissegundos.

Durante o teste no testador de estratégia, o tempo do servidor simuladoTimeGMT() é sempre igual ao TimeTradeServer().

Exemplo:

void OnStart()
  {
//--- declaramos a a variável MqlDateTime para preencher com dados de data/hora e obter a hora local do computador e a hora GMT
   MqlDateTime tm={};
   datetime    time1=TimeLocal();            // primeira forma de chamada: hora local do computador
   datetime    time2=TimeGMT(tm);            // segunda forma de chamada: hora GMT calculada pela hora do computador local com o preenchimento da estrutura MqlDateTime
   int         shift=int(time1-time2)/3600;  // deslocamento da hora local em relação à hora GMT
   
//--- exibimos no log a hora local e a hora GMT com dados da estrutura MqlDateTime preenchida
   PrintFormat("Time Local: %s\nTime GMT: %s\n- Year: %u\n- Month: %02u\n- Day: %02u\n"+
               "- Hour: %02u\n- Min: %02u\n- Sec: %02u\n- Day of Year: %03u\n- Day of Week: %u (%s)\nLocal time offset relative to GMT: %+d",
               (string)time1, (string)time2, tm.year, tm.mon, tm.day, tm.hour, tm.min, tm.sec, tm.day_of_year, tm.day_of_week,
               EnumToString((ENUM_DAY_OF_WEEK)tm.day_of_week), shift);
  /*
  Resultado
   Time Local: 2024.04.18 19:37:23
   Time GMT: 2024.04.18 12:37:23
   - Year: 2024
   - Month: 04
   - Day: 18
   - Hour: 12
   - Min: 37
   - Sec: 23
   - Day of Year: 108
   - Day of Week: 4 (THURSDAY)
   Local time offset relative to GMT: +7
  */
  }