//--- description
#property description "Le script crée un rectangle sur le graphique."
#property description "Les coordonnées du point d'ancrage sont définies en"
#property description "pourcentage de la taille de la fenêtre du graphique"
//--- affichage de la fenêtre des paramètres d'entrée lors du lancement du script
#property script_show_inputs
//--- paramètres d'entrée du script
input string InpName="Rectangle"; // Nom du rectangle
input int InpDate1=40; // Date du premier point, %
input int InpPrice1=40; // Prix du premier point, %
input int InpDate2=60; // Date du second point, %
input int InpPrice2=60; // Prix du second point, %
input color InpColor=clrRed; // Couleur du rectangle
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // Style des lignes du rectangle
input int InpWidth=2; // Largeur des lignes du rectangle
input bool InpFill=true; // Remplissage du rectangle avec une couleur
input bool InpBack=false; // Rectangle en arrière plan
input bool InpSelection=true; // Mise en surbrillance pour déplacer
input bool InpHidden=true; // Caché dans la liste des objets
input long InpZOrder=0; // Priorité du clic de souris
//+----------------------------------------------------------------------------------------------------+
//| Crée un rectangle aux coordonnées données |
//+----------------------------------------------------------------------------------------------------+
bool RectangleCreate(const long chart_ID=0, // identifiant du graphique
const string name="Rectangle", // nom du rectangle
const int sub_window=0, // indice de sous-fenêtre
datetime time1=0, // heure du premier point
double price1=0, // prix du premier point
datetime time2=0, // heure du second point
double price2=0, // prix du second point
const color clr=clrRed, // couleur du rectangle
const ENUM_LINE_STYLE style=STYLE_SOLID, // style de lignes du rectangle
const int width=1, // largeur des lignes du rectangle
const bool fill=false, // remplissage du rectangle avec une couleur
const bool back=false, // en arrière-plan
const bool selection=true, // mise en surbrillance pour déplacer
const bool hidden=true, // caché dans la liste des objets
const long z_order=0) // priorité du clic de souris
{
//--- définit les coordonnées du point d'ancrage si elles ne sont pas définies
ChangeRectangleEmptyPoints(time1,price1,time2,price2);
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- crée un rectangle aux coordonnées données
if(!ObjectCreate(chart_ID,name,OBJ_RECTANGLE,sub_window,time1,price1,time2,price2))
{
Print(__FUNCTION__,
" : impossible de créer un rectangle ! Code d'erreur = ",GetLastError());
return(false);
}
//--- définit la couleur du rectangle
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- définit le style des lignes du rectangle
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- définit la largeur des lignes du rectangle
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- active (true) ou désactive (false) le mode de remplissage du rectangle
ObjectSetInteger(chart_ID,name,OBJPROP_FILL,fill);
//--- affiche en premier plan (false) ou en arrière-plan (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- active (true) ou désactive (false) le mode de mise en surbrillance du rectangle pour le déplacement
//--- lors de la création d'un objet graphique utilisant la fonction ObjectCreate, l'objet ne peut pas être
//--- mis en surbrillance et déplacé par défaut. Dans cette méthode, le paramètre de sélection
//--- est vrai par défaut, permettant de mettre en surbrillance et de déplacer l'objet
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- masque (true) ou affiche (false) le nom de l'objet graphique dans la liste des objets
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- définit la priorité pour recevoir l'événement d'un clic de souris dans le graphique
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Déplace le point d'ancrage du rectangle |
//+----------------------------------------------------------------------------------------------------+
bool RectanglePointChange(const long chart_ID=0, // identifiant du graphique
const string name="Rectangle", // nom du rectangle
const int point_index=0, // indice du point d'ancrage
datetime time=0, // coordonnée horaire du point d'ancrage
double price=0) // coordonnée prix du point d'ancrage
{
//--- si la position du point n'est pas définie, le déplace vers la barre courante du prix Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- déplace le point d'ancrage
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
" : impossible de déplacer le point d'ancrage ! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Supprime le rectangle |
//+----------------------------------------------------------------------------------------------------+
bool RectangleDelete(const long chart_ID=0, // identifiant du graphique
const string name="Rectangle") // nom du rectangle
{
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- supprime le rectangle
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": impossible de supprimer le rectangle ! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Vérifie les valeurs des points d'ancrage du rectangle et définit les valeurs |
//| par défaut des points vides |
//+----------------------------------------------------------------------------------------------------+
void ChangeRectangleEmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2)
{
//--- si l'heure du premier point n'est pas définie, elle sera définie sur la barre courante
if(!time1)
time1=TimeCurrent();
//--- si le prix du premier point n'est pas défini, il aura la valeur Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- si l'heure du second point n'est pas réglée, elle se trouve à 9 barres de la seconde
if(!time2)
{
//--- tableau pour recevoir l'heure d'ouverture des 10 dernières barres
datetime temp[10];
CopyTime(Symbol(),Period(),time1,10,temp);
//--- Positionne le deuxième point à 9 barres à gauche du premier
time2=temp[0];
}
//--- si le prix du deuxième point n'est pas défini, le déplace 300 points plus bas que le premier
if(!price2)
price2=price1-300*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
}
//+----------------------------------------------------------------------------------------------------+
//| Fonction de démarrage du script |
//+----------------------------------------------------------------------------------------------------+
void OnStart()
{
//--- vérifie l'exactitude des paramètres d'entrée
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100)
{
Print("Erreur ! Valeurs incorrectes des paramètres d'entrée !");
return;
}
//--- nombre de barres visibles dans la fenêtre du graphique
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- taille du tableau des prix
int accuracy=1000;
//--- tableaux pour stocker les valeurs de date et de prix à utiliser
//--- pour définir et changer les coordonnées des points d'ancrage du rectangle
datetime date[];
double price[];
//--- allocation mémoire
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- remplit le tableau de dates
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("N'a pas réussi à copier les valeurs de l'heure ! Code d'erreur = ",GetLastError());
return;
}
//--- remplit le tableau des prix
//--- trouve les valeurs les plus élevées et les plus faibles du graphique
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- définit un changement de prix et remplit le tableau
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- définit les points pour dessiner le rectangle
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
//--- crée un rectangle
if(!RectangleCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],InpColor,
InpStyle,InpWidth,InpFill,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- redéssine le graphique et attend 1 seconde
ChartRedraw();
Sleep(1000);
//--- maintenant, déplace les points d'ancrage du rectangle
//--- compteur de boucle
int h_steps=bars/2;
//--- déplace les points d'ancrage
for(int i=0;i<h_steps;i++)
{
//--- utilise les valeurs suivantes
if(d1<bars-1)
d1+=1;
if(d2>1)
d2-=1;
//--- décale les points
if(!RectanglePointChange(0,InpName,0,date[d1],price[p1]))
return;
if(!RectanglePointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- vérifie si l'exécution du script a été stoppée
if(IsStopped())
return;
//--- redessine le graphique
ChartRedraw();
// délai de 0,05 secondes
Sleep(50);
}
//--- délai de 1 seconde
Sleep(1000);
//--- compteur de boucle
int v_steps=accuracy/2;
//--- déplace les points d'ancrage
for(int i=0;i<v_steps;i++)
{
//--- utilise les valeurs suivantes
if(p1<accuracy-1)
p1+=1;
if(p2>1)
p2-=1;
//--- décale les points
if(!RectanglePointChange(0,InpName,0,date[d1],price[p1]))
return;
if(!RectanglePointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- vérifie si l'exécution du script a été stoppée
if(IsStopped())
return;
//--- redessine le graphique
ChartRedraw();
}
//--- délai de 1 seconde
Sleep(1000);
//--- supprime le rectangle du graphique
RectangleDelete(0,InpName);
ChartRedraw();
//--- délai de 1 seconde
Sleep(1000);
//---
}
|