MQL5 リファレンスカスタム指標IndicatorSetString

IndicatorSetString

この関数は、対応する指標プロパティの値を設定します。指標プロパティは string 型でなければなりません。この関数には 2 つのバージョンがあります。

プロパティ識別子との呼び出し

bool IndicatorSetString(
int prop_id, // 識別子
string prop_value // 設定する値
);

プロパティ識別子と修飾子との呼び出し

bool IndicatorSetString(
int prop_id, // 識別子
int prop_modifier, // 修飾子
string prop_value // 設定する値
）

パラメータ

prop_id

[in] 指標プロパティの識別子。値は ENUM_CUSTOMIND_PROPERTY_STRING 列挙のいずれかです。

prop_modifier

[in] 指定されたプロパティの修飾子。修飾子はレベルプロパティのみで必要です。

prop_value

[in] プロパティ値

戻り値

実行成功の場合は true、それ以外の場合は false

注意事項

#property ディレクティブの使用時にはプロパティ（修飾子）の番号付けは１から始まる一方、関数では番号付けが0から始まります。レベル番号が正しく設定されていない場合、指標の表示目的のものと異なる場合があります。

例えば、最初の水平ラインの記述を設定するにはゼロインデックスを使用します。

IndicatorSetString(INDICATOR_LEVELTEXT, 0, "First Level") - 最初のレベルの記述を設定するにはインデックス 0 を使用する

例：指標水平線にラベルを設定する指標

IndicatorSetString() 関数の使用例

#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
//--- 3 つの水平レベルを別々の指標ウィンドウに表示
#property indicator_level1 30
#property indicator_level2 50
#property indicator_level3 70
//--- 水平レベルの色を設定
#property indicator_levelcolor clrRed
//--- 水平レベルのスタイルを設定
#property indicator_levelstyle STYLE_SOLID
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数 |
//+------------------------------------------------------------------+
int OnInit()
{
//--- 水平レベルの記述を設定
IndicatorSetString(INDICATOR_LEVELTEXT,0,"First Level (index 0)");
IndicatorSetString(INDICATOR_LEVELTEXT,1,"Second Level (index 1)");
IndicatorSetString(INDICATOR_LEVELTEXT,2,"Third Level (index 2)");
//--- 指標の短縮名を設定
IndicatorSetString(INDICATOR_SHORTNAME,"IndicatorSetString() Demo");
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| カスタム指標の反復関数 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//---

//--- 次の呼び出しのために prev_calculated の値を返す
return(rates_total);
}

参照

カスタム指標プロパティ、プログラムのプロパティ（#property）

IndicatorSetInteger

PlotIndexSetDouble