Référence MQL5Méthodes sur les Matrices et les VecteursFonctionnalitésNorm

Norm

Retourne la norme de la matrice ou du vecteur.

double vector::Norm(
  const ENUM_VECTOR_NORM  norm,     // norme vectorielle
  const int                        norm_p=2  // nombre de p-norm en cas de VECTOR_NORM_P
   );

double matrix::Norm(
  const ENUM_MATRIX_NORM  norm      // norme matricielle
   );

Paramètres

la norme

[in] Ordre de la norme

Valeur de Retour

Norme de la matrice ou du vecteur.

Note

VECTOR_NORM_INF est la valeur absolue maximale parmi les éléments vectoriels.
VECTOR_NORM_MINUS_INF est la valeur absolue minimale d'un vecteur.
VECTOR_NORM_P est la norme P du vecteur. Si norm_p=0, alors c'est le nombre d'éléments vectoriels non nuls. norm_p=1 est la somme des valeurs absolues des éléments du vecteur. norm_p=2 est la racine carrée de la somme des carrés des valeurs des éléments vectoriels. La norme P peut être négative.
MATRIX_NORM_FROBENIUS est la racine carrée de la somme des carrés des valeurs des éléments de la matrice. La norme de Frobenius et la norme vectorielle P2 sont cohérentes.
MATRIX_NORM_SPECTRAL est la valeur maximale du spectre matriciel.
MATRIX_NORM_NUCLEAR est la somme des valeurs singulières de la matrice.
MATRIX_NORM_INF est le vecteur p1-norm maximal parmi les vecteurs verticaux de la matrice. La norme inf de la matrice et la norme inf du vecteur sont cohérentes.
MATRIX_NORM_MINUS_INF est le vecteur p1-norm minimum parmi les vecteurs verticaux de la matrice.
MATRIX_NORM_P1 est le vecteur p1-norm maximal parmi les vecteurs matriciels horizontaux.
MATRIX_NORM_MINUS_P1 est le vecteur minimal p1-norm parmi les vecteurs matriciels horizontaux.
MATRIX_NORM_P2 est la valeur singulière la plus élevée de la matrice.
MATRIX_NORM_MINUS_P2 est la plus petite valeur singulière d'une matrice.

Un algorithme simple pour calculer la norme P d'un vecteur en MQL5 :

double VectorNormP(const vector& v,int norm_value)
  {
   ulong  i;
   double norm=0.0;
//---
   switch(norm_value)
     {
      case 0 :
         for(i=0; i<v.Size(); i++)
            if(v[i]!=0)
               norm+=1.0;
         break;
      case 1 :
         for(i=0; i<v.Size(); i++)
            norm+=MathAbs(v[i]);
         break;
      case 2 :
         for(i=0; i<v.Size(); i++)
            norm+=v[i]*v[i];
         norm=MathSqrt(norm);
         break;
      default :
         for(i=0; i<v.Size(); i++)
            norm+=MathPow(MathAbs(v[i]),norm_value);
         norm=MathPow(norm,1.0/norm_value);
     }
//---
   return(norm);
  }

Exemple en MQL5 :

  matrix a= {{0, 1, 2, 3, 4, 5, 6, 7, 8}};
  a=a-4;
  Print("matrix a \n", a);
  a.Reshape(3, 3);
  matrix b=a;
  Print("matrix b \n", b);
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_FROBENIUS)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_INF)", b.Norm(MATRIX_NORM_INF));
  Print("b.Norm(MATRIX_NORM_MINUS_INF)", b.Norm(MATRIX_NORM_MINUS_INF));
  Print("b.Norm(MATRIX_NORM_P1)=)", b.Norm(MATRIX_NORM_P1));
  Print("b.Norm(MATRIX_NORM_MINUS_P1)=", b.Norm(MATRIX_NORM_MINUS_P1));
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_P2));
  Print("b.Norm(MATRIX_NORM_MINUS_P2)=", b.Norm(MATRIX_NORM_MINUS_P2));

  /*
  matrix a
  [[-4,-3,-2,-1,0,1,2,3,4]]
  matrix b
  [[-4,-3,-2]
  [-1,0,1]
  [2,3,4]]
  b.Norm(MATRIX_NORM_P2)=7.745966692414834
  b.Norm(MATRIX_NORM_FROBENIUS)=7.745966692414834
  b.Norm(MATRIX_NORM_INF)9.0
  b.Norm(MATRIX_NORM_MINUS_INF)2.0
  b.Norm(MATRIX_NORM_P1)=)7.0
  b.Norm(MATRIX_NORM_MINUS_P1)=6.0
  b.Norm(MATRIX_NORM_P2)=7.348469228349533
  b.Norm(MATRIX_NORM_MINUS_P2)=1.857033188519056e-16
  */

Exemple en Python :

import numpy as np
from numpy import linalg as LA
a = np.arange(9) - 4
print("a \n",a)
b = a.reshape((3, 3))
print("b \n",b)
print("LA.norm(b)=",LA.norm(b))
print("LA.norm(b, 'fro')=",LA.norm(b, 'fro'))
print("LA.norm(b, np.inf)=",LA.norm(b, np.inf))
print("LA.norm(b, -np.inf)=",LA.norm(b, -np.inf))
print("LA.norm(b, 1)=",LA.norm(b, 1))
print("LA.norm(b, -1)=",LA.norm(b, -1))
print("LA.norm(b, 2)=",LA.norm(b, 2))
print("LA.norm(b, -2)=",LA.norm(b, -2))

a
[-4 -3 -2 -1  0  1  2  3  4]
b
[[-4 -3 -2]
[-1  0  1]
[ 2  3  4]]
LA.norm(b)= 7.745966692414834
LA.norm(b, 'fro')= 7.745966692414834
LA.norm(b, np.inf)= 9.0
LA.norm(b, -np.inf)= 2.0
LA.norm(b, 1)= 7.0
LA.norm(b, -1)= 6.0
LA.norm(b, 2)= 7.3484692283495345
LA.norm(b, -2)= 1.857033188519056e-16

Size

Cond