OnCalculate

int  OnCalculate(
   const int        rates_total,       // fiyat[] dizisi boyutu
   const int        prev_calculated,   // önceki çağrıda yönetilen bar sayısı
   const int        begin,             // Anlamlı verilerin başladığı fiyat dizisi endeks numarası
   const double&    price[]            // hesaplama için değer dizisi
   );

int  OnCalculate(
   const int        rates_total,       // girdi zaman serilerinin boyutu
   const int        prev_calculated,   // önceki çağrıda yönetilen bar sayısı
   const datetime&  time[],            // Açılış zamanı dizisi
   const double&    open[],            // Açılış fiyat dizisi
   const double&    high[],            // Yüksek fiyat dizisi
   const double&    low[],             // Düşük fiyat dizisi
   const double&    close[],           // Kapanış fiyat dizisi
   const long&      tick_volume[],     // Tik Hacim dizisi
   const long&      volume[],          // Gerçek hacim dizisi
   const int&       spread[]           // Spread dizisi
   );

//+------------------------------------------------------------------+
//|                                           OnCalculate_Sample.mq5 |
//|                        Copyright 2018, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "Örnek Momentum göstergesi hesaplaması"
 
//---- gösterge ayarları
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1
#property indicator_type1   DRAW_LINE
#property indicator_color1  Blue
//---- girdiler
input int MomentumPeriod=14; // Hesaplama zaman aralığı
//---- gösterge arabelleği
double    MomentumBuffer[];
//--- Hesaplama zaman aralığını saklamak için global değişkenler
int       IntPeriod;
//+------------------------------------------------------------------+
//| Özel gösterge başlatma fonksiyonu                                |
//+------------------------------------------------------------------+
void OnInit()
  {
//--- girdi parametrelerini kontrol et
   if(MomentumPeriod<0)
     {
      IntPeriod=14;
      Print("Zaman aralığı parametresi yanlış bir değere sahiptir. Aşağıdaki değer hesaplamalar için kullanılacaktır ",IntPeriod);
     }
   else
      IntPeriod=MomentumPeriod;
//---- arabellekler  
   SetIndexBuffer(0,MomentumBuffer,INDICATOR_DATA);
//---- DataWindow ve alt pencerede görüntülenecek gösterge ismi
   IndicatorSetString(INDICATOR_SHORTNAME,"Momentum"+"("+string(IntPeriod)+")");
//--- çizilmeye oradan başlanacak olan barın indeksini ayarla
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,IntPeriod-1);
//--- çizilmeyen boş bir değer olarak 0.0'ı ayarla
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);
//--- görüntülenecek gösterge hassasiyeti
   IndicatorSetInteger(INDICATOR_DIGITS,2);
  }
//+------------------------------------------------------------------+
//|  Momentum gösterge hesaplaması                                   |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,     // fiyat[] dizisi boyutu 
                const int prev_calculated, // önceki yönetilen bar sayısı
                const int begin,           // anlamlı verilerin başladığı yer 
                const double &price[])     // yönetim için veri dizisi
  {
//--- hesaplamalar için başlangıç pozisyonu
   int StartCalcPosition=(IntPeriod-1)+begin;
//---- eğer hesaplama verisi yetersizse
   if(rates_total<StartCalcPosition)
      return(0);  // sıfır değeri ile çık - gösterge hesaplanmaz
//--- doğru çizim başlar
   if(begin>0)
      PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,StartCalcPosition+(IntPeriod-1));
//--- hesaplamayı başlat, başlangıç pozisyonunu tanımla
   int pos=prev_calculated-1;
   if(pos<StartCalcPosition)
      pos=begin+IntPeriod;
//--- ana hesaplama döngüsü
   for(int i=pos;i<rates_total && !IsStopped();i++)
      MomentumBuffer[i]=price[i]*100/price[i-IntPeriod];
//--- OnCalculate gerçekleşimi tamamlandı. Sonraki çağrı için yeni prev_calculated değerini geri döndür
   return(rates_total);
  }