SymbolInfoSessionTrade

bool  SymbolInfoSessionTrade(
   string            name,                // nome do ativo
   ENUM_DAY_OF_WEEK  day_of_week,         // dia da semana
   uint              session_index,       // índice da sessão
   datetime&         from,                // hora de início da sessão
   datetime&         to                   // hora de término da sessão
   );

#define SYMBOL_NAME   Symbol()
#define SESSION_INDEX 0
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- imprime o cabeçalho com o símbolo e o índice da sessão SESSION_INDEX e
//--- em um loop de segunda a sexta, imprime no log a hora de início e término da sessão de negociação
   PrintFormat("Symbol %s, Trade session %d:", SYMBOL_NAME, SESSION_INDEX);
   for(int i=MONDAY; i<SATURDAY; i++)
      SymbolInfoSessionTradePrint(SYMBOL_NAME, (ENUM_DAY_OF_WEEK)i, SESSION_INDEX);
   /*
   resultado:
   Symbol GBPUSD, Trade session 0:
   - Monday     00:15 - 23:55
   - Tuesday    00:15 - 23:55
   - Wednesday  00:15 - 23:55
   - Thursday   00:15 - 23:55
   - Friday     00:15 - 23:55
   */
  }
//+------------------------------------------------------------------+
//| Imprime no log o horário de início e término da sessão |
//| de negociação para o símbolo e dia da semana especificados |
//+------------------------------------------------------------------+
void SymbolInfoSessionTradePrint(const string symbol, const ENUM_DAY_OF_WEEK day_of_week, const uint session_index)
  {
//--- declaramos variáveis para armazenar o início e término da sessão de negociação
   datetime date_from;  // hora de início da sessão
   datetime date_to;    // hora de término da sessão
   
//--- obtemos os dados da sessão de negociação para o símbolo e dia da semana
   if(!SymbolInfoSessionTrade(symbol, day_of_week, session_index, date_from, date_to))
     {
      Print("SymbolInfoSessionTrade() failed. Error ", GetLastError());
      return;
     }
     
//--- criamos o nome do dia da semana a partir da constante de enumeração
   string week_day=EnumToString(day_of_week);
   if(week_day.Lower())
      week_day.SetChar(0, ushort(week_day.GetChar(0)-32));
 
//--- imprimimos no log os dados da sessão de negociação especificada
   PrintFormat("- %-10s %s - %s", week_day, TimeToString(date_from, TIME_MINUTES), TimeToString(date_to, TIME_MINUTES));
  }