DokümantasyonBölümler
MQL5 ReferansıTarih ve ZamanTimeGMT 

TimeGMT

GMT zamanına dönüş yapar. Yaz Saati dönüşümü hesaba katılarak, müşteri terminalinin çalıştırıldığı bilgisayarın zamanını kullanarak hesaplanır. Fonksiyonun 2 çeşidi bulunmaktadır.

Parametresiz çağrı

datetime  TimeGMT();

MqlDateTime tipi parametre ile çağrı

datetime  TimeGMT(
   MqlDateTime&  dt_struct      // Yapı tipli değişken
   );

Parametreler

dt_struct

[out] MqlDateTime yapı tipli değişken .

Dönüş değeri

datetime tipli değer

Not

MqlDateTime yapı tipli değişken, parametre olarak geçirilmişse, uygun şekilde doldurulur.

Yüksek kesinlikte sayaçlar ve zamanlayıcılar için, milisaniye bazında değerler üreten GetTickCount() fonksiyonunu kullanın.

Strateji sınayıcıda test sırasında, TimeGMT() her zaman TimeTradeServer() simüle edilmiş sunucu zamanına eşittir.

Örnek:

void OnStart()
  {
//--- MqlDateTime değişkenini tarih/saat verileriyle doldurulacak şekilde bildir ve PC yerel saatini ve GMT'yi al
   MqlDateTime tm={};
   datetime    time1=TimeLocal();            // birinci çağrı şekli: PC yerel saati
   datetime    time2=TimeGMT(tm);            // ikinci çağrı şekli: MqlDateTime yapısı doldurularak PC yerel saatinden hesaplanan GMT
   int         shift=int(time1-time2)/3600;  // GMT'ye göre yerel saat farkı
   
//--- doldurulan MqlDateTime yapısının verileriyle yerel saati ve GMT'yi günlükte görüntüle
   PrintFormat("Time Local: %s\nTime GMT: %s\n- Year: %u\n- Month: %02u\n- Day: %02u\n"+
               "- Hour: %02u\n- Min: %02u\n- Sec: %02u\n- Day of Year: %03u\n- Day of Week: %u (%s)\nLocal time offset relative to GMT: %+d",
               (string)time1, (string)time2, tm.year, tm.mon, tm.day, tm.hour, tm.min, tm.sec, tm.day_of_year, tm.day_of_week,
               EnumToString((ENUM_DAY_OF_WEEK)tm.day_of_week), shift);
  /*
  Sonuç:
   Time Local: 2024.04.18 19:37:23
   Time GMT: 2024.04.18 12:37:23
   - Year: 2024
   - Month: 04
   - Day: 18
   - Hour: 12
   - Min: 37
   - Sec: 23
   - Day of Year: 108
   - Day of Week: 4 (THURSDAY)
   Local time offset relative to GMT: +7
  */
  }