A lona é legal! - página 73

Novo comentário
 
Vitaliy Kuznetsov #:

Alguém pode me informar se existe algum código pronto para a Edit Box to canvas.

Estou criando um painel de borracha e preciso desse elemento. Ao clicar nele, você precisa inserir e excluir números e ver um cursor piscando.

Se não houver, farei uma substituição normal ao clicar nele.

Alguém fez isso e houve problemas não com os gráficos, mas com a entrada - o MetaTrader "arrastou/processou" os botões usuais (Enter/Tab) e o pressionamento de teclas/Repetir/Liberar em geral.

É mais fácil pegar uma DLL e incorporar a janela de controle do Windows ou o Notepad.exe.

Alguns dias de preocupação com a falta de informações (coisas de baixo nível são difíceis de encontrar hoje em dia, há poucas delas), mas no final o código terá duas ordens de magnitude a menos e funcionará melhor.

 
Vitaliy Kuznetsov #:

Alguém pode me informar se existe algum código pronto para a Edit Box to canvas.

...

EasyAndFastGUI - biblioteca para criação de interfaces gráficas >>>

Veja o arquivo TextBox.mqh

EasyAndFastGUI - библиотека для создания графических интерфейсов
EasyAndFastGUI - библиотека для создания графических интерфейсов
  • www.mql5.com
Библиотека EasyAndFastGUI дает возможность создавать графические интерфейсы для своих MQL-программ.
 
Obrigado a todos, vou tentar outras opções
 
Maxim Kuznetsov #:

Se alguém o fez, não houve problemas com os gráficos, mas com a entrada de dados - o MetaTrader "arrastou/processou" os botões usuais (Enter/Tab) e o pressionamento/repetição/liberação de teclas em geral.

É mais fácil pegar uma DLL e incorporar a janela de controle do Windows ou o Notepad.exe.

Alguns dias de preocupação com a falta de informações (coisas de baixo nível são difíceis de encontrar hoje em dia, há poucas delas), mas no final o código terá duas ordens de magnitude a menos e funcionará melhor.

A propósito, sobre o "zambed" e a lembrança de diferentes experimentos: as janelas são incorporadas, mas há problemas com o redesenho e a entrada. Simplesmente não é utilizável, eu parei no "fato de que potencialmente funciona"

Mas isso não é surpreendente - os EAs funcionam em uma faixa, a GUI do gráfico em outra e, aparentemente, também há coisas diferentes .
É necessário explicar o Windows de alguma forma para que todas as mensagens necessárias sejam enviadas e a renderização seja processada corretamente. Não é um design de GUI típico quando há um controle (em termos de win, afinal, é uma janela) que tem tudo em outra faixa.

É claro que estou em um beco sem saída aqui, pois a prática do Linux não é favorável. É necessário definir alguns (o quê?) sinalizadores para o processo Expert (em termos de sistema operacional, ele não é uma trilha de GUI, como parece, e parte dele simplesmente não voa para ele) e/ou puxar AttachThreadInput.

Se esse problema for resolvido, as perspectivas são boas para aqueles que não têm medo de DLLs:

- Será possível usar o Gtk/Qt/Lazarus com seus designers e gráficos realmente bons, para "diálogos dentro do gráfico" (e o nível superior é feito, mas nem sempre é conveniente, pois o usuário ainda trabalha com o gráfico)

- será possível criar suas próprias "guias" - dentro do MDI e, de "desenhar uma janela no gráfico" para "criar uma guia no MT", será necessário meio passo. Todos os tipos de placas/quadros não exigirão a abertura de um novo gráfico

Sim, em nível de hacking :-)

 
Vitaliy Kuznetsov #:

Alguém pode me informar se existe algum código pronto para a Edit Box to canvas.

Estou criando um painel de borracha e preciso desse elemento. Ao clicar nele, você precisa inserir e excluir números e ver um cursor piscando.

Se não houver, farei uma substituição normal ao clicar nele.

Exemplo de código desse EditCtrl (base)

//+------------------------------------------------------------------+
//|                                                     EditCtrl.mq5 |
//|                                  Copyright 2022, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2022, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"

#include <Canvas/Canvas.mqh>
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
class CControl : protected CCanvas
  {
public:

   bool              Create(int x,int y,int w,int h)
     {
      if(!CCanvas::CreateBitmapLabel("TEST_EDIT",x,y,w,h,COLOR_FORMAT_ARGB_NORMALIZE))
         return(false);
      if(!OnCreate())
         return(false);

      Update();
      return(true);
     }

   void              TimerSet(uint msec)
     {
      if(msec)
         EventSetMillisecondTimer(msec);
      else
         EventKillTimer();
     }

   void              Update(void)
     {
      OnDraw(this);
      CCanvas::Update();
     }

   virtual bool      OnCreate(void) { return(true); }
   virtual void      OnKeyDown(int key,uint flags) { }
   virtual void      OnTimer(void) { }
   virtual void      OnDraw(CCanvas &canvas) { }
  };
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
class CEditCtrl : public CControl
  {
protected:
   string            m_text;
   uint              m_cursor_pos;
   bool              m_cursor_visible;

public:
   virtual bool      OnCreate(void)
     {
      m_cursor_pos    =0;
      m_cursor_visible=true;
      m_text          ="";
      TimerSet(500);
      return(true);
     }

   virtual void      OnKeyDown(int key,uint flags)
     {
      short code;

      switch(key)
        {
         case 35: // END
            if(m_cursor_pos==m_text.Length())
               return;
            m_cursor_pos=m_text.Length();
            break;
         case 36: // HOME
            if(m_cursor_pos==0)
               return;
            m_cursor_pos=0;
            break;
         case 37: // LEFT
            if(m_cursor_pos==0)
               return;
            m_cursor_pos--;
            break;
         case 39: // RIGHT
            if(m_cursor_pos>=m_text.Length())
               return;
            m_cursor_pos++;
            break;
         default:
            if((code=TranslateKey(key))==-1)
               return;

            if(code<32)
              {
               if(code==8 && m_cursor_pos)
                 {
                  m_text=m_text.Substr(0,m_cursor_pos-1) + m_text.Substr(m_cursor_pos,-1);

                  if(--m_cursor_pos>m_text.Length())
                     m_cursor_pos=m_text.Length();
                     
                  break;
                 }

               return;
              }

            if(m_cursor_pos!=m_text.Length())
               m_text = m_text.Substr(0,m_cursor_pos) + "\xFFFF" + m_text.Substr(m_cursor_pos,m_text.Length());

            m_text.SetChar(m_cursor_pos,code);
            m_cursor_pos++;
            break;
        }

      Update();
     }

   virtual void      OnTimer(void)
     {
      m_cursor_visible=!m_cursor_visible;
      Update();
     }

   virtual void      OnDraw(CCanvas &canvas)
     {
      CCanvas::Erase(ARGB(255,255,255,255));

      if(m_text.Length())
         canvas.TextOut(0,0,m_text,ARGB(255,0,0,0));

      if(m_cursor_visible)
        {
         int x=0,y;

         if(m_cursor_pos)
            canvas.TextSize(m_text.Substr(0,m_cursor_pos),x,y);

         canvas.FillRectangle(x,0,x,canvas.Height(),ARGB(255,0,0,0));
        }
     }
  };

CEditCtrl ExtEditCtrl;
CControl *ExtInputFocus=&ExtEditCtrl;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(void)
  {
   ExtEditCtrl.Create(100,100,200,20);

   ChartSetInteger(0,CHART_QUICK_NAVIGATION,false);
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
  }
//+------------------------------------------------------------------+
//| Timer function                                                   |
//+------------------------------------------------------------------+
void OnTimer(void)
  {
   ExtInputFocus.OnTimer();
  }
//+------------------------------------------------------------------+
//| ChartEvent function                                              |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
                  const long &lparam,
                  const double &dparam,
                  const string &sparam)
  {
   if(id==CHARTEVENT_KEYDOWN)
      ExtInputFocus.OnKeyDown((int)lparam,(uint)sparam);
  }
//+------------------------------------------------------------------+
 
Ilyas #:

Exemplo de código desse EditCtrl (base)

Muito obrigado. Vou tentar fazer isso no MT5 um pouco mais tarde.

 
Ilyas #:

Exemplo de código do EditCtrl (base)

Obrigado, Ilyas, por um bom exemplo de tutorial de código de qualidade
 
Ilyas #:

Exemplo de código desse EditCtrl (base)

Existe alguma maneira de desativar o backspace para que o objeto não seja excluído?

 
Aleksei Beliakov #:

Existe alguma maneira de desativar o backspace para que o objeto não seja excluído?

int OnInit()
  {
   ChartSetInteger(0,CHART_EVENT_OBJECT_CREATE,true);   
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| ChartEvent function                                              |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
                  const long &lparam,
                  const double &dparam,
                  const string &sparam)
  {
   if(id==CHARTEVENT_OBJECT_CREATE)
     {
      ObjectSetInteger(0,sparam,OBJPROP_HIDDEN,true);
      ChartRedraw();
      Print(sparam);
     }
  }
 
Ilyas #:
Mesmo que eu defina essa propriedade, o objeto é excluído por backspace, talvez porque esteja selecionado?
Existe alguma maneira de colocar um objeto sobre outro objeto se o tempo de criação for menor?
Por exemplo, se eu criar um objeto de rótulo de bitmap e depois qualquer outro objeto, o bitmaplabel estará sob os objetos criados depois dele
Pergunta: Existe alguma maneira de colocar o rótulo de bitmap sobre os objetos criados depois dele, exceto excluir e criar novamente?
1...666768697071727374757677787980...93
Novo comentário