//+------------------------------------------------------------------+
//| DRAW_COLOR_CANDLES.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "An indicator to demonstrate DRAW_COLOR_CANDLES."
#property description "It draws candlesticks of a selected symbol in a separate window"
#property description " "
#property description "The color and width of candlesticks, as well as the symbol are changed"
#property description "randomly every N ticks"
#property indicator_separate_window
#property indicator_buffers 5
#property indicator_plots 1
//--- 标图 ColorCandles
#property indicator_label1 "ColorCandles"
#property indicator_type1 DRAW_COLOR_CANDLES
//--- 定义8种用于填充蜡烛图的颜色（它们存储在指定数组）
#property indicator_color1 clrRed,clrBlue,clrGreen,clrYellow,clrMagenta,clrCyan,clrLime,clrOrange
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- 输入参数
input int N=5; // 改变类型的订单号数量
input int bars=500; // 显示的蜡烛图数量
input bool messages=false; // 在"EA交易"日志显示信息
//--- 指标缓冲区
double ColorCandlesBuffer1[];
double ColorCandlesBuffer2[];
double ColorCandlesBuffer3[];
double ColorCandlesBuffer4[];
double ColorCandlesColors[];
int candles_colors;
//--- 交易品种名称
string symbol;
//--- 存储颜色的数组包含14种元素
color colors[]=
{
clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod,
clrIndigo,clrLightBlue,clrAliceBlue,clrMoccasin,clrMagenta,clrCyan,clrMediumPurple
};
//+------------------------------------------------------------------+
//| 自定义指标初始化函数 |
//+------------------------------------------------------------------+
int OnInit()
{
//--- 如果柱形非常小 - 提前完成工作
if(bars<50)
{
Comment("Please specify a larger number of bars! The operation of the indicator has been terminated");
return(INIT_PARAMETERS_INCORRECT);
}
//--- 指标缓冲区映射
SetIndexBuffer(0,ColorCandlesBuffer1,INDICATOR_DATA);
SetIndexBuffer(1,ColorCandlesBuffer2,INDICATOR_DATA);
SetIndexBuffer(2,ColorCandlesBuffer3,INDICATOR_DATA);
SetIndexBuffer(3,ColorCandlesBuffer4,INDICATOR_DATA);
SetIndexBuffer(4,ColorCandlesColors,INDICATOR_COLOR_INDEX);
//--- 空值
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- 绘制柱形的交易品种名称
symbol=_Symbol;
//--- 设置交易品种的展示
PlotIndexSetString(0,PLOT_LABEL,symbol+" Open;"+symbol+" High;"+symbol+" Low;"+symbol+" Close");
IndicatorSetString(INDICATOR_SHORTNAME,"DRAW_COLOR_CANDLES("+symbol+")");
//---- 为蜡烛图填充颜色的颜色数量
candles_colors=8; // 请见注释#property indicator_color1 属性
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| 自定义指标迭代函数 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=INT_MAX-100;
//--- 计算订单号改变样式，颜色
ticks++;
//--- 如果足够数量的订单号被积累
if(ticks>=N)
{
//--- 选择来自市场报价窗口的新交易品种
symbol=GetRandomSymbolName();
//--- 改变格式
ChangeLineAppearance();
//--- 改变用于绘制蜡烛图的颜色
ChangeColors(colors,candles_colors);
int tries=0;
//--- 试图5 次填充缓冲区plot1的交易品种价格
while(!CopyFromSymbolToBuffers(symbol,rates_total,0,
ColorCandlesBuffer1,ColorCandlesBuffer2,ColorCandlesBuffer3,
ColorCandlesBuffer4,ColorCandlesColors,candles_colors)
&& tries<5)
{
//--- CopyFromSymbolToBuffers() 函数调用的计数器
tries++;
}
//--- 重置0计数器
ticks=0;
}
//--- 返回 prev_calculated值以便下次调用函数
return(rates_total);
}
//+------------------------------------------------------------------+
//| 填充指定蜡烛图 |
//+------------------------------------------------------------------+
bool CopyFromSymbolToBuffers(string name,
int total,
int plot_index,
double &buff1[],
double &buff2[],
double &buff3[],
double &buff4[],
double &col_buffer[],
int cndl_colors
)
{
//--- 在rates[] 数组中，我们将复制开盘价，最高价，最低价和收盘价
MqlRates rates[];
//--- 尝试计数器
int attempts=0;
//--- 已复制多少
int copied=0;
//--- 试图25次获得所需交易品种的时间帧
while(attempts<25 && (copied=CopyRates(name,_Period,0,bars,rates))<0)
{
Sleep(100);
attempts++;
if(messages) PrintFormat("%s CopyRates(%s) attempts=%d",__FUNCTION__,name,attempts);
}
//--- 如果复制足够数量的柱形失败
if(copied!=bars)
{
//--- 形成信息字符串
string comm=StringFormat("For the symbol %s, managed to receive only %d bars of %d requested ones",
name,
copied,
bars
);
//--- 在主图表窗口的注释中显示信息
Comment(comm);
//--- 显示信息
if(messages) Print(comm);
return(false);
}
else
{
//--- 设置交易品种的展示
PlotIndexSetString(plot_index,PLOT_LABEL,name+" Open;"+name+" High;"+name+" Low;"+name+" Close");
IndicatorSetString(INDICATOR_SHORTNAME,"DRAW_COLOR_CANDLES("+symbol+")");
}
//--- 初始化空值缓冲区
ArrayInitialize(buff1,0.0);
ArrayInitialize(buff2,0.0);
ArrayInitialize(buff3,0.0);
ArrayInitialize(buff4,0.0);
//--- 在每个订单号上复制缓冲区价格
for(int i=0;i<copied;i++)
{
//--- 计算缓冲区相应的标引
int buffer_index=total-copied+i;
//--- 写下缓冲区的价格
buff1[buffer_index]=rates[i].open;
buff2[buffer_index]=rates[i].high;
buff3[buffer_index]=rates[i].low;
buff4[buffer_index]=rates[i].close;
//--- 设置蜡烛图颜色
int color_index=i%cndl_colors;
col_buffer[buffer_index]=color_index;
}
return(true);
}
//+------------------------------------------------------------------+
//| 随机返回来自市场报价的交易品种 |
//+------------------------------------------------------------------+
string GetRandomSymbolName()
{
//--- 市场报价窗口中显示的交易品种数量
int symbols=SymbolsTotal(true);
//--- 列表中的交易品种位置 - 从0到交易品种的随机号
int number=MathRand()%symbols;
//--- 返回指定位置的交易品种名称
return SymbolName(number,true);
}
//+------------------------------------------------------------------+
//| 改变蜡烛图节段的颜色 |
//+------------------------------------------------------------------+
void ChangeColors(color &cols[],int plot_colors)
{
//--- 颜色数
int size=ArraySize(cols);
//---
string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
//--- 为每个颜色标引随机定义一个新的颜色
for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
{
//--- 获得随机数
int number=MathRand();
//--- 获得col[]数组的标引作为整数除法的余数
int i=number%size;
//--- 设置每个标引的颜色为 PLOT_LINE_COLOR属性
PlotIndexSetInteger(0, // 图形样式数量
PLOT_LINE_COLOR, // 属性标识符
plot_color_ind, // 颜色标引，我们在这里编写颜色
cols[i]); // 新颜色
//--- 编写颜色
comm=comm+StringFormat("CandleColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
ChartSetString(0,CHART_COMMENT,comm);
}
//---
}
//+------------------------------------------------------------------+
//| 改变蜡烛图的外观 |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- 形成蜡烛图属性信息的字符串
string comm="";
//--- 写下交易品种名称
comm="\r\n"+symbol+comm;
//--- 使用注释在图表上显示信息
Comment(comm);
}
|
