ドキュメントセクション
MQL5 リファレンスネットワーク関数SendNotification 

SendNotification

MetaQuotes ID が「通知」タブで指定されているモバイル端末にプッシュ通知を送信します。

bool  SendNotification(
  string  text          // 通知テキスト
  );

パラメータ

text

[in]  通知テキストメッセージの長さは 255 文字を超えることは出来ません。

戻り値

通知が正常に端末から送信された場合は true、失敗なら false。失敗したプッシュ後に通知をチェックした際、GetLastError () は次のいずれかのエラーを返します。

  • 4515 – ERR_NOTIFICATION_SEND_FAILED,
  • 4516 – ERR_NOTIFICATION_WRONG_PARAMETER,
  • 4517 – ERR_NOTIFICATION_WRONG_SETTINGS,
  • 4518 – ERR_NOTIFICATION_TOO_FREQUENT.

注意事項

SendNotification() 関数には厳格な使用制限が設定されており、呼び出しは毎秒 2 以下と毎分 10 以下に限られています。 使用頻度は動的に監視されます。制限違反の場合にはこの関数は無効にされることが出来ます。

SendNotification() 関数はストラテジーテスター内では使用できません。

例：

//+------------------------------------------------------------------+
//|                                             SendNotification.mq5 |
//|                                  Copyright 2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, MetaQuotes Ltd."
#property link     "https://www.mql5.com
#property version     "1.00"
 
#define   MESSAGE   "Test Message"
//+------------------------------------------------------------------+
//| スクリプトプログラム開始関数                                              |
//+------------------------------------------------------------------+
void OnStart(void)
 {
//--- 端末で通知を送信する権限を確認する
  if(!TerminalInfoInteger(TERMINAL_NOTIFICATIONS_ENABLED))
    {
    Print("Error. The client terminal does not have permission to send notifications");
    return;
    }
//--- 通知を送信する
  ResetLastError();
  if(!SendNotification(MESSAGE))
    Print("SendNotification() failed. Error ",GetLastError());
 }