StructToTime

datetime  StructToTime(
   MqlDateTime&  dt_struct      // estrutura da data e hora
   );

#property script_show_inputs
 
input int   InpYear  =  0;    // Year
input int   InpMonth =  0;    // Month
input int   InpDay   =  0;    // Day
input int   InpHour  =  0;    // Hour
input int   InpMin   =  0;    // Minutes
input int   InpSec   =  0;    // Seconds
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- corregemos os valores inseridos e os escrevemos nas variáveis
   int year =  (InpYear<1970 ? 1970 : InpYear); // Se o ano inserido for inferior a 1970, será usado 1970
   int month=  (InpMonth<1 ?  1  :  InpMonth > 12  ?  12 :  InpMonth);
   int day  =  (InpDay  <1 ?  1  :  InpDay   > 31  ?  31 :  InpDay);
   int hour =  (InpHour <0 ?  0  :  InpHour  > 23  ?  23 :  InpHour);
   int min  =  (InpMin  <0 ?  0  :  InpMin   > 59  ?  59 :  InpMin);
   int sec  =  (InpSec  <0 ?  0  :  InpSec   > 59  ?  59 :  InpSec);
 
//--- exibimos os valores inseridos no log
   PrintFormat("Entered date and time: %04u.%02u.%02u %02u:%02u:%02u", InpYear, InpMonth, InpDay, InpHour, InpMin, InpSec);
   
//--- exibimos os valores corrigidos no log
   PrintFormat("Corrected date and time: %04u.%02u.%02u %02u:%02u:%02u", year, month, day, hour, min, sec);
   
//--- escrevemos os valores de entrada nos campos correspondentes da estrutura
   MqlDateTime time_struct={};
   time_struct.year= year;
   time_struct.mon = month;
   time_struct.day = day;
   time_struct.hour= hour;
   time_struct.min = min;
   time_struct.sec = sec;
   
//--- convertemos a data e a hora da estrutura em uma variável com o tipo datetime e
   datetime time = StructToTime(time_struct);
   
//--- exibimos o resultado da conversão de uma variável do tipo de estrutura MqlDateTime em um valor do tipo datetime
   Print("Converted date and time: ",TimeToString(time,TIME_DATE|TIME_MINUTES|TIME_SECONDS));
   /*
   Resultados, se forem inseridos valores padrão zero:
   Entered date and time: 0000.00.00 00:00:00
   Corrected date and time: 1970.01.01 00:00:00
   Converted date and time: 1970.01.01 00:00:00
   
   Resultados, se for inserido o dia errado do mês de fevereiro do ano atual:
   Entered date and time: 2024.02.31 00:00:00
   Corrected date and time: 2024.02.31 00:00:00
   Converted date and time: 2024.03.02 00:00:00
   */
  }