Mt4 Fin de l'assistance.

Vitaly Muzichenko 2017.09.12 11:26 #421

Реter Konow:

Quel est votre résultat ?

D'où appelez-vous la fonction ?

//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
   Trading_on_new_bars_strategy();
  }

Реter Konow 2017.09.12 11:32 #422

Vitaly Muzichenko:

1. Remplacer le type bool par le type int du tableau All_bars_table[][7] ; au début où les variables globales sont déclarées.

2. Mettez l'appel à la minuterie, où il est dit "Voici votre code".

Maintenant je l'ai vérifié et il fonctionne sur EURUSD. En bref, cela fonctionne.

Toute question des nouveaux L'agonie du choix [ARCHIVE]Toute question de débutant,

Реter Konow 2017.09.12 11:39 #423

Voici la variante qui s'imprime sur la minute EURUSD :

//+------------------------------------------------------------------+
//|                                                  Новый бар 4.mq4 |
//|                                                      Peter Konow |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Peter Konow"
#property link      "https://www.mql5.com"
#property version   "1.00"
#property strict
//+------------------------------------------------------------------+
datetime Last_Bar_Time;

int    Periodicity = 25;
int    All_symbols;

string Symbols[];
int    Timeframes[7] = {PERIOD_M1,PERIOD_M5,PERIOD_M15,PERIOD_M30,PERIOD_H1,PERIOD_H4,PERIOD_D1};
int    All_Timeframes = 7;


int    All_bars_table[][7];
int    New_Bar_Events[][7];

//+------------------------------------------------------------------+
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- create timer
   EventSetMillisecondTimer(25);
   //-------------------------------------------------------------
   //Записываем время последнего бара на момент загрузки эксперта.  
   //Для корректного начала работы, робота нужно запустить на М1. 
   //-------------------------------------------------------------
   Last_Bar_Time = Time[0];
   //-------------------------------------------------------------   
   //Узнаем сколько символов есть в обзоре рынка.
   //---------------------------------------------------------
   All_symbols = SymbolsTotal(true);
   //---------------------------------------------------------   
   //Устанавливаем размер массива Symbols. Внутри него будут записаны
   //имена всех символов, которые есть в окне обзоре рынка.
   //---------------------------------------------------------
   ArrayResize(Symbols,All_symbols);
   //---------------------------------------------------------
   //Устанавливаем размеры массивов "All_bars_table[]" и "New_Bar_Events[]".
   //В массиве "All_bars_table[]" будет записыватся текущее количество баров каждого символа
   //и каждого таймфрейма. А в массиве "New_Bar_Events[]" устанавливаться флаги
   //события нового бара для каждого символа и каждого таймфрейма. 
   //---------------------------------------------------------
   ArrayResize(All_bars_table,All_symbols);
   ArrayResize(New_Bar_Events,All_symbols);
   //---------------------------------------------------------
   //Записываем наименования символов обзора рынка в массив "Symbols[]".
   //---------------------------------------------------------
   for(int a1 = 0; a1 < All_symbols; a1++)
     {
      Symbols[a1] = SymbolName(a1 + 1,true); 
      //Возможно, нумерация символов в обзора рынка идет с нуля.
      //Тогда: Symbols[a1] = SymbolName(a1,true);
     }
   //---------------------------------------------------------
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- destroy timer
   EventKillTimer();
      
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {

  }
//+------------------------------------------------------------------+
//| Timer function                                                   |
//+------------------------------------------------------------------+
void OnTimer()
{
 static bool Start_count;
 static int  Current_period;
 //---------------------------
 //Нам нужен корректный старт отсчета. Это должно быть время начала бара.
 //---------------------------
 if(!Start_count && Last_Bar_Time != Time[0])Start_count = true; 
 //--------------------------- 
 if(Start_count)Current_period++;
 //--------------------------- 
 //В следующем цикле, мы будем обращатся к функции iBars для получения количества баров на 
 //каждом из символов и таймфреймов, которые будем проходить в цикле.
 //Далее, будем сравнивать записанное количество баров с текущим и при 
 //наличии разницы установим флаг события нового бара в массив "New_Bar_Events[]".
 //---------------------------
 if(Current_period*Periodicity >= 1000)
   {
    for(int a1 = 0; a1 < All_symbols; a1++)
      {
       string This_symbol = Symbols[a1];
       //---------------------------------
       for(int a2 = 0; a2 < All_Timeframes; a2++)
         {
          int This_timeframe = Timeframes[a2];
          //------------------------------------------
          int All_current_bars = iBars(This_symbol,This_timeframe);
          //------------------------------------------
          if(All_current_bars > All_bars_table[a1][a2])
            {
             //------------------------------------------------------------
             //Если это не самая первая запись в массив All_bars_table,
             //то фиксируем событие нового бара.
             //------------------------------------------------------------
             if(All_bars_table[a1][a2])
               {
                New_Bar_Events[a1][a2]  = true;
               } 
             //------------------------------------------------------------
             //Устанавливаем новое значение текущего количества баров.
             //------------------------------------------------------------
             All_bars_table   [a1][a2]  = All_current_bars;
            }
          //------------------------------------------
         }
      }
    //---------
    Current_period = 0;
   }
 //-----------------------------------------------
 //Здесь наш код...
 //Здесь наш код...
 //Здесь наш код...
 Trading_on_new_bars_strategy();
 //-----------------------------------------------
 //После завершения всех вызовов на этом событии таймера
 //снимаем флаги событий нового бара.
 if(!Current_period)Refresh_new_bar_events_table();
 //-----------------------------------------------  
}
//+------------------------------------------------------------------+


//+------------------------------------------------------------------+
//Функция снимает флаги событий нового бара.
//Эта процедура осуществляется после выполнения всего пользовательского
//кода один раз в минуту. Вплоть до момента очищения массива флагов 
//новых баров, все функции могут их видеть обращаясь к массиву напрямую.
//+------------------------------------------------------------------+
void Refresh_new_bar_events_table()
{
 for(int a1 = 0; a1 < All_symbols; a1++)
   {
    for(int a2 = 0; a2 < All_Timeframes; a2++)
      {
       New_Bar_Events[a1][a2] = false;
      }
   }
}
//+------------------------------------------------------------------+


//+------------------------------------------------------------------+
//Пример использования событий нового бара в пользовательском функционал.
//Просто обращаемся к глобальному массиву "New_Bar_Events[a1][a2]" напрямую
//и используем событие в наших торговых алгоритмах.
//+------------------------------------------------------------------+
void Trading_on_new_bars_strategy()
{
  for(int a1 = 0; a1 < All_symbols; a1++)
   {
    string This_symbol    = Symbols[a1];
    //----------------------------------
    for(int a2 = 0; a2 < All_Timeframes; a2++)
      {
       bool   New_bar      = New_Bar_Events[a1][a2];
       int    This_timeframe = Timeframes[a2];
       //----------------------------------
       if(New_bar && This_symbol == "EURUSD" && This_timeframe == PERIOD_M1)
         {
          //Buy();
          Alert("New_bar !!!");
         }
       //---------------------------------- 
       if(New_bar && This_symbol == "AUDUSD" && This_timeframe == PERIOD_M30)
         {
          //Sell();
         }
       //----------------------------------        
      }
   }
}
//+------------------------------------------------------------------+

Vitaly Muzichenko 2017.09.12 12:12 #424

Реter Konow:

Voici une variante qui imprime sur l'EURUSD à la minute :

Ça marche, mais il faut le mettre sur une petite échelle de temps.

Néanmoins, je dois admettre que la solution OOP est plus jolie et qu'il y a plusieurs fois moins de code.

POURQUOI LES TRADERS PERDENT-ILS Quel est le problème L'apprentissage automatique dans la

Реter Konow 2017.09.12 12:27 #425

Vitaly Muzichenko:

Cela fonctionne, mais vous devez le faire sur une petite échelle de temps.

Néanmoins, il faut admettre que la solution OOP est plus jolie et qu'il y a plusieurs fois moins de code.

Utilisez ce que vous voulez.

Ne soyez pas ridicule - ce n'est pas gentil, pas gentil. Comparez-les en termes de consommation de ressources.

Vous n'avez pas besoin de l'inscrire sur un petit calendrier.

Au lieu de cela :

 if(!Start_count && Last_Bar_Time != Time[0])Start_count = true; 
 //--------------------------- 
 if(Start_count)Current_period++;
 //---------------------------

Laissez seulement :

Current_period++;

Quartier 6 FOREX - Tendances, prévisions Erreurs, bugs, questions

Реter Konow 2017.09.12 12:34 #426

Vitaly Muzichenko:

... et le code est plusieurs fois moindre.

Voici tout le code de la solution :

//+------------------------------------------------------------------+
//|                                                  Новый бар 4.mq4 |
//|                                                      Peter Konow |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Peter Konow"
#property link      "https://www.mql5.com"
#property version   "1.00"
#property strict
//+------------------------------------------------------------------+
int    Periodicity = 25;
int    All_symbols;

string Symbols[];
int    Timeframes[7] = {PERIOD_M1,PERIOD_M5,PERIOD_M15,PERIOD_M30,PERIOD_H1,PERIOD_H4,PERIOD_D1};
int    All_Timeframes = 7;


int    All_bars_table[][7];
int    New_Bar_Events[][7];

//+------------------------------------------------------------------+
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- create timer
   EventSetMillisecondTimer(25);
   //-------------------------------------------------------------   
   All_symbols = SymbolsTotal(true);
   //---------------------------------------------------------   
   ArrayResize(Symbols,All_symbols);
   //---------------------------------------------------------
   ArrayResize(All_bars_table,All_symbols);
   ArrayResize(New_Bar_Events,All_symbols);
   //---------------------------------------------------------
   for(int a1 = 0; a1 < All_symbols; a1++)Symbols[a1] = SymbolName(a1 + 1,true); 
   //---------------------------------------------------------
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- destroy timer
   EventKillTimer();
      
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {

  }
//+------------------------------------------------------------------+
//| Timer function                                                   |
//+------------------------------------------------------------------+
void OnTimer()
{
 static int  Current_period;
 //---------------------------
 Current_period++;
 //--------------------------- 
 if(Current_period*Periodicity >= 1000)
   {
    for(int a1 = 0; a1 < All_symbols; a1++)
      {
       string This_symbol = Symbols[a1];
       //---------------------------------
       for(int a2 = 0; a2 < All_Timeframes; a2++)
         {
          int This_timeframe = Timeframes[a2];
          //------------------------------------------
          int All_current_bars = iBars(This_symbol,This_timeframe);
          //------------------------------------------
          if(All_current_bars > All_bars_table[a1][a2])
            {
             if(All_bars_table[a1][a2])New_Bar_Events[a1][a2]  = true;
             All_bars_table   [a1][a2]  = All_current_bars;
            }
         }
      }
    //---------
    Current_period = 0;
   }
 //-----------------------------------------------
 
 //-----------------------------------------------
 if(!Current_period)Refresh_new_bar_events_table();
 //-----------------------------------------------  
}
//+------------------------------------------------------------------+


//+------------------------------------------------------------------+
void Refresh_new_bar_events_table()
{
 for(int a1 = 0; a1 < All_symbols; a1++)
   {
    for(int a2 = 0; a2 < All_Timeframes; a2++)
      {
       New_Bar_Events[a1][a2] = false;
      }
   }
}
//+------------------------------------------------------------------+

N'oubliez pas le code OOP caché. Il y a moins de code parce qu'on ne le voit pas !

Nikolai Semko 2017.09.12 15:56 #427

Si vous en avez besoin, voici une fonction multiplateforme fonctionnelle (pour MT5 et MT4).

Contrairement au code de Peter, il fonctionne et est un ordre de grandeur plus rapide.

//+---------------------------------------------------------------------------------------------------+
//|   Функция определения нового бара по всем ТФ всех инструментов в окне "Обзор рынка"               |
//|   два режима работы:                                                                              |
//|   - режим сбора информации, out=false (значение по умолчанию). Достаточно запустить IsNewBar();   |
//|   - режим вывода информации, out=true                                                             |
//|   tf - период таймфрейма, по умолчанию текущий ТФ (необходим только при выводе информации)        |
//|   Sym - символ инструмента, по умолчанию текущий символ (необходим только при выводе информации)  |
//+---------------------------------------------------------------------------------------------------+
bool IsNewBar(bool out=false,int tf=PERIOD_CURRENT,string Sym="")
  {
#ifdef __MQL5__
   static int allTF=21;
   static const ENUM_TIMEFRAMES TF[21]=
     {
      PERIOD_M1,PERIOD_M2,PERIOD_M3,PERIOD_M4,PERIOD_M5,PERIOD_M6,PERIOD_M10,PERIOD_M12,PERIOD_M15,PERIOD_M20,PERIOD_M30,
      PERIOD_H1,PERIOD_H2,PERIOD_H3,PERIOD_H4,PERIOD_H6,PERIOD_H8,PERIOD_H12,PERIOD_D1,PERIOD_W1,PERIOD_MN1
     };
#else
   static int allTF=9;
   static const ENUM_TIMEFRAMES TF[9]={PERIOD_M1,PERIOD_M5,PERIOD_M15,PERIOD_M30,PERIOD_H1,PERIOD_H4,PERIOD_D1,PERIOD_W1,PERIOD_MN1};
#endif
   static bool New_Bar_Events[];
   static long All_bars_table[]; // array of current bars
   static int N_Sym=0;
   static string symbName[]; // массив имен символов
   if(Sym=="") Sym=Symbol();
   int total=SymbolsTotal(true);
   if(total!=N_Sym) // если первый раз, или добавлен, или удален новый символ
     {
      ArrayResize(symbName,total);
      for(int i=0; i<total; i++) symbName[i]=SymbolName(i,true);
      ArrayResize(All_bars_table,allTF*total); ArrayInitialize(All_bars_table,0);
      ArrayResize(New_Bar_Events,allTF*total); ArrayInitialize(New_Bar_Events,false);
      N_Sym=total;
     }
   int n_cur=-1;
   for(int i=0; i<total; i++) if(Sym==symbName[i]){ n_cur=i; break;}
   if(n_cur<0) { Print("данного символа нет в списке MarketWatch(окошко слева - Обзор рынка)"); return(false);}
   if(out && N_Sym>0) // если режим вывода информации 
     {
      int curtf=0;
      if(tf==PERIOD_CURRENT) tf=_Period;
      while(TF[curtf]!=tf) curtf++;
      return (New_Bar_Events[n_cur*allTF+curtf]);
     }
// режим сбора информации
   for(int j=0,j1=0; j<total; j++,j1+=allTF) // перебор символов
      for(int i=0;i<allTF;i++)               // перебор таймфреймов
        {
         #ifdef __MQL5__
         long CurBars=SeriesInfoInteger(symbName[j],TF[i],SERIES_LASTBAR_DATE);
         #else
         long CurBars=iTime(symbName[j],TF[i],0);
         #endif
         if(All_bars_table[j1+i]<CurBars) // пришел новый бар
           {
            //if (All_bars_table[j1+i]>0) Print ("Новый бар: "+SymbolName(j,true)+"   "+EnumToString(TF[i]));
            All_bars_table[j1+i]=CurBars;
            New_Bar_Events[j1+i]=true;
           }
         else                       // еще не пришел новый бар
           {
            New_Bar_Events[j1+i]=false;
            if(i==0) for(;i<allTF;i++) New_Bar_Events[j1+i]=false;   // если минутный бар тот же, то нет смысла продолжать проверять старшие ТФ
           }
        }
   return(false);
  }

Dossiers :

TestIsNewBar.mq4 12 kb

TestIsNewBar.mq5 11 kb

Alexey Viktorov 2017.09.12 16:13 #428

Nikolai Semko:

Si vous en avez besoin, voici une fonction multiplateforme fonctionnelle (pour MT5 et MT4).

Contrairement au code de Peter, il fonctionne et est beaucoup plus rapide.

Le but était un, mais il a atteint un autre...

Si... quelqu'un, l'aperçu du marché montre TOUS les symboles, mais ne fonctionne qu'avec un seul ... Je préfère ne pas en dire plus...

Pourquoi essayez-vous de mesurer... le but était tout à fait différent..........

De la théorie à Testeur de stratégie MetaTrader Théorie du marché

Реter Konow 2017.09.12 16:38 #429

Alexey Viktorov:

L'objectif était un et la réalisation d'un autre...

Si quelqu'un a... quelqu'un, l'aperçu du marché montre TOUS les symboles et ne fonctionne qu'avec un seul... Je préfère ne pas en dire plus...

Pourquoi mesurer ... le but était tout autre.........

On m'a confié une tâche : créer un moyen de recevoir les événements d'une nouvelle barre d'un ensemble de symboles, sur un ensemble d'horizons temporels, sans OOP, et en faisant un code court et efficace.

Maintenant, dites-moi : ai-je atteint l'objectif ?

Conseiller en multidevise - Système ASCTrend Bienvenue au cours MQL4

Реter Konow 2017.09.12 16:48 #430

Nikolai Semko:

Si vous en avez besoin, voici une fonction multiplateforme fonctionnelle (pour MT5 et MT4).

Contrairement au code de Peter, il fonctionne et est beaucoup plus rapide.

Nikolaï, je vois que tu n'as pas négligé d'utiliser les noms de mes variables dans ton code :

New_Bar_Events

All_bars_table

Cela ne me dérange certainement pas, mais pourquoi "abaisser" mon code en dessous du vôtre ? ))

C'est pas sympa...

CCI simple avec filtre examen de trader Index de Hearst

Mt4 Fin de l'assistance. - page 43