DocumentazioneSezioni
MQL5 RiferimentoData ed OraTimeGMT 

TimeGMT

Restituisce il GMT, che viene calcolato tenendo conto del DST switch dall'ora locale del computer in cui il terminale client è in esecuzione. Ci sono due varianti della funzione.

Chiamata senza parametri

datetime  TimeGMT();

Chiamata con parametro di tipo MqlDateTime

datetime  TimeGMT(
   MqlDateTime&  dt_struct      // Variabile di tipo struttura
   );

Parametri

dt_struct

[out]  Variabile di tipo struttura MqlDateTime.

Valore restituito

Valore di tipo datetime

Nota

Se la variabile MqlDateTime di tipo struttura è stata passata come parametro, viene riempita di conseguenza.

Per organizzare contatori e timers ad alta risoluzione, utilizzare la funzione GetTickCount(), che produce valori in millisecondi.

Durante il test nel tester di strategia, TimeGMT() è sempre uguale a TimeTradeServer() ora del server simulato.

Esempio:

void OnStart()
  {
//--- dichiarare la variabile MqlDateTime da riempire con dati di data/ora e ottenere l'ora locale del PC e GMT
   MqlDateTime tm={};
   datetime    time1=TimeLocal();            // prima forma di chiamata: ora locale del PC
   datetime    time2=TimeGMT(tm);            // seconda forma di chiamata: GMT calcolato dall'ora locale del PC con il riempimento della struttura MqlDateTime
   int         shift=int(time1-time2)/3600;  // offset ora locale rispetto a GMT
   
//-- visualizza nel log l'ora locale e GMT con i dati inseriti della struttura MqlDateTime
   PrintFormat("Time Local: %s\nTime GMT: %s\n- Year: %u\n- Month: %02u\n- Day: %02u\n"+
               "- Hour: %02u\n- Min: %02u\n- Sec: %02u\n- Day of Year: %03u\n- Day of Week: %u (%s)\nLocal time offset relative to GMT: %+d",
               (string)time1, (string)time2, tm.year, tm.mon, tm.day, tm.hour, tm.min, tm.sec, tm.day_of_year, tm.day_of_week,
               EnumToString((ENUM_DAY_OF_WEEK)tm.day_of_week), shift);
  /*
  risultato:
   Time Local: 2024.04.18 19:37:23
   Time GMT: 2024.04.18 12:37:23
   - Year: 2024
   - Month: 04
   - Day: 18
   - Hour: 12
   - Min: 37
   - Sec: 23
   - Day of Year: 108
   - Day of Week: 4 (THURSDAY)
   Local time offset relative to GMT: +7
  */
  }