Erros, bugs, perguntas

Alexey Navoykov 2016.07.30 03:42 #16211

fxsaber:
Parece ser sobre as janelas por vezes não fechadas dos testes visuais. No entanto, não o consigo reproduzir. Está a funcionar agora.

Tem estado a testar ou a optimizar? Se este último, há de facto problemas com isto.

Koldun Zloy 2016.07.30 04:25 #16212

Karputov Vladimir:

Aqui está o script que traz o menu "Ficheiro" - item "Ligar à conta de negociação" - clique no botão "OK" - assim o terminal irá ligar-se à última conta de negociação que foi criada:

#ifndef  _IsX64
#define  HWND long
#define  HMENU long
#define  HBITMAP long
#define  ULONG_PTR long
#else
#define  HWND int
#define  HMENU int
#define  HBITMAP int
#define  ULONG_PTR int
#endif

_IsX64 não pode ser utilizado desta forma. Só é relevante em tempo de execução.

fxsaber 2016.07.30 07:26 #16213

Alexey Navoykov:

Tem estado a testar ou a optimizar? Se este último, há de facto problemas com isto.

Corridas únicas, não incluí a optimização.

Vladimir Karputov 2016.07.30 08:14 #16214

Koldun Zloy:

_IsX64 não pode ser utilizado desta forma. Só é importante em tempo de execução.

Obrigado pela dica. Corrigiu-o e fê-lo como um ficheiro de inclusão:

//+------------------------------------------------------------------+
//|                                          LoginToTradeAccount.mqh |
//|                              Copyright © 2016, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2016, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.00"
#property description "Library for clicks on the MetaTrader 5 menu \"File\" item \"Login to trading account\""
#property description "Библиотека для кликов по меню MetaTrader 5 \"Файл\" пункт \"Подключиться к торговому счёту\""

int number_menu=1;   //menu "File"; меню "Файл"
int item_menu=14;    //item "Login to trading account"; пункт "Подключиться к торговому счёту"

#define  GA_ROOT            0x00000002  // Retrieves the root window by walking the chain of parent windows
#define  WM_COMMAND         0x00000111
#define  BM_CLICK           0x000000F5

#import "user32.dll"
int  GetLastError();
//+------------------------------------------------------------------+
//| GetAncestor. Retrieves the handle to the ancestor of the         |
//| specified window. Возвращает хендл предка заданного окна         |
//+------------------------------------------------------------------+
//--- x64
long  GetAncestor(long hwnd,int gaFlags);
//--- x86
int  GetAncestor(int hwnd,int gaFlags);
//+------------------------------------------------------------------+
//| GetMenu. Retrieves a handle to the menu assigned to the          |
//| specified window. Возвращает хендл меню,                         |
//| назначенного указанному окну.                                    |
//+------------------------------------------------------------------+
//--- x64
long GetMenu(long hWnd);
//--- x86
int GetMenu(int hWnd);
//+------------------------------------------------------------------+
//| GetSubMenu. Retrieves a handle to the drop-down menu or submenu  |
//| activated by the specified menu item. Возвращает хендл           |
//| выпадающего меню или подменю указанного пункта меню.             |
//+------------------------------------------------------------------+
//--- x64
long GetSubMenu(long hMenu,int nPos);
//--- x86
int GetSubMenu(int hMenu,int nPos);
//+------------------------------------------------------------------+
//| GetMenuItemID. Retrieves the menu item identifier of a menu item |
//| located at the specified position in a menu. Возвращает          |
//| идентификатор пункта меню, расположенного в                      |
//| указанной позиции в меню.                                        |
//+------------------------------------------------------------------+
//--- x64
int   GetMenuItemID(long hMenu,int nPos);
//--- x86
int   GetMenuItemID(int hMenu,int nPos);
//+------------------------------------------------------------------+
//| PostMessageW. Places (posts) a message in the message queue      |
//| associated with the thread that created the specified window     |
//| and returns without waiting for the thread to process the        |
//| message. Размещает (публикует) сообщение в очереди сообщений,    |
//| связанной с потоком, который создал указанное окно и             |
//| возвращается, не дожидаясь потока, чтобы обработать сообщение.   |
//+------------------------------------------------------------------+
//--- x64
bool  PostMessageW(long hWnd,int Msg,int wParam,int lParam);
//--- x86
bool  PostMessageW(int hWnd,int Msg,int wParam,int lParam);
//+------------------------------------------------------------------+
//| GetLastActivePopup. Determines which pop-up window owned by the  |
//| specified window was most recently active. Определяет, какое     |
//| всплывающее окно, принадлежащие указанному окну, совсем недавно  |
//| было активным.                                                   |
//+------------------------------------------------------------------+
//--- x64
long  GetLastActivePopup(long hWnd);
//--- x86
int  GetLastActivePopup(int hWnd);
//+------------------------------------------------------------------+
//| GetDlgItem. Retrieves a handle to a control in the specified     |
//| dialog box. Возвращает хэндл элемента управления в               |
//| указанном диалоговом окне.                                       |
//+------------------------------------------------------------------+
//--- x64
long  GetDlgItem(long hDlg,int nIDDlgItem);
//--- x86
int  GetDlgItem(int hDlg,int nIDDlgItem);
#import
//+------------------------------------------------------------------+
//| Click on the item "Login to trading account"                     |
//| Клик на пункте "Подключиться к торговому счёту"                  |
//+------------------------------------------------------------------+
void LoginToTradeAccount()
  {
   long mainChartID=ChartID(); //returns the ID of the current chart; возвращает идентификатор текущего графика
   int hdlmainChartID=ChartWindowsHandle(mainChartID); //returns the Chart window handle (HWND); получает хэндл графика 

   if(_IsX64)
     {
      long hdlRoot=GetAncestor((long)hdlmainChartID,GA_ROOT);
      long hmenu=GetMenu(hdlRoot);
      long hsubmenu=GetSubMenu(hmenu,number_menu);
      int hpos=GetMenuItemID(hsubmenu,item_menu);
      PostMessageW(hdlRoot,WM_COMMAND,hpos,0);
      Sleep(2000);
      long hlastPopup=GetLastActivePopup(hdlRoot);
      long hOK=GetDlgItem(hlastPopup,0x00000001);
      PostMessageW(hOK,BM_CLICK,0,0);
     }
   else
     {
      int hdlRoot=GetAncestor(hdlmainChartID,GA_ROOT);
      int hmenu=GetMenu(hdlRoot);
      int hsubmenu=GetSubMenu(hmenu,number_menu);
      int hpos=GetMenuItemID(hsubmenu,item_menu);
      PostMessageW(hdlRoot,WM_COMMAND,hpos,0);
      Sleep(2000);
      int hlastPopup=GetLastActivePopup(hdlRoot);
      int hOK=GetDlgItem(hlastPopup,0x00000001);
      PostMessageW(hOK,BM_CLICK,0,0);
     }
  }
//+------------------------------------------------------------------+
//| The function gets the handle graphics                            |
//| Функция получает хэндл графика                                   |
//+------------------------------------------------------------------+
int ChartWindowsHandle(long chart_ID)
  {
//--- prepare the variable to get the property value
//--- подготовим переменную для получения значения свойства
   long result=-1;
//--- reset the error value
//--- сбросим значение ошибки
   ResetLastError();
//--- receive the property value
//--- получим значение свойства
   if(!ChartGetInteger(chart_ID,CHART_WINDOW_HANDLE,0,result))
     {
      //--- display the error message in Experts journal
      //--- выведем сообщение об ошибке в журнал "Эксперты"
      Print(__FUNCTION__+", Error Code = ",GetLastError());
     }
//--- return the value of the chart property
//--- вернем значение свойства графика
   return((int)result);
  }
//+------------------------------------------------------------------+

Arquivos anexados:

LoginToTradeAccount.mqh 7 kb

Vladimir Karputov 2016.07.30 14:23 #16215

Dmitri Custurov:
Infelizmente, nem sempre. Se não houver ligação durante muito tempo, o terminal mostra "Conta desactivada" e depois tem de fazer o login manualmente. Isto acontece, por exemplo, num fundo onde os servidores são normalmente desligados à noite.

Aqui está a solução: EA verifica periodicamente o estado da ligação ao servidor de negociação(TERMINAL_CONNECTED) e se o valor retornado for "0", chama (usando WIn API) menu "File", item "Connect to trade account". O ficheiro include no qual a função de clique do menu é implementada pode ser encontrado aqui. Exemplo de uma EA:

//+------------------------------------------------------------------+
//|                                           TestAccountDisable.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"

#include <LoginToTradeAccount.mqh>
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- create timer
   EventSetTimer(12);

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- destroy timer
   EventKillTimer();

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---

  }
//+------------------------------------------------------------------+
//| Timer function                                                   |
//+------------------------------------------------------------------+
void OnTimer()
  {
//---
   static bool cleaner=false;
   if(!cleaner)
     {
      long rezult=TerminalInfoInteger(TERMINAL_CONNECTED);
      Comment("TERMINAL_CONNECTED: ",IntegerToString(rezult));
      if(rezult==0)
         LoginToTradeAccount();
     }
   else
      Comment("");
   cleaner=!cleaner;
  }
//+------------------------------------------------------------------+

A EA verifica o estado da ligação de 12 em 12 segundos e apaga comentários de vez em quando.

[AVISO FECHADO!] Qualquer pergunta Perguntas de Iniciantes MQL5 Qualquer pergunta de novato,

TheXpert 2016.07.30 15:48 #16216

Não existe realmente uma definição?

Aliaksandr Yemialyanau 2016.07.31 05:40 #16217

Como é que ligo um ficheiro de matriz ao meu EA?

Primeiro, o guião escreve uma matriz:

string filename="mas.dat";
int handle=FileOpen(filename,FILE_BIN|FILE_WRITE);
FileWriteArray(handle,hol,0,4608);
FileClose(handle);

Conecto o ficheiro na EA:

#include <mas.dat>

Ao compilar, erros:

t ...' - o identificador é demasiado longo mas.dat 1 1

'' - símbolo desconhecido mas.dat 1 3015

Aleksey Vyazmikin 2016.07.31 09:04 #16218

Aliaksandr Yemialyanau:

Como é que ligo um ficheiro de matriz ao meu EA?

Primeiro, o guião escreve uma série:

Conecto o ficheiro na EA:

Ao compilar, erros:

??????????????????????????t ...' - o identificador é demasiado longo mas.dat 1 1

'' - símbolo desconhecido mas.dat 1 3015

É muito mais rápido ler todo o ficheiro da matriz na memória e depois trabalhar com ela - será por vezes mais rápido.

Dmitri Custurov 2016.07.31 10:17 #16219

Karputov Vladimir:

Aqui está a solução: EA verifica periodicamente o estado da ligação ao servidor de negociação(TERMINAL_CONNECTED) e se o valor retornado for "0", chama (usando WIn API) menu "File", item "Connect to trade account". O ficheiro include no qual a função de clique do menu é implementada pode ser encontrado aqui. Exemplo de uma EA:

O conselheiro verifica o estado da ligação de 12 em 12 segundos e apaga os comentários de vez em quando.

Muito obrigado pela solução fornecida. Tudo está a funcionar.

fxsaber 2016.07.31 10:18 #16220

Depuração de contas

#define  i ii

void OnTick()
{
  for (int i = 0; i < 5; i++)
    Print(i); // отладчик по Shift+F9 показывает не ii, а i, выдавая Unknown identifier
}

Erros, bugs, perguntas - página 1622