StructToTime

datetime  StructToTime(
   MqlDateTime&  dt_struct      // struttura della data e dell'ora
   );

#property script_show_inputs
 
input int   InpYear  =  0;    // Anno
input int   InpMonth =  0;    // Mese
input int   InpDay   =  0;    // Giorno
input int   InpHour  =  0;    // Ora
input int   InpMin   =  0;    // Minuti
input int   InpSec   =  0;    // Secondi
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- regola i valori inseriti e li scrive nelle variabili
   int year =  (InpYear<1970 ? 1970 : InpYear); // Se l'anno inserito è inferiore a 1970, allora viene utilizzato 1970
   int month=  (InpMonth<1 ?  1  :  InpMonth > 12  ?  12 :  InpMonth);
   int day  =  (InpDay  <1 ?  1  :  InpDay   > 31  ?  31 :  InpDay);
   int hour =  (InpHour <0 ?  0  :  InpHour  > 23  ?  23 :  InpHour);
   int min  =  (InpMin  <0 ?  0  :  InpMin   > 59  ?  59 :  InpMin);
   int sec  =  (InpSec  <0 ?  0  :  InpSec   > 59  ?  59 :  InpSec);
 
//-- visualizza i valori inseriti nel log
   PrintFormat("Entered date and time: %04u.%02u.%02u %02u:%02u:%02u", InpYear, InpMonth, InpDay, InpHour, InpMin, InpSec);
   
//-- visualizza i valori impostati nel log
   PrintFormat("Corrected date and time: %04u.%02u.%02u %02u:%02u:%02u", year, month, day, hour, min, sec);
   
//--- scrive i valori di input nei corrispondenti campi della struttura
   MqlDateTime time_struct={};
   time_struct.year= year;
   time_struct.mon = month;
   time_struct.day = day;
   time_struct.hour= hour;
   time_struct.min = min;
   time_struct.sec = sec;
   
//-- convertire la data e l'ora dalla struttura in una variabile di tipo datetime e
   datetime time = StructToTime(time_struct);
   
//--- visualizza il risultato della conversione da una variabile di tipo struttura MqlDateTime a un valore di tipo datetime
   Print("Converted date and time: ",TimeToString(time,TIME_DATE|TIME_MINUTES|TIME_SECONDS));
  /*
  risultati se vengono inseriti valori predefiniti pari a zero:
   Entered date and time: 0000.00.00 00:00:00
   Corrected date and time: 1970.01.01 00:00:00
   Converted date and time: 1970.01.01 00:00:00
   
  risultati se viene inserito il giorno sbagliato di Febbraio dell'anno in corso:
   Entered date and time: 2024.02.31 00:00:00
   Corrected date and time: 2024.02.31 00:00:00
   Converted date and time: 2024.03.02 00:00:00
  */
  }