//+------------------------------------------------------------------+
//| DRAW_ZIGZAG.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "DRAW_ZIGZAG를 시연하기 위한 지표"
#property description "하루의 막대를 건너뛰고 \"saw\" 을 직선 세그먼트로 그립니다"
#property description "건너뛸 요일은 지표 시작 중이 임의로 선택됩니다"
#property description "세그먼트의 색상, 너비 및 스타일이 임의로 변경됩니다"
#property description " 모든 N 틱"
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots 1
//--- ZigZag 플롯
#property indicator_label1 "ZigZag"
#property indicator_type1 DRAW_ZIGZAG
#property indicator_color1 clrBlue
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- 매개변수 입력
input int N=5; // 변경할 틱의 수
//--- 지표 버퍼
double ZigZagBuffer1[];
double ZigZagBuffer2[];
//--- 지표가 플롯되지 않은 요일
int invisible_day;
//--- 색상을 저장할 배열
color colors[]={clrRed,clrBlue,clrGreen};
//--- 선 스타일을 저장할 배열
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| 사용자 지정 지표 초기화 함수 |
//+------------------------------------------------------------------+
int OnInit()
{
//--- 배열 및 지표 버퍼 바인딩
SetIndexBuffer(0,ZigZagBuffer1,INDICATOR_DATA);
SetIndexBuffer(1,ZigZagBuffer2,INDICATOR_DATA);
//--- 0 ~ 6사이의 임의 값을 가져오고, 이 날의 지표는 표시되지 않습니다
invisible_day=MathRand()%6;
//--- 0(빈) 값은 그리기에 포함되지 않습니다
PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//--- 0(빈) 값은 그리기에 포함되지 않습니다
PlotIndexSetString(0,PLOT_LABEL,"ZigZag1;ZigZag2");
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| 사용자 지정 지표 반복 함수 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- 틱을 계산하여 선의 스타일, 색상 및 너비 변경
ticks++;
//--- 충분한 수의 틱이 누적된 경우
if(ticks>=N)
{
//--- 선 속성 변경
ChangeLineAppearance();
//--- 틱 카운터를 0으로 재설정
ticks=0;
}
//--- 시간 구조는 각 막대의 요일을 가져오는 데 필요합니다
MqlDateTime dt;
//--- 계산 시작 위치
int start=0;
//--- 지표가 이전 틱에서 계산된 경우, 마지막 틱에서 한 틱으로 계산을 시작합니다
if(prev_calculated!=0) start=prev_calculated-1;
//--- 계산 루프
for(int i=start;i<rates_total;i++)
{
//--- 구조에 막대 오픈 시간 기록
TimeToStruct(time[i],dt);
//--- 이 막대의 요일이 invisible_day와 같은 경우
if(dt.day_of_week==invisible_day)
{
//--- 이 막대의 버퍼에 쓰기
ZigZagBuffer1[i]=0;
ZigZagBuffer2[i]=0;
}
//--- 요일이 정상이면 버퍼를 채웁니다
else
{
//--- 막대 수가 짝수인 경우
if(i%2==0)
{
//--- 첫 번째 버퍼에는 고가, 두 번째 버퍼에는 저가 쓰기
ZigZagBuffer1[i]=high[i];
ZigZagBuffer2[i]=low[i];
}
//--- 바의 수가 홀수입니다
else
{
//--- 역순으로 막대를 채웁니다
ZigZagBuffer1[i]=low[i];
ZigZagBuffer2[i]=high[i];
}
}
}
//--- 다음 호출을 위한 prev_calculated의 반환 값
return(rates_total);
}
//+------------------------------------------------------------------+
//| 지그재그 세그먼트의 모양 변경 |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- ZigZag 속성에 대한 정보 형성을 위한 문자열
string comm="";
//--- ZigZag 색상 변경 블록
int number=MathRand(); // 임의 숫자 가져오기
//--- 제수는 colors[] 배열의 크기와 같습니다
int size=ArraySize(colors);
//--- 정수 나눗셈의 나머지의 새로운 색상을 선택할 인덱스를 가져오기
int color_index=number%size;
//--- 색상을 PLOT_LINE_COLOR 속성으로 설정
PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- 선 색상 쓰기
comm=comm+"\r\n"+(string)colors[color_index];
//--- 선 너비 변경 블록
number=MathRand();
//--- 정수 나눗셈의 나머지 너비 가져오기
int width=number%5; // 너비는 0 ~ 4로 설정됩니다
//--- 색상을 PLOT_LINE_WIDTH 속성으로 설정
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- 선 너비 쓰기
comm=comm+"\r\nWidth="+IntegerToString(width);
//--- 선의 스타일을 변경하기 위한 블록
number=MathRand();
//--- 제수는 스타일 배열의 크기와 같습니다
size=ArraySize(styles);
//--- 정수 나눗셈의 나머지 항목으로 새 스타일을 선택할 인덱스를 가져오기
int style_index=number%size;
//--- 색상을 PLOT_LINE_COLOR 속성으로 설정
PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- 선 스타일 쓰기
comm="\r\n"+EnumToString(styles[style_index])+""+comm;
//--- 계산에 생략된 날짜에 대한 정보 추가
comm="\r\nNot plotted day - "+EnumToString((ENUM_DAY_OF_WEEK)invisible_day)+comm;
//--- 설명을 사용하여 차트에 정보 표시
Comment(comm);
}
|
