DocumentaçãoSeções
Referência MQL5Indicadores CustomizadosIndicatorSetString 

IndicatorSetString

A função define o valor da propriedade do indicador correspondente. Propriedade do indicador deve ser do tipo string. Existem duas variantes da função.

Chamar especificando o identificador da propriedade.

bool  IndicatorSetString(
   int     prop_id,           // identificador
   string  prop_value         // valor a ser definido
   );

Chamar especificando o identificador e o modificador da propriedade.

bool  IndicatorSetString(
   int     prop_id,           // identificador
   int     prop_modifier,     // modificador
   string  prop_value         // valor a ser definido
   )

Parâmetros

prop_id

[in]  Identificador da propriedade do indicador. O valor pode ser um dos valores do enumerador ENUM_CUSTOMIND_PROPERTY_STRING.

prop_modifier

[in]  Modificador da propriedade específica. Somente as propriedades de nível requerem um modificador.

prop_value

[in]  Valor de propriedade.

Valor do Retorno

Em caso de execução bem sucedida, retorna true, do contrário - false.

Observação

Numeração das propriedades (modificadores) começa a partir de 1 (um) quando usa a diretiva de #property, enquanto que a função usa numeração a partir de (zero). No caso do número de nível ser definido incorretamente, o visor do indicador pode ser diferente do pretendido.

Por exemplo, na ordem para definir a descrição da primeira linha horizontal usar o índice zero:

  • IndicatorSetString(INDICATOR_LEVELTEXT, 0, "Primeiro Nível") - índice 0 é usado para definir a descrição de texto do primeiro nível.

Exemplo: indicador que define etiquetas de texto para as linhas horizontais do indicador.

Exemplo usando a função IndicatorSetString()

#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
//--- visualiza três níveis horizontais na janela separada
#property indicator_level1 30
#property indicator_level2 50
#property indicator_level3 70
//--- definir a cor dos níveis horizontais
#property indicator_levelcolor clrRed
//--- definir o estilo dos níveis horizontais
#property indicator_levelstyle STYLE_SOLID
//+------------------------------------------------------------------+
//| Função de inicialização do indicador customizado                 |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- definir as descrições dos níveis horizontais
   IndicatorSetString(INDICATOR_LEVELTEXT,0,"Primeiro Nível (índice 0)");
   IndicatorSetString(INDICATOR_LEVELTEXT,1,"Segundo Nível (índice 1)");
   IndicatorSetString(INDICATOR_LEVELTEXT,2,"Terceiro Nível (índice 2)");
//--- define o mome abreviado para o indicador
   IndicatorSetString(INDICATOR_SHORTNAME,"IndicatorSetString() Demo");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Função de iteração do indicador customizado                      |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   
//--- valor retorno de prev_calculated para a próxima chamada
   return(rates_total);
  }

Também Veja

Propriedades de Indicador Personalizado, Propriedades (#property) de Programa