Fragen von Anfängern MQL5 MT5 MetaTrader 5 - Seite 1225

[[Gelöscht]]

Vitaly Muzichenko:

Für alle. Genauer gesagt wird im Diagrammfenster die in der Einstellung angegebene Anzahl von Balken angezeigt, die nicht vom Zeitrahmen abhängt.

P.S. Ich habe diesen Wert nie geändert, aber ich habe ihn gerade überprüft und gesehen, dass er nicht kleiner als 1000 eingestellt werden kann.

Sie müssen also mitiBars() prüfen?

[SEM]

Guten Tag. Das Skript funktioniert aus irgendeinem Grund nicht.

Wo liegt das Problem?

//+------------------------------------------------------------------+
//|                                                         test.mq5 |
//|                        Copyright 2020, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   
   if(!ChartSetInteger(0,CHART_IS_MAXIMIZED,true))
     {
      //--- выведем сообщение об ошибке в журнал "Эксперты"
      Print(__FUNCTION__+", Error Code = ",GetLastError());
      //return(false);
     };


  }
//+------------------------------------------------------------------+

[Vladimir Karputov]

Kommentare, die sich nicht auf dieses Thema beziehen, wurden nach "Fragen von MQL4 MT4 MetaTrader 4 Anfängern" verschoben.

[Vladimir Voronin]

Hallo Freunde!

Fragen:

1. Werden Sell Stop Limit-Orders auf der Maklerseite oder auf der Terminalseite platziert?

2. Wenn ich das Programm schließe, wird dann dieser Auftrag ausgelöst, wenn die Bedingungen erfüllt sind?

Handel an der MICEX-Aktienbörse. Vielen Dank im Voraus!

[Alexey Belyakov]

Guten Tag, liebe Programmierer. Frage zu MQL5

Wie implementiert man die Positionskontrolle in MetaTrader 5? Ich möchte nur eine offene Position auf einem Balken haben, d.h. die Position soll geschlossen werden, egal wo - auf welchem Balken, aber die Eröffnung soll nur auf einem Balken erfolgen.

Dieser Code wird völlig ignoriert. Wo liegt der Fehler?

if (OrderSelect(HistoryDealsTotal()-1))

{
datetime Cu=PositionsTotal();
int hd=iBarShift(Symbol(),_Period,Cu);
if (hd<=1)
{
return;
}
}

[Aleksey Vyazmikin]

Alexey Belyakov:

Guten Tag, liebe Programmierer. Frage zu MQL5

Wie implementiert man die Positionskontrolle in MetaTrader 5? Das bedeutet, dass die Position geschlossen wird, egal wo - auf welchem Balken, aber die Eröffnung sollte nur auf einem Balken erfolgen.

Am einfachsten ist es, den Zeitpunkt der Bareröffnung, zu dem die Position eröffnet wird, in der globalen Variable zu speichern und dann bei der Eröffnung einer neuen Position den Zeitpunkt der Bareröffnung zu überprüfen, wenn der Wert höher ist als der gespeicherte Wert, und dann eine Position zu eröffnen.

[Vladimir Karputov]

Alexey Belyakov:

Guten Tag, liebe Programmierer. Frage zu MQL5

Wie implementiert man die Positionskontrolle in MetaTrader 5? Ich möchte nur eine offene Position auf einem Balken haben, d.h. die Position soll geschlossen werden, egal wo - auf welchem Balken, aber die Eröffnung soll nur auf einem Balken erfolgen.

Dieser Code wird völlig ignoriert. Wo liegt der Fehler?

Fehler: Sie haben die Fliegen und die Koteletts verwechselt - Sie haben die FERNBESTELLUNGEN und die POSITIONEN verwechselt.

Um Verwirrung zu vermeiden, lesen Sie bitte die Referenz:Allgemeine Grundsätze

Die obige einfache Methode besteht darin, sich die Eröffnungszeit des aktuellen Balkens zu merken, wenn Sie eine Position eröffnen. Wenn Sie dann eine neue Position eröffnen wollen, prüfen Sie die gespeicherte Zeit und die Eröffnungszeit des aktuellen Balkens.

Die Speicherung des Zeitpunkts der Positionseröffnung ist inOnTradeTransaction praktisch:

//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- get transaction type as enumeration value
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- if transaction is result of addition of the transaction in history
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      if(HistoryDealSelect(trans.deal))
         m_deal.Ticket(trans.deal);
      else
         return;
      if(m_deal.Symbol()==m_symbol.Name() && m_deal.Magic()==InpMagic)
        {
         if(m_deal.DealType()==DEAL_TYPE_BUY || m_deal.DealType()==DEAL_TYPE_SELL)
           {
            if(m_deal.Entry()==DEAL_ENTRY_IN || m_deal.Entry()==DEAL_ENTRY_INOUT)
               m_last_deal_in=iTime(m_symbol.Name(),InpTimeFrame,0);
            int size_need_position=ArraySize(SPosition);
            if(size_need_position>0)
              {
               for(int i=0; i<size_need_position; i++)
                 {
                  if(SPosition[i].waiting_transaction)
                     if(SPosition[i].waiting_order_ticket==m_deal.Order())
                       {
                        Print(__FUNCTION__," Transaction confirmed");
                        SPosition[i].transaction_confirmed=true;
                        break;
                       }
                 }
              }
           }
        }
     }
  }

und stimmen den Zeitpunkt der Auslösung des Signals ab:

//+------------------------------------------------------------------+
//| Search trading signals                                           |
//+------------------------------------------------------------------+
bool SearchTradingSignals(void)
  {
   if(m_prev_bars==m_last_deal_in) // on one bar - only one deal
      return(true);

Beispiel aus dem Code vonOHLC Check 2

[Alexey Belyakov]

Irgendwie ist das ein bisschen trickreich..... Kein Problem in der ersten Phase "Erinnern Sie sich an die Öffnungszeit der aktuellen Bar".

Das war's:

if (PositionsTotal()==1)  // Здесь проверяю, что открыта одна позиция
{
datetime Cu=iTime(NULL,_Period,0);        // Здесь в переменную - время открытия бара при открытой позиции

Aber hier " bringen Sie die gespeicherte Zeit und die Öffnungszeit des aktuellen Taktes in Einklang".

Ich habe ungefähr das Gleiche getan. Sehen Sie sich das an:

if (PositionsTotal()==1)  // Здесь проверяю, что открыта одна позиция (или была открыта, неважно, любое торговое действие)
{
datetime Cu=iTime(NULL,_Period,0);        // Здесь в переменную - время открытия бара при открытой позиции
int hd=+iBarShift(Symbol(),_Period,Cu)+1;    // Здесь в переменную - бар на котором произошло открытие позиции 
if (hd>=1)                                //Здесь проверяем - если этих баров, больше чем один, то.......   
{
return; //....то зацикливанием программу, НО проблема только в return
}
}

Alles, was ich hier tun muss, ist eine Schleife wie "return(-1)", aber ich kann der Rückgabe wegen der Leere keinen Ausdruck zuweisen. Wie kann ich das umgehen? Wie kann man eine Schleife machen, aber nicht zurückkehren?

[Alexey Belyakov]

datetime PR=iTime(NULL,_Period,0);  // проверяю время открытие бара
if (PositionsTotal()==1)  
{
datetime TK=iTime(NULL,_Period,0);  // время открытия бара при открытой позиции                        
if (PR==TK)                         // сравниваю
{
return(true);  // НЕ катит true - ошибка 
}
}

Das hat auch nicht funktioniert.

[Vladimir Karputov]

Alexey Belyakov:

Irgendwie ist das ein bisschen trickreich..... Kein Problem in der ersten Phase "Erinnern Sie sich an die Öffnungszeit der aktuellen Bar".

Das war's:

Aber hier " überprüfen Sie die gespeicherte Zeit und die Öffnungszeit des aktuellen Balkens" Problem.

Ich habe ungefähr das Gleiche getan. Sehen Sie sich das an:

Alles, was ich hier tun muss, ist eine Schleife wie "return(-1)", aber ich kann der Rückgabe wegen der Leere keinen Ausdruck zuweisen. Wie kann ich das umgehen? Wie kann man eine Schleife machen, aber nicht zurückkehren?

Die Behandlung für Looping-Programme besteht darin, ihnen die Arme um den Hals zu schneiden. Damit Sie es in Zukunft nicht wieder tun müssen.

Hier ist, was Sie brauchen - das ganze Programm Körper, müssen Sie nur zu formalisieren Signalempfang:

//+------------------------------------------------------------------+
//|                              Example One position on one bar.mq5 |
//|                        Copyright 2020, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2020, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//---
#include <Trade\PositionInfo.mqh>
#include <Trade\Trade.mqh>
#include <Trade\SymbolInfo.mqh>
#include <Trade\DealInfo.mqh>
//---
CPositionInfo  m_position;                   // object of CPositionInfo class
CTrade         m_trade;                      // object of CTrade class
CSymbolInfo    m_symbol;                     // object of CSymbolInfo class
CDealInfo      m_deal;                       // object of CDealInfo class
//--- input parameters
input ulong    InpMagic             = 200;      // Magic number
//---
datetime m_prev_bars                = 0;        // "0" -> D'1970.01.01 00:00';
datetime m_last_deal_in             = 0;        // "0" -> D'1970.01.01 00:00';
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   if(!m_symbol.Name(Symbol())) // sets symbol name
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");
      return(INIT_FAILED);
     }
   RefreshRates();
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//--- we work only at the time of the birth of new bar
   datetime time_0=iTime(m_symbol.Name(),Period(),0);
   if(time_0==m_prev_bars)
      return;
   m_prev_bars=time_0;
   if(!RefreshRates())
     {
      m_prev_bars=0;
      return;
     }
//--- search for trading signals
   if(!SearchTradingSignals())
     {
      m_prev_bars=0;
      return;
     }
  }
//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- get transaction type as enumeration value
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- if transaction is result of addition of the transaction in history
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      if(HistoryDealSelect(trans.deal))
         m_deal.Ticket(trans.deal);
      else
         return;
      if(m_deal.Symbol()==m_symbol.Name() && m_deal.Magic()==InpMagic)
        {
         if(m_deal.DealType()==DEAL_TYPE_BUY || m_deal.DealType()==DEAL_TYPE_SELL)
           {
            if(m_deal.Entry()==DEAL_ENTRY_IN || m_deal.Entry()==DEAL_ENTRY_INOUT)
               m_last_deal_in=iTime(m_symbol.Name(),Period(),0);
           }
        }
     }
  }
//+------------------------------------------------------------------+
//| Search trading signals                                           |
//+------------------------------------------------------------------+
bool SearchTradingSignals(void)
  {
   if(m_prev_bars==m_last_deal_in) // on one bar - only one deal
      return(true);
//--- signal
//---
   return(false);
  }
//+------------------------------------------------------------------+
//| Refreshes the symbol quotes data                                 |
//+------------------------------------------------------------------+
bool RefreshRates()
  {
//--- refresh rates
   if(!m_symbol.RefreshRates())
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: ","RefreshRates error");
      return(false);
     }
//--- protection against the return value of "zero"
   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)
     {
      Print(__FILE__," ",__FUNCTION__,", ERROR: ","Ask == 0.0 OR Bid == 0.0");
      return(false);
     }
//---
   return(true);
  }
//+------------------------------------------------------------------+

Die Variable"m_prev_bars" speichert die Eröffnungszeit des aktuellen Balkens und die Variable"m_last_deal_in" speichert die Eröffnungszeit des Balkens, zu dem die Position eröffnet wurde.

Diese beiden Variablen werden im Block zum Abrufen von Signalen"SearchTradingSignals" verglichen.