MQL5 リファレンスファイル関数FileIsEnding

FileIsEnding

읽는 과정에서 파일의 끝을 정의합니다.

bool  FileIsEnding(
   int  file_handle      // 파일 핸들
   );

Parameters

file_handle

[in] FileOpen()에서 반환된 파일 설명자.

반환 값

이 함수는 파일 포인터를 읽거나 이동하는 과정에서 파일 끝에 도달하면 true를 반환합니다.

참고

파일의 끝을 정의하기 위해 함수는 파일의 다음 문자열 읽기를 시도합니다. 문자열이 없으면 함수는 true를 반환하고, 그렇지 않으면 false를 반환합니다.

예:

//--- 스크립트를 시작할 때 입력 매개 변수의 창을 표시합니다.
#property script_show_inputs
//--- 입력 매개 변수
input string InpFileName="file.txt";    // 파일명
input string InpDirectoryName="Data";   // 디렉토리명
input int    InpEncodingType=FILE_ANSI; // ANSI=32 또는 UNICODE=64
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 사용할 파일의 경로를 인쇄
   PrintFormat("Working %s\\Files\\ folder",TerminalInfoString(TERMINAL_DATA_PATH));
//--- 에러값 리셋
   ResetLastError();
//--- 읽기 목적으로 파일 열기(파일이 없는 경우 오류 발생).
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_TXT|InpEncodingType);
   if(file_handle!=INVALID_HANDLE)
     {
      //--- 파일 내용 인쇄
      while(!FileIsEnding(file_handle))
         Print(FileReadString(file_handle));
      //--- 파일 닫기
      FileClose(file_handle);
     }
   else
      PrintFormat("Error, code = %d",GetLastError());
  }

FileGetInteger

FileIsLineEnding