FileReadArray

uint  FileReadArray(
   int    file_handle,               // 파일 핸들
   void&  array[],                   // 기록할 배열
   int    start=0,                   // 쓸 배열 포지션 시작
   int    count=WHOLE_ARRAY          // 읽기 카운트
   );

//--- 스크립트를 시작할 때 입력 매개 변수 창을 표시합니다
#property script_show_inputs
//--- 입력 매개 변수
input string InpFileName="data.bin";
input string InpDirectoryName="SomeFolder";
//+------------------------------------------------------------------+
//| 가격 데이터 저장 구조                                 |
//+------------------------------------------------------------------+
struct prices
  {
   datetime          date; // 날짜
   double            bid;  // 입찰가
   double            ask;  // 요청가
  };
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 구조 배열
   prices arr[];
//--- 파일 경로
   string path=InpDirectoryName+"//"+InpFileName;
//--- 파일 열기
   ResetLastError();
   int file_handle=FileOpen(path,FILE_READ|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      //--- 파일에서 배열로 모든 데이터를 읽음
      FileReadArray(file_handle,arr);
      //--- 배열 규모 수령
      int size=ArraySize(arr);
      //--- 배열로부터 데이터 출력
      for(int i=0;i<size;i++)
         Print("Date = ",arr[i].date," Bid = ",arr[i].bid," Ask = ",arr[i].ask);
      Print("Total data = ",size);
      //--- 파일 닫기
      FileClose(file_handle);
     }
   else
      Print("파일 열기 실패, 오류 ",GetLastError());
  }