//--- description
#property description "Le script dessine l'objet graphique \"Expansion de Fibonacci\"."
#property description "Les coordonnées du point d'ancrage sont définies en pourcentage de"
#property description "la taille de la fenêtre du graphique."
//--- affichage de la fenêtre des paramètres d'entrée lors du lancement du script
#property script_show_inputs
//--- paramètres d'entrée du script
input string InpName="FiboExpansion"; // nom de l'objet
input int InpDate1=10; // Date du premier point, %
input int InpPrice1=55; // Prix du premier point, %
input int InpDate2=30; // Date du second point, %
input int InpPrice2=10; // Prix du second point, %
input int InpDate3=80; // Date du troisième point, %
input int InpPrice3=75; // Prix du troisième point, %
input color InpColor=clrRed; // couleur de l'objet
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Style des lignes
input int InpWidth=2; // Largeur des lignes
input bool InpBack=false; // Objet en arrière plan
input bool InpSelection=true; // Mise en surbrillance pour déplacer
input bool InpRayLeft=false; // Prolongement de l'objet vers la gauche
input bool InpRayRight=false; // Prolongement de l'objet vers la droite
input bool InpHidden=true; // Caché dans la liste des objets
input long InpZOrder=0; // Priorité du clic de souris
//+----------------------------------------------------------------------------------------------------+
//| Crée l'Expansion de Fibonacci aux coordonnées données |
//+----------------------------------------------------------------------------------------------------+
bool FiboExpansionCreate(const long chart_ID=0, // identifiant du graphique
const string name="FiboExpansion", // nom du canal
const int sub_window=0, // indice de sous-fenêtre
datetime time1=0, // heure du premier point
double price1=0, // prix du premier point
datetime time2=0, // heure du deuxième point
double price2=0, // prix du deuxième point
datetime time3=0, // heure du troisième point
double price3=0, // prix du troisième point
const color clr=clrRed, // couleur de l'objet
const ENUM_LINE_STYLE style=STYLE_SOLID, // Style des lignes
const int width=1, // Largeur des lignes
const bool back=false, // en arrière plan
const bool selection=true, // mise en surbrillance pour le déplacement
const bool ray_left=false, // Prolongement de l'objet vers la gauche
const bool ray_right=false, // Prolongement de l'objet vers la droite
const bool hidden=true, // caché dans la liste des objets
const long z_order=0) // priorité pour le clic de souris
{
//--- définit les coordonnées du point d'ancrage si elles ne sont pas définies
ChangeFiboExpansionEmptyPoints(time1,price1,time2,price2,time3,price3);
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- Crée l'Expansion de Fibonacci aux coordonnées données
if(!ObjectCreate(chart_ID,name,OBJ_EXPANSION,sub_window,time1,price1,time2,price2,time3,price3))
{
Print(__FUNCTION__,
" : échec de création de l'objet \"Expansion de Fibonacci\"! Code d'erreur = ",GetLastError());
return(false);
}
//--- définit la couleur de l'objet
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- définit le style de la ligne
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- définit la largeur des lignes
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- affiche en premier plan (false) ou en arrière-plan (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- active (true) ou désactive (false) le mode de mise en surbrillance du canal pour le déplacement
//--- lors de la création d'un objet graphique utilisant la fonction ObjectCreate, l'objet ne peut pas être
//--- mis en surbrillance et déplacé par défaut. Dans cette méthode, le paramètre de sélection
//--- est vrai par défaut, permettant de mettre en surbrillance et de déplacer l'objet
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- active (true) ou désactive (false) le mode de prolongement de l'objet vers la gauche
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- active (true) ou désactive (false) le mode de prolongement de l'objet vers la droite
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- masque (true) ou affiche (false) le nom de l'objet graphique dans la liste des objets
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- définit la priorité pour recevoir l'événement d'un clic de souris dans le graphique
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Définit le nombre de niveaux et leurs paramètres |
//+----------------------------------------------------------------------------------------------------+
bool FiboExpansionLevelsSet(int levels, // nombre de lignes de niveaux
double &values[], // valeurs des lignes de niveaux
color &colors[], // couleurs des lignes de niveaux
ENUM_LINE_STYLE &styles[], // style des lignes de niveaux
int &widths[], // largeur des lignes de niveaux
const long chart_ID=0, // identifiant du graphique
const string name="FiboExpansion") // nom de l'objet
{
//--- vérifie les tailles des tableaux
if(levels!=ArraySize(colors) || levels!=ArraySize(styles) ||
levels!=ArraySize(widths) || levels!=ArraySize(widths))
{
Print(__FUNCTION__," : la taille du tableau ne correspond pas au nombre de niveaux, erreur !");
return(false);
}
//--- définit le nombre de niveaux
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELS,levels);
//--- définit les propriétés des niveaux dans la boucle
for(int i=0;i<levels;i++)
{
//--- valeur du niveau
ObjectSetDouble(chart_ID,name,OBJPROP_LEVELVALUE,i,values[i]);
//--- couleur du niveau
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELCOLOR,i,colors[i]);
//--- style du niveau
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELSTYLE,i,styles[i]);
//--- largeur du niveau
ObjectSetInteger(chart_ID,name,OBJPROP_LEVELWIDTH,i,widths[i]);
//--- description du niveau
ObjectSetString(chart_ID,name,OBJPROP_LEVELTEXT,i,"FE "+DoubleToString(100*values[i],1));
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Déplace le point d'ancrage de l'Expansion de Fibonacci |
//+----------------------------------------------------------------------------------------------------+
bool FiboExpansionPointChange(const long chart_ID=0, // identifiant du graphique
const string name="FiboExpansion", // nom de l'objet
const int point_index=0, // indice du point d'ancrage
datetime time=0, // coordonnées du point d'ancrage temporel
double price=0) // coordonnées du point d'ancrage prix
{
//--- si la position du point n'est pas définie, le déplace vers la barre courante du prix Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- déplace le point d'ancrage
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
" : impossible de déplacer le point d'ancrage ! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Supprime l'Expansion de Fibonacci |
//+----------------------------------------------------------------------------------------------------+
bool FiboExpansionDelete(const long chart_ID=0, // identifiant du graphique
const string name="FiboExpansion") // nom de l'objet
{
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- supprime l'objet
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
" : échec de suppression de l'objet \"Expansion de Fibonacci\"! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Vérifie les valeurs des points d'ancrage de l'Expansion de Fibonacci et définit la valeur |
//| par défaut des points vides |
//+----------------------------------------------------------------------------------------------------+
void ChangeFiboExpansionEmptyPoints(datetime &time1,double &price1,datetime &time2,
double &price2,datetime &time3,double &price3)
{
//--- si l'heure du troisième (droite) point n'est pas définie, il sera mis sur la barre courante
if(!time3)
time3=TimeCurrent();
//--- si le prix du troisième point n'est pas défini, il aura la valeur Bid
if(!price3)
price3=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- si l'heure du premier (gauche) point n'est pas définie, il est mis 9 barres à gauche du troisième
//--- tableau pour récupérer l'heure d'ouverture des 10 dernières barres
datetime temp[];
ArrayResize(temp,10);
if(!time1)
{
CopyTime(Symbol(),Period(),time3,10,temp);
//--- définit le premier point 9 barres à gauche du deuxième
time1=temp[0];
}
//--- si le prix du premier point n'est pas défini, il est égal à celui du troisième point
if(!price1)
price1=price3;
//--- si l'heure du deuxième point n'est pas définie, il est mis 7 barres à gauche du troisième
if(!time2)
time2=temp[2];
//--- si le prix du deuxième point n'est pas défini, le déplace 250 points plus bas que le premier
if(!price2)
price2=price1-250*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
}
//+----------------------------------------------------------------------------------------------------+
//| Fonction de démarrage du script |
//+----------------------------------------------------------------------------------------------------+
void OnStart()
{
//--- vérifie l'exactitude des paramètres d'entrée
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100 ||
InpDate3<0 || InpDate3>100 || InpPrice3<0 || InpPrice3>100)
{
Print("Erreur ! Valeurs incorrectes des paramètres d'entrée !");
return;
}
//--- nombre de barres visibles dans la fenêtre du graphique
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- taille du tableau des prix
int accuracy=1000;
//--- tableaux pour stocker les valeurs de date et de prix à utiliser
//--- pour définir et changer les coordonnées des points d'ancrage de l'objet
datetime date[];
double price[];
//--- allocation mémoire
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- remplit le tableau de dates
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("N'a pas réussi à copier les valeurs de l'heure ! Code d'erreur = ",GetLastError());
return;
}
//--- remplit le tableau des prix
//--- trouve les valeurs les plus élevées et les plus faibles du graphique
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- définit un changement de prix et remplit le tableau
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- définit les points pour dessiner l'Expansion de Fibonacci
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int d3=InpDate3*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
int p3=InpPrice3*(accuracy-1)/100;
//--- crée l'Expansion de Fibonacci
if(!FiboExpansionCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],date[d3],price[p3],
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- redéssine le graphique et attend 1 seconde
ChartRedraw();
Sleep(1000);
//--- déplace maintenant les points d'ancrage
//--- compteur de boucle
int v_steps=accuracy/10;
//--- déplace le premier point d'ancrage
for(int i=0;i<v_steps;i++)
{
//--- utilise la valeur suivante
if(p1>1)
p1-=1;
//--- déplace le point
if(!FiboExpansionPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- vérifie si l'exécution du script a été stoppée
if(IsStopped())
return;
//--- redessine le graphique
ChartRedraw();
}
//--- délai de 1 seconde
Sleep(1000);
//--- compteur de boucle
v_steps=accuracy/2;
//--- déplace le troisième point d'ancrage
for(int i=0;i<v_steps;i++)
{
//--- utilise la valeur suivante
if(p3>1)
p3-=1;
//--- déplace le point
if(!FiboExpansionPointChange(0,InpName,2,date[d3],price[p3]))
return;
//--- vérifie si l'exécution du script a été stoppée
if(IsStopped())
return;
//--- redessine le graphique
ChartRedraw();
}
//--- délai de 1 seconde
Sleep(1000);
//--- compteur de boucle
v_steps=accuracy*4/5;
//--- déplace le second point d'ancrage
for(int i=0;i<v_steps;i++)
{
//--- utilise la valeur suivante
if(p2<accuracy-1)
p2+=1;
//--- déplace le point
if(!FiboExpansionPointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- vérifie si l'exécution du script a été stoppée
if(IsStopped())
return;
//--- redessine le graphique
ChartRedraw();
}
//--- délai de 1 seconde
Sleep(1000);
//--- supprime l'objet du graphique
FiboExpansionDelete(0,InpName);
ChartRedraw();
//--- délai de 1 seconde
Sleep(1000);
//---
}
|
