OnCalculate

int  OnCalculate(
   const int        rates_total,       // taille du tableau price[]
   const int        prev_calculated,   // nombre de barres gérées durant l'appel précédent
   const int        begin,             // numéro de l'indice dans le tableau price[] où les données utiles commencent
   const double&    price[]            // tableau de valeurs pour le calcul
   );

int  OnCalculate(
   const int        rates_total,       // taille des séries temporelles d'entrée
   const int        prev_calculated,   // nombre de barres gérées durant l'appel précédent
   const datetime&  time[],            // Tableau des heures
   const double&    open[],            // Tableau des prix Open
   const double&    high[],            // Tableau des prix High
   const double&    low[],             // Tableau des prix Low
   const double&    close[],           // Tableau des prix Close
   const long&      tick_volume[],     // Tableau du volume des ticks
   const long&      volume[],          // Tableau des volumes réels
   const int&       spread[]           // Tableau des spreads
   );

//+------------------------------------------------------------------+
//|                                           OnCalculate_Sample.mq5 |
//|                        Copyright 2018, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "Extrait du calcul de l'indicateur Momentum"
 
//---- paramètres de l'indicateur
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1
#property indicator_type1   DRAW_LINE
#property indicator_color1  Blue
//---- entrées
input int MomentumPeriod=14; // Période du calcul
//---- buffer de l'indicateur
double    MomentumBuffer[];
//--- variable globale pour stocker la période de calcul
int       IntPeriod;
//+------------------------------------------------------------------+
//| Fonction d'initialisation d'un indicateur personnalisé           |
//+------------------------------------------------------------------+
void OnInit()
  {
//--- vérification des paramètres d'entrée
   if(MomentumPeriod<0)
     {
      IntPeriod=14;
      Print("Le paramètre de la période a une valeur incorrecte. La valeur suivante est définie pour les calculs ",IntPeriod);
     }
   else
      IntPeriod=MomentumPeriod;
//---- buffers  
   SetIndexBuffer(0,MomentumBuffer,INDICATOR_DATA);
//---- nom de l'indicateur à afficher dans la fenêtre des Données et dans les sous-fenêtres
   IndicatorSetString(INDICATOR_SHORTNAME,"Momentum"+"("+string(IntPeriod)+")");
//--- définit l'indice de la barre de début de dessin
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,IntPeriod-1);
//--- définit 0.0 comme valeur vide qui ne sera pas dessinée
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);
//--- précision de l'affichage de l'indicateur
   IndicatorSetInteger(INDICATOR_DIGITS,2);
  }
//+------------------------------------------------------------------+
//|  Calcul de l'indicateur Momentum                                 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,     // taille du tableau price[] 
                const int prev_calculated, // nombre de barres gérées précédemment
                const int begin,           // indice du début des données significatives 
                const double &price[])     // tableau des valeurs
  {
//--- position initiale pour les calculs
   int StartCalcPosition=(IntPeriod-1)+begin;
//---- si les données de calcul sont insuffisantes
   if(rates_total<StartCalcPosition)
      return(0);  // sort avec la valeur zéro - l'indicateur n'est pas calculé
//--- début du dessin de l'indicateur
   if(begin>0)
      PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,StartCalcPosition+(IntPeriod-1));
//--- début des calculs, définit la position de départ
   int pos=prev_calculated-1;
   if(pos<StartCalcPosition)
      pos=begin+IntPeriod;
//--- boucle principale de calcul
   for(int i=pos;i<rates_total && !IsStopped();i++)
      MomentumBuffer[i]=price[i]*100/price[i-IntPeriod];
//--- exécution de OnCalculate terminée. Retourne la nouvelle valeur de prev_calculated pour le prochain appel
   return(rates_total);
  }