Referência MQL5Biblioteca PadrãoMatemáticaLógica difusaFunções de associaçãoCNormalMembershipFunction

CNormalMembershipFunction

Classe para implementar uma função de associação simétrica de Gauss com parâmetros B e Sigma.

Descrição

A função de associação simétrica de Gauss é gerada utilizando distribuição de Gauss. Em todo o domínio, a função é suave e tem valores diferentes de zero.

fuzzy_norm_function

Exemplo de código para plotagem do gráfico mostrado abaixo.

Declaração

class CNormalMembershipFuncion : public IMembershipFunction

Cabeçalho

#include <Math\Fuzzy\membershipfunction.mqh>

Hierarquia de herança

CObject

IMembershipFunction

CNormalMembershipFunction

Métodos de classe

Método de classe	Descrição
B	Retorna e define o centro da função de associação.
Sigma	Retorna e define o parâmetro da curvatura da função de associação.
GetValue	Calcula o valor da função de associação para o argumento especificado.

Métodos herdados da classe CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Exemplo

//+------------------------------------------------------------------+
//|                                     NormalMembershipFunction.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Create membership functions
CNormalMembershipFunction func1(5,0.5);
CNormalMembershipFunction func2(5,1);
CNormalMembershipFunction func3(5,3);
//--- Create wrappers for membership functions
double NormalMembershipFunction1(double x) { return(func1.GetValue(x)); }
double NormalMembershipFunction2(double x) { return(func2.GetValue(x)); }
double NormalMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- create graphic
   CGraphic graphic;
   if(!graphic.Create(0,"NormalMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"NormalMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("NormalMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- create curve
   graphic.CurveAdd(NormalMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[5, 0.0]");
   graphic.CurveAdd(NormalMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[5, 1]");
   graphic.CurveAdd(NormalMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[5, 3]");
//--- sets the X-axis properties
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- sets the Y-axis properties
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- plot
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue