SymbolInfoSessionTrade

bool  SymbolInfoSessionTrade(
   string            name,                // nome simbolo
   ENUM_DAY_OF_WEEK  day_of_week,         // giorno della settimana
   uint              session_index,       // indice della sessione
   datetime&         from,                // orario inizio sessione
   datetime&         to                   // orario fine sessione
   );

#define SYMBOL_NAME   Symbol()
#define SESSION_INDEX 0
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//-- stampa l'intestazione con un simbolo e SESSION_INDEX e
//--- in un ciclo per giorno della settimana da Lun a Ven, stampa gli orari di inizio e fine sessione delle sessioni di trading nel journal
   PrintFormat("Symbol %s, Trade session %d:", SYMBOL_NAME, SESSION_INDEX);
   for(int i=MONDAY; i<SATURDAY; i++)
      SymbolInfoSessionTradePrint(SYMBOL_NAME, (ENUM_DAY_OF_WEEK)i, SESSION_INDEX);
   /*
  risultato:
   Symbol GBPUSD, Trade session 0:
   - Monday     00:15 - 23:55
   - Tuesday    00:15 - 23:55
   - Wednesday  00:15 - 23:55
   - Thursday   00:15 - 23:55
   - Friday     00:15 - 23:55
   */
  }
//+--------------------------------------------------------------------------------------+
//| Invia gli orari di inizio e fine sessione di trading specificata |
//| per il simbolo specificato e il giorno della settimana al journal |
//+--------------------------------------------------------------------------------------+
void SymbolInfoSessionTradePrint(const string symbol, const ENUM_DAY_OF_WEEK day_of_week, const uint session_index)
  {
//--- dichiarare le variabili per registrare l'inizio e la fine della sessione di trading
   datetime date_from;  // ora di inizio sessione
   datetime date_to;    // ora di fine sessione
   
//--- ottenere dati dalla sessione di trading per simbolo e giorno della settimana
   if(!SymbolInfoSessionTrade(symbol, day_of_week, session_index, date_from, date_to))
     {
      Print("SymbolInfoSessionTrade() failed. Error ", GetLastError());
      return;
     }
     
//--- creare il nome del giorno della settimana dalla costante di enumerazione
   string week_day=EnumToString(day_of_week);
   if(week_day.Lower())
      week_day.SetChar(0, ushort(week_day.GetChar(0)-32));
 
//--- inviare i dati per la sessione di trading specificata al journal
   PrintFormat("- %-10s %s - %s", week_day, TimeToString(date_from, TIME_MINUTES), TimeToString(date_to, TIME_MINUTES));
  }