OrderSelect

bool  OrderSelect(
   ulong   ticket      // Ticket de ordem
   );

#define   EXPERT_MAGIC  123456
#define   OFFSET        50                      // desvio da ordem em relação ao preço atual, em pontos
#define   DIRECTION     ORDER_TYPE_BUY_LIMIT    // tipo de ordem
#define   VOLUME        1.0                     // volume
#define   DEVIATION     2              // desvio permitido do preço
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//-- declaração e inicialização da solicitação, resultado e variáveis
   MqlTradeRequest request={};
   MqlTradeResult  result ={};
   double          order_price=0;
   
//--- parâmetros para a colocação de uma ordem pendente
   request.action    = TRADE_ACTION_PENDING;                               //--- tipo de operação
   request.symbol    = _Symbol;                                            // símbolo
   request.volume    = volume;            // volume
   request.deviation = DEVIATION;         // desvio permitido em relação ao preço
   request.magic     = EXPERT_MAGIC;      // MagicNumber da ordem
   
//--- verificação do tipo de operação
   switch(DIRECTION)
     {
      case ORDER_TYPE_BUY_LIMIT :
        request.type = ORDER_TYPE_BUY_LIMIT;                               // tipo de ordem
        order_price  = SymbolInfoDouble(_Symbol, SYMBOL_ASK)-OFFSET*_Point;// preço para abertura 
        request.price= NormalizeDouble(order_price, _Digits);              // preço de abertura normalizado 
        break;
      case ORDER_TYPE_SELL_LIMIT :
        request.type = ORDER_TYPE_SELL_LIMIT;                              // tipo de ordem
        order_price  = SymbolInfoDouble(_Symbol, SYMBOL_BID)+OFFSET*_Point;// preço de abertura 
        request.price= NormalizeDouble(order_price, _Digits);              // preço de abertura normalizado 
        break;
      case ORDER_TYPE_BUY_STOP :
        request.type = ORDER_TYPE_BUY_STOP;                                // tipo de ordem
        order_price  = SymbolInfoDouble(_Symbol, SYMBOL_ASK)-OFFSET*_Point;// preço para abertura 
        request.price= NormalizeDouble(order_price, _Digits);              // preço de abertura normalizado 
        break;
      case ORDER_TYPE_SELL_STOP :
        request.type = ORDER_TYPE_SELL_STOP;                               // tipo de ordem
        order_price  = SymbolInfoDouble(_Symbol, SYMBOL_BID)+OFFSET*_Point;// preço de abertura 
        request.price= NormalizeDouble(order_price, _Digits);              // preço de abertura normalizado 
        break;
      default: // se a ordem selecionada não for pendente ou do tipo StopLimit
        Alert("This example is only for placing pending orders BuyLimit, SellLimit, BuyStop and SellStop");
        break;
     }
 
//--- enviamos a solicitação, se o envio falhar, imprimimos o código de erro e encerramos o trabalho
   if(!OrderSend(request, result))
     {
      Print("OrderSend error ", GetLastError());
      return;
     }
     
//--- imprimimos informações sobre a operação
   PrintFormat("Trade request result: retcode=%u, order=%I64u", result.retcode, result.order);
   
//--- obtemos o ticket da ordem do resultado da operação de negociação e selecionamos a ordem pelo ticket
   ulong ticket=result.order;
   ResetLastError();
   if(!OrderSelect(ticket))
     {
      PrintFormat("OrderSelect(%I64u) failed. Error %d", ticket, GetLastError());
      return;
     }
 
//--- imprimimos no log os dados da ordem selecionada pelo ticket
   ENUM_ORDER_TYPE   type  = (ENUM_ORDER_TYPE)OrderGetInteger(ORDER_TYPE);
   long              time  = OrderGetInteger(ORDER_TIME_SETUP_MSC);
   double            price = OrderGetDouble(ORDER_PRICE_OPEN);
   double            volume= OrderGetDouble(ORDER_VOLUME_CURRENT);
   string            symbol= OrderGetString(ORDER_SYMBOL);
   int               digits= (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
   PrintFormat("Current selected order: %s %.2f %s #%I64u at %.*f, %s",
               symbol, volume, OrderTypeDescription(type), ticket, digits, price, TimeMscToString(time));
   /*
   Resultado:
   Trade request result: retcode=10009, order=2811006719
   Current selected order: EURUSD 1.00 Buy Limit #2811006719 at 1.10550, 2024.09.04 10:38:28.563
   */
  }
//+------------------------------------------------------------------+
//| Retorna o tempo em milissegundos                                 |
//+------------------------------------------------------------------+
string TimeMscToString(const long time_msc, int flags=TIME_DATE|TIME_MINUTES|TIME_SECONDS)
  {
   return(TimeToString(time_msc/1000, flags) + "." + IntegerToString(time_msc %1000, 3, '0'));
  }
//+------------------------------------------------------------------+
//| Retorna a descrição do tipo de ordem                             |
//+------------------------------------------------------------------+
string OrderTypeDescription(const ENUM_ORDER_TYPE type)
  {
   switch(type)
     {
      case ORDER_TYPE_BUY              :  return("Buy");
      case ORDER_TYPE_SELL             :  return("Sell");
      case ORDER_TYPE_BUY_LIMIT        :  return("Buy Limit");
      case ORDER_TYPE_SELL_LIMIT       :  return("Sell Limit");
      case ORDER_TYPE_BUY_STOP         :  return("Buy Stop");
      case ORDER_TYPE_SELL_STOP        :  return("Sell Stop");
      case ORDER_TYPE_BUY_STOP_LIMIT   :  return("Buy Stop Limit");
      case ORDER_TYPE_SELL_STOP_LIMIT  :  return("Sell Stop Limit");
      default                          :  return("Unknown order type");
     }
  }