#define EXPERT_MAGIC 123456
#define OFFSET 50 // emri yerleştirmek için mevcut fiyattan puan cinsinden ofset
#define DIRECTION ORDER_TYPE_BUY_LIMIT // emir türü
#define VOLUME 1.0 // hacim
#define DEVIATION 2 // fiyattan izin verilen sapma
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//-- işlem talebini, sonucu ve değişkenleri bildir ve başlat
MqlTradeRequest request={};
MqlTradeResult result ={};
double order_price=0;
//--- bekleyen emir yerleştirme parametreleri
request.action = TRADE_ACTION_PENDING; // işlem türü
request.symbol = _Symbol; // sembol
request.volume = VOLUME; // hacim
request.deviation = DEVIATION; // fiyattan izin verilen sapma
request.magic = EXPERT_MAGIC; // emir sihirli sayısı
//--- işlem türünü kontrol et
switch(DIRECTION)
{
case ORDER_TYPE_BUY_LIMIT :
request.type = ORDER_TYPE_BUY_LIMIT; // emir türü
order_price = SymbolInfoDouble(_Symbol, SYMBOL_ASK)-OFFSET*_Point;// açılış fiyatı
request.price= NormalizeDouble(order_price, _Digits); // normalleştirilmiş açılış fiyatı
break;
case ORDER_TYPE_SELL_LIMIT :
request.type = ORDER_TYPE_SELL_LIMIT; // emir türü
order_price = SymbolInfoDouble(_Symbol, SYMBOL_BID)+OFFSET*_Point;// açılış fiyatı
request.price= NormalizeDouble(order_price,_Digits); // normalleştirilmiş açılış fiyatı
break;
case ORDER_TYPE_BUY_STOP :
request.type = ORDER_TYPE_BUY_STOP; // emir türü
order_price = SymbolInfoDouble(_Symbol, SYMBOL_ASK)+OFFSET*_Point;// açılış fiyatı
request.price= NormalizeDouble(order_price,_Digits); // normalleştirilmiş açılış fiyatı
break;
case ORDER_TYPE_SELL_STOP :
request.type = ORDER_TYPE_SELL_STOP; // emir türü
order_price = SymbolInfoDouble(_Symbol, SYMBOL_BID)-OFFSET*_Point;// açılış fiyatı
request.price= NormalizeDouble(order_price,_Digits); // normalleştirilmiş açılış fiyatı
break;
default: // beklemede olmayan veya Stop Limit emri seçilmişse
Alert("This example is only for placing pending orders BuyLimit, SellLimit, BuyStop and SellStop");
break;
}
//--- bir talep gönder. Talep gönderilemediyse, hata kodunu görüntüle ve operasyonu tamamla
if(!OrderSend(request, result))
{
Print("OrderSend error ", GetLastError());
return;
}
//--- işlem verilerini görüntüle
PrintFormat("Trade request result: retcode=%u, order=%I64u", result.retcode, result.order);
//--- işlem sonucundan emir fişini al ve emri fişe göre seç
ulong ticket=result.order;
ResetLastError();
if(!OrderSelect(ticket))
{
PrintFormat("OrderSelect(%I64u) failed. Error %d", ticket, GetLastError());
return;
}
//--- fiş ile seçilen emrin verilerini günlükte görüntüle
ENUM_ORDER_TYPE type = (ENUM_ORDER_TYPE)OrderGetInteger(ORDER_TYPE);
long time = OrderGetInteger(ORDER_TIME_SETUP_MSC);
double price = OrderGetDouble(ORDER_PRICE_OPEN);
double volume= OrderGetDouble(ORDER_VOLUME_CURRENT);
string symbol= OrderGetString(ORDER_SYMBOL);
int digits= (int)SymbolInfoInteger(symbol, SYMBOL_DIGITS);
PrintFormat("Current selected order: %s %.2f %s #%I64u at %.*f, %s",
symbol, volume, OrderTypeDescription(type), ticket, digits, price, TimeMscToString(time));
/*
sonuç:
Trade request result: retcode=10009, order=2811006719
Current selected order: EURUSD 1.00 Buy Limit #2811006719 at 1.10550, 2024.09.04 10:38:28.563
*/
}
//+------------------------------------------------------------------+
//| Milisaniyeli zamanı geri döndür |
//+------------------------------------------------------------------+
string TimeMscToString(const long time_msc, int flags=TIME_DATE|TIME_MINUTES|TIME_SECONDS)
{
return(TimeToString(time_msc/1000, flags) + "." + IntegerToString(time_msc %1000, 3, '0'));
}
//+------------------------------------------------------------------+
//| Emir türü açıklamasını geri döndür |
//+------------------------------------------------------------------+
string OrderTypeDescription(const ENUM_ORDER_TYPE type)
{
switch(type)
{
case ORDER_TYPE_BUY : return("Buy");
case ORDER_TYPE_SELL : return("Sell");
case ORDER_TYPE_BUY_LIMIT : return("Buy Limit");
case ORDER_TYPE_SELL_LIMIT : return("Sell Limit");
case ORDER_TYPE_BUY_STOP : return("Buy Stop");
case ORDER_TYPE_SELL_STOP : return("Sell Stop");
case ORDER_TYPE_BUY_STOP_LIMIT : return("Buy Stop Limit");
case ORDER_TYPE_SELL_STOP_LIMIT : return("Sell Stop Limit");
default : return("Unknown order type");
}
}
|