MQL5 ReferansıMatris ve Vektör MetotlarıÖzelliklerNorm

Norm

Matrisin veya vektörün normunu geri döndürür.

double vector::Norm(
  const ENUM_VECTOR_NORM  norm,     // vektör normu türü
  const int                        norm_p=2  // VECTOR_NORM_P durumunda p sayısı
   );

double matrix::Norm(
  const ENUM_MATRIX_NORM  norm      // matris normu türü
   );

Parametreler

norm

[in] Norm türü.

Geri dönüş değeri

Matris veya vektör normu.

Not

VECTOR_NORM_INF, vektör elemanları arasındaki maksimum mutlak değerdir.
VECTOR_NORM_MINUS_INF, vektörün minimum mutlak değeridir.
VECTOR_NORM_P, vektörün p-normudur. norm_p=0, sıfır olmayan vektör elemanlarının sayısıdır. norm_p=1, vektör elemanlarının mutlak değerlerinin toplamıdır. norm_p=2, vektör elemanlarının karelerinin toplamının kareköküdür. p sayısı negatif olabilir.
MATRIX_NORM_FROBENIUS, matris elemanlarının karelerinin toplamının kareköküdür. Frobenius normu ve vektör 2-normu tutarlıdır.
MATRIX_NORM_SPECTRAL, matris spektrumunun maksimum değeridir.
MATRIX_NORM_NUCLEAR, matrisin tekil değerlerinin toplamıdır.
MATRIX_NORM_INF, matrisin dikey vektörleri arasında maksimum vektör 1-normudur. Matris inf-normu ve vektör inf-normu tutarlıdır.
MATRIX_NORM_MINUS_INF, matrisin dikey vektörleri arasında minimum vektör 1-normudur.
MATRIX_NORM_P1, matrisin yatay vektörleri arasında maksimum vektör 1-normudur.
MATRIX_NORM_MINUS_P1, matrisin yatay vektörleri arasında minimum vektör 1-normudur.
MATRIX_NORM_P2, matrisin maksimum tekil değeridir.
MATRIX_NORM_MINUS_P2, matrisin minimum tekil değeridir.

MQL5'te bir vektörün p-normunu hesaplamak için basit bir algoritma:

double VectorNormP(const vector& v,int norm_value)
  {
   ulong  i;
   double norm=0.0;
//---
   switch(norm_value)
     {
      case 0 :
         for(i=0; i<v.Size(); i++)
            if(v[i]!=0)
               norm+=1.0;
         break;
      case 1 :
         for(i=0; i<v.Size(); i++)
            norm+=MathAbs(v[i]);
         break;
      case 2 :
         for(i=0; i<v.Size(); i++)
            norm+=v[i]*v[i];
         norm=MathSqrt(norm);
         break;
      default :
         for(i=0; i<v.Size(); i++)
            norm+=MathPow(MathAbs(v[i]),norm_value);
         norm=MathPow(norm,1.0/norm_value);
     }
//---
   return(norm);
  }

MQL5 örneği:

  matrix a= {{0, 1, 2, 3, 4, 5, 6, 7, 8}};
  a=a-4;
  Print("matrix a \n", a);
  a.Reshape(3, 3);
  matrix b=a;
  Print("matrix b \n", b);
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_FROBENIUS)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_INF)", b.Norm(MATRIX_NORM_INF));
  Print("b.Norm(MATRIX_NORM_MINUS_INF)", b.Norm(MATRIX_NORM_MINUS_INF));
  Print("b.Norm(MATRIX_NORM_P1)=)", b.Norm(MATRIX_NORM_P1));
  Print("b.Norm(MATRIX_NORM_MINUS_P1)=", b.Norm(MATRIX_NORM_MINUS_P1));
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_P2));
  Print("b.Norm(MATRIX_NORM_MINUS_P2)=", b.Norm(MATRIX_NORM_MINUS_P2));

  /*
  matrix a
  [[-4,-3,-2,-1,0,1,2,3,4]]
  matrix b
  [[-4,-3,-2]
  [-1,0,1]
  [2,3,4]]
  b.Norm(MATRIX_NORM_P2)=7.745966692414834
  b.Norm(MATRIX_NORM_FROBENIUS)=7.745966692414834
  b.Norm(MATRIX_NORM_INF)9.0
  b.Norm(MATRIX_NORM_MINUS_INF)2.0
  b.Norm(MATRIX_NORM_P1)=)7.0
  b.Norm(MATRIX_NORM_MINUS_P1)=6.0
  b.Norm(MATRIX_NORM_P2)=7.348469228349533
  b.Norm(MATRIX_NORM_MINUS_P2)=1.857033188519056e-16
  */

Python örneği:

import numpy as np
from numpy import linalg as LA
a = np.arange(9) - 4
print("a \n",a)
b = a.reshape((3, 3))
print("b \n",b)
print("LA.norm(b)=",LA.norm(b))
print("LA.norm(b, 'fro')=",LA.norm(b, 'fro'))
print("LA.norm(b, np.inf)=",LA.norm(b, np.inf))
print("LA.norm(b, -np.inf)=",LA.norm(b, -np.inf))
print("LA.norm(b, 1)=",LA.norm(b, 1))
print("LA.norm(b, -1)=",LA.norm(b, -1))
print("LA.norm(b, 2)=",LA.norm(b, 2))
print("LA.norm(b, -2)=",LA.norm(b, -2))

a
[-4 -3 -2 -1  0  1  2  3  4]
b
[[-4 -3 -2]
[-1  0  1]
[ 2  3  4]]
LA.norm(b)= 7.745966692414834
LA.norm(b, 'fro')= 7.745966692414834
LA.norm(b, np.inf)= 9.0
LA.norm(b, -np.inf)= 2.0
LA.norm(b, 1)= 7.0
LA.norm(b, -1)= 6.0
LA.norm(b, 2)= 7.3484692283495345
LA.norm(b, -2)= 1.857033188519056e-16

Size

Cond