DokumentationKategorien
Nachschlagewerk MQL5Datum und ZeitTimeTradeServer 

TimeTradeServer

Gibt aktuelle Zeit des Handelsservers zurück. Zum Unterschied von der Funktion TimeCurrent(), wird die Zeitberechnung im Client-Terminal durchgeführt und hängt von den Zeitenstellungen im Computer des Nutzers ab. Es gibt  2 Varianten der Funktion.

Aufruf ohne Parameter

datetime  TimeTradeServer();

Aufruf mit Parameter des Typs  MqlDateTime

datetime  TimeTradeServer(
   MqlDateTime&  dt_struct      // die Strukturvariable der Zeit
   );

Parameter

dt_struct

[out]  die Strukturvariable der Zeit MqlDateTime.

Rückgabewert

Zeitwert vom Typs datetime

Hinweis

Wenn als Parameter die Strukturvariable des Typs MqlDateTime übergeben wurde, wird sie entsprechend ausgefüllt.

Um die Zähler und hochauflösende Timer zu arrangieren, verwenden Sie die Funktion GetTickCount(), die den Wert in Millisekunden gibt.

Im Strategietester ist TimeTradeServer() immer gleich der Serverzeit TimeCurrent().

Beispiel:

void OnStart()
  {
//--- Deklarieren der Variablen MqlDateTime, die mit Datums-/Zeitdaten gefüllt werden soll und der Ermittlung des Zeitpunkts des letzten Kurses und den geschätzten aktuellen Zeitpunkt des Handelsservers
   MqlDateTime tm={};
   datetime    time_current=TimeCurrent();                  // erste Form des Aufrufs: Zeitpunkt des letzten Kurses für eines der Symbole im Fenster Marktübersicht
   datetime    time_server =TimeTradeServer(tm);            // zweite Form des Aufrufs: geschätzte aktuelle Zeit des Handels-Servers in Form der Zeitstruktur MqlDateTime
   int         difference  =int(time_current-time_server);  // Differenz zwischen aktueller Zeit und der Zeit des Handels-Server
   
//--- Ausgabe der Zeit des letzten Kurses und der geschätzten aktuellen Zeit des Handelsservers mit den Daten der gefüllten MqlDateTime-Struktur im Protokoll
   PrintFormat("Time Current: %s\nTime Trade Server: %s\n- Year: %u\n- Month: %02u\n- Day: %02u\n"+
               "- Hour: %02u\n- Min: %02u\n- Sec: %02u\n- Day of Year: %03u\n- Day of Week: %u (%s)\nDifference between Time Current and Time Trade Server: %+d",
               (string)time_current, (string)time_server, tm.year, tm.mon, tm.day, tm.hour, tm.min, tm.sec, tm.day_of_year, tm.day_of_week,
               EnumToString((ENUM_DAY_OF_WEEK)tm.day_of_week), difference);
  /*
  Ergebnis:
   Time Current: 2024.04.18 16:10:14
   Time Trade Server: 2024.04.18 16:10:15
   - Year: 2024
   - Month: 04
   - Day: 18
   - Hour: 16
   - Min: 10
   - Sec: 15
   - Day of Year: 108
   - Day of Week: 4 (THURSDAY)
   Difference between Time Current and Time Trade Server: -1
  */
  }