Errores, fallos, preguntas

Alexey Navoykov 2016.07.30 03:42 #16211

fxsaber:
Parece que se trata de las ventanas a veces no cerradas de las pruebas visuales. Sin embargo, no puedo reproducirlo. Ya funciona.

Si se trata de esto último, efectivamente hay problemas con esto.

Koldun Zloy 2016.07.30 04:25 #16212

Karputov Vladimir:

Aquí está el script que llama al menú "Archivo" - elemento "Conectar a la cuenta de comercio" - haga clic en el botón "OK" - así el terminal se conectará a la última cuenta de comercio que fue autenticada:

#ifndef  _IsX64
#define  HWND long
#define  HMENU long
#define  HBITMAP long
#define  ULONG_PTR long
#else
#define  HWND int
#define  HMENU int
#define  HBITMAP int
#define  ULONG_PTR int
#endif

_IsX64 no se puede utilizar de esta manera. Sólo es relevante en tiempo de ejecución.

fxsaber 2016.07.30 07:26 #16213

Alexey Navoykov:

Si se trata de esto último, efectivamente hay problemas con esto.

Las carreras individuales, no incluí la optimización.

Vladimir Karputov 2016.07.30 08:14 #16214

Koldun Zloy:

_IsX64 no se puede utilizar de esta manera. Sólo importa en tiempo de ejecución.

Gracias por el consejo. Lo corregí y lo hice como un archivo de inclusión:

//+------------------------------------------------------------------+
//|                                          LoginToTradeAccount.mqh |
//|                              Copyright © 2016, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2016, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.00"
#property description "Library for clicks on the MetaTrader 5 menu \"File\" item \"Login to trading account\""
#property description "Библиотека для кликов по меню MetaTrader 5 \"Файл\" пункт \"Подключиться к торговому счёту\""

int number_menu=1;   //menu "File"; меню "Файл"
int item_menu=14;    //item "Login to trading account"; пункт "Подключиться к торговому счёту"

#define  GA_ROOT            0x00000002  // Retrieves the root window by walking the chain of parent windows
#define  WM_COMMAND         0x00000111
#define  BM_CLICK           0x000000F5

#import "user32.dll"
int  GetLastError();
//+------------------------------------------------------------------+
//| GetAncestor. Retrieves the handle to the ancestor of the         |
//| specified window. Возвращает хендл предка заданного окна         |
//+------------------------------------------------------------------+
//--- x64
long  GetAncestor(long hwnd,int gaFlags);
//--- x86
int  GetAncestor(int hwnd,int gaFlags);
//+------------------------------------------------------------------+
//| GetMenu. Retrieves a handle to the menu assigned to the          |
//| specified window. Возвращает хендл меню,                         |
//| назначенного указанному окну.                                    |
//+------------------------------------------------------------------+
//--- x64
long GetMenu(long hWnd);
//--- x86
int GetMenu(int hWnd);
//+------------------------------------------------------------------+
//| GetSubMenu. Retrieves a handle to the drop-down menu or submenu  |
//| activated by the specified menu item. Возвращает хендл           |
//| выпадающего меню или подменю указанного пункта меню.             |
//+------------------------------------------------------------------+
//--- x64
long GetSubMenu(long hMenu,int nPos);
//--- x86
int GetSubMenu(int hMenu,int nPos);
//+------------------------------------------------------------------+
//| GetMenuItemID. Retrieves the menu item identifier of a menu item |
//| located at the specified position in a menu. Возвращает          |
//| идентификатор пункта меню, расположенного в                      |
//| указанной позиции в меню.                                        |
//+------------------------------------------------------------------+
//--- x64
int   GetMenuItemID(long hMenu,int nPos);
//--- x86
int   GetMenuItemID(int hMenu,int nPos);
//+------------------------------------------------------------------+
//| PostMessageW. Places (posts) a message in the message queue      |
//| associated with the thread that created the specified window     |
//| and returns without waiting for the thread to process the        |
//| message. Размещает (публикует) сообщение в очереди сообщений,    |
//| связанной с потоком, который создал указанное окно и             |
//| возвращается, не дожидаясь потока, чтобы обработать сообщение.   |
//+------------------------------------------------------------------+
//--- x64
bool  PostMessageW(long hWnd,int Msg,int wParam,int lParam);
//--- x86
bool  PostMessageW(int hWnd,int Msg,int wParam,int lParam);
//+------------------------------------------------------------------+
//| GetLastActivePopup. Determines which pop-up window owned by the  |
//| specified window was most recently active. Определяет, какое     |
//| всплывающее окно, принадлежащие указанному окну, совсем недавно  |
//| было активным.                                                   |
//+------------------------------------------------------------------+
//--- x64
long  GetLastActivePopup(long hWnd);
//--- x86
int  GetLastActivePopup(int hWnd);
//+------------------------------------------------------------------+
//| GetDlgItem. Retrieves a handle to a control in the specified     |
//| dialog box. Возвращает хэндл элемента управления в               |
//| указанном диалоговом окне.                                       |
//+------------------------------------------------------------------+
//--- x64
long  GetDlgItem(long hDlg,int nIDDlgItem);
//--- x86
int  GetDlgItem(int hDlg,int nIDDlgItem);
#import
//+------------------------------------------------------------------+
//| Click on the item "Login to trading account"                     |
//| Клик на пункте "Подключиться к торговому счёту"                  |
//+------------------------------------------------------------------+
void LoginToTradeAccount()
  {
   long mainChartID=ChartID(); //returns the ID of the current chart; возвращает идентификатор текущего графика
   int hdlmainChartID=ChartWindowsHandle(mainChartID); //returns the Chart window handle (HWND); получает хэндл графика 

   if(_IsX64)
     {
      long hdlRoot=GetAncestor((long)hdlmainChartID,GA_ROOT);
      long hmenu=GetMenu(hdlRoot);
      long hsubmenu=GetSubMenu(hmenu,number_menu);
      int hpos=GetMenuItemID(hsubmenu,item_menu);
      PostMessageW(hdlRoot,WM_COMMAND,hpos,0);
      Sleep(2000);
      long hlastPopup=GetLastActivePopup(hdlRoot);
      long hOK=GetDlgItem(hlastPopup,0x00000001);
      PostMessageW(hOK,BM_CLICK,0,0);
     }
   else
     {
      int hdlRoot=GetAncestor(hdlmainChartID,GA_ROOT);
      int hmenu=GetMenu(hdlRoot);
      int hsubmenu=GetSubMenu(hmenu,number_menu);
      int hpos=GetMenuItemID(hsubmenu,item_menu);
      PostMessageW(hdlRoot,WM_COMMAND,hpos,0);
      Sleep(2000);
      int hlastPopup=GetLastActivePopup(hdlRoot);
      int hOK=GetDlgItem(hlastPopup,0x00000001);
      PostMessageW(hOK,BM_CLICK,0,0);
     }
  }
//+------------------------------------------------------------------+
//| The function gets the handle graphics                            |
//| Функция получает хэндл графика                                   |
//+------------------------------------------------------------------+
int ChartWindowsHandle(long chart_ID)
  {
//--- prepare the variable to get the property value
//--- подготовим переменную для получения значения свойства
   long result=-1;
//--- reset the error value
//--- сбросим значение ошибки
   ResetLastError();
//--- receive the property value
//--- получим значение свойства
   if(!ChartGetInteger(chart_ID,CHART_WINDOW_HANDLE,0,result))
     {
      //--- display the error message in Experts journal
      //--- выведем сообщение об ошибке в журнал "Эксперты"
      Print(__FUNCTION__+", Error Code = ",GetLastError());
     }
//--- return the value of the chart property
//--- вернем значение свойства графика
   return((int)result);
  }
//+------------------------------------------------------------------+

Archivos adjuntos:

LoginToTradeAccount.mqh 7 kb

Vladimir Karputov 2016.07.30 14:23 #16215

Dmitri Custurov:
Por desgracia, no siempre. Si no hay conexión durante mucho tiempo, el terminal muestra "Cuenta desactivada" y entonces hay que iniciar la sesión manualmente. Esto ocurre, por ejemplo, en un fondo donde los servidores suelen estar apagados por la noche.

Esta es la solución: el EA comprueba periódicamente el estado de la conexión con el servidor de comercio(TERMINAL_CONNECTED) y si el valor devuelto es "0", llama (usando la API de WIn) al menú "File", elemento "Connect to trade account". El archivo de inclusión donde se implementa la función de clic del menú se puede encontrar aquí. Ejemplo de EA:

//+------------------------------------------------------------------+
//|                                           TestAccountDisable.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2016, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"

#include <LoginToTradeAccount.mqh>
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- create timer
   EventSetTimer(12);

//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- destroy timer
   EventKillTimer();

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---

  }
//+------------------------------------------------------------------+
//| Timer function                                                   |
//+------------------------------------------------------------------+
void OnTimer()
  {
//---
   static bool cleaner=false;
   if(!cleaner)
     {
      long rezult=TerminalInfoInteger(TERMINAL_CONNECTED);
      Comment("TERMINAL_CONNECTED: ",IntegerToString(rezult));
      if(rezult==0)
         LoginToTradeAccount();
     }
   else
      Comment("");
   cleaner=!cleaner;
  }
//+------------------------------------------------------------------+

El asesor comprueba el estado de la conexión cada 12 segundos y borra los comentarios de vez en cuando.

Lectura de los búferes [¡Archivo!] Cualquier pregunta de [SERVICE DESK] ¡Error al

TheXpert 2016.07.30 15:48 #16216

¿Realmente no hay definición?

Aliaksandr Yemialyanau 2016.07.31 05:40 #16217

¿Cómo puedo conectar un archivo de matriz a mi EA?

En primer lugar, el script escribe un array:

string filename="mas.dat";
int handle=FileOpen(filename,FILE_BIN|FILE_WRITE);
FileWriteArray(handle,hol,0,4608);
FileClose(handle);

Conecto el archivo en el EA:

#include <mas.dat>

Al compilar, errores:

'??????????????????????????t????...' - el identificador es demasiado largo mas.dat 1 1

'' - símbolo desconocido mas.dat 1 3015

Errors, bugs, questions Preguntas de los principiantes [¡Archivo!] Cualquier pregunta de

Aleksey Vyazmikin 2016.07.31 09:04 #16218

Aliaksandr Yemialyanau:

¿Cómo puedo conectar un archivo de matriz a mi EA?

En primer lugar, el script escribe un array:

Conecto el archivo en el EA:

Al compilar, errores:

'??????????????????????????t????...' - el identificador es demasiado largo mas.dat 1 1

'' - símbolo desconocido mas.dat 1 3015

Es mucho más rápido leer todo el archivo de la matriz en la memoria y luego trabajar con él - será veces más rápido.

Dmitri Custurov 2016.07.31 10:17 #16219

Karputov Vladimir:

Esta es la solución: el EA comprueba periódicamente el estado de la conexión con el servidor de comercio(TERMINAL_CONNECTED) y si el valor devuelto es "0", llama (usando la API de WIn) al menú "File", elemento "Connect to trade account". El archivo de inclusión en el que se implementa la función de clic del menú se puede encontrar aquí. Ejemplo de EA:

El asesor comprueba el estado de la conexión cada 12 segundos y borra los comentarios de vez en cuando.

Muchas gracias por la solución aportada. Todo está funcionando.

fxsaber 2016.07.31 10:18 #16220

Depuración

#define  i ii

void OnTick()
{
  for (int i = 0; i < 5; i++)
    Print(i); // отладчик по Shift+F9 показывает не ii, а i, выдавая Unknown identifier
}

Errores, fallos, preguntas - página 1622