Кадрирование (вывод части) изображения

Для графических объектов с рисунками (OBJ_BITMAP_LABEL и OBJ_BITMAP) MQL5 позволяет настроить показ лишь части изображения, заданного свойством OBJPROP_BMPFILE. Для этого необходимо установить размер объекта (OBJPROP_XSIZE и OBJPROP_YSIZE) меньше размера изображения, а координаты верхнего левого угла видимого прямоугольного фрагмента задать с помощью целочисленных свойств OBJPROP_XOFFSET и OBJPROP_YOFFSET. Данные два свойства задают, соответственно, отступ по X и по Y в пикселях от левой и верхней границы исходного изображения.

Вывод части изображения в объект

Обычно подобный прием с использованием части большого изображения применяется для иконок инструментальных панелей (наборов кнопок, меню и т.п.): единый файл со всеми иконками обеспечивает более эффективное ресурсопотребление, чем множество мелких файлов с отдельными иконками.

Тестовый скрипт ObjectBitmapOffset.mq5 создает несколько панелей с картинками (OBJ_BITMAP_LABEL), причем для всех них указан один и тот же графический файл в свойстве OBJPROP_BMPFILE. Однако за счет свойств OBJPROP_XOFFSET и OBJPROP_YOFFSET все объекты отображают разные участки изображения.

void SetupBitmap(const int i, const int x, const int y, const int size,
   const string imageOn, const string imageOff = NULL)
{
   // создаем объект
   const string name = ObjNamePrefix + "Tool-" + (string)i;
   ObjectCreate(0, name, OBJ_BITMAP_LABEL, 0, 0, 0);
   ObjectSetInteger(0, name, OBJPROP_CORNER, CORNER_RIGHT_UPPER);
   ObjectSetInteger(0, name, OBJPROP_ANCHOR, ANCHOR_RIGHT_UPPER);
   // позиция и размер
   ObjectSetInteger(0, name, OBJPROP_XDISTANCE, x);
   ObjectSetInteger(0, name, OBJPROP_YDISTANCE, y);
   ObjectSetInteger(0, name, OBJPROP_XSIZE, size);
   ObjectSetInteger(0, name, OBJPROP_YSIZE, size);
   // смещение в исходной картинке, по которому читается i-й фрагмент
   ObjectSetInteger(0, name, OBJPROP_XOFFSET, i * size);
   ObjectSetInteger(0, name, OBJPROP_YOFFSET, 0);
   // общее изображение (файл)
   ObjectSetString(0, name, OBJPROP_BMPFILE, imageOn);
}

void OnStart()
{
   const int icon = 46; // размер одной иконки
   for(int i = 0; i < 7; ++i) // цикл по иконкам в файле
   {
      SetupBitmap(i, 10, 10 + i * icon, icon,
         "\\Files\\MQL5Book\\icons-322-46.bmp");
   }
}

В исходном изображении находится несколько мелких значков размером 46 на 46 пикселей. Скрипт "вырезает" их по одному и располагает по вертикали у правого края окна.

Ниже показан общий файл (/Files/MQL5Book/icons-322-46.bmp), и что получилось на графике.

BMP-файл с иконками

Объекты-кнопки с иконками на графике

Настройка изображений в объектах-картинках

Свойства поля ввода: выравнивание и "только чтение"