//+------------------------------------------------------------------+
//| DRAW_LINE.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "DRAW_LINE을 시연하기 위한 지표"
#property description "종가에서 지정된 색상의 선을 그립니다"
#property description "선의 색상, 너비 및 스타일이 임의로 변경됩니다"
#property description "모든 N 틱 후"
#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots 1
//--- 선 속성은 컴파일러 지시문을 사용하여 설정합니다
#property indicator_label1 "Line" // 데이터 창의의 플롯 이름
#property indicator_type1 DRAW_LINE // 플로팅 유형은 선입니다
#property indicator_color1 clrRed // 선 색상
#property indicator_style1 STYLE_SOLID // 선 스타일
#property indicator_width1 1 // 선 너비
//--- 매개변수 입력
input int N=5; // 변경할 틱의 수
//--- 플롯에 대한 지표 버퍼
double LineBuffer[];
//--- 색상을 저장할 배열
color colors[]={clrRed,clrBlue,clrGreen};
//--- 선 스타일을 저장할 배열
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| 사용자 지정 지표 초기화 함수 |
//+------------------------------------------------------------------+
int OnInit()
{
//--- 지표 버퍼 및 배열 바인딩
SetIndexBuffer(0,LineBuffer,INDICATOR_DATA);
//--- 모조 난수 생성기 초기화
MathSrand(GetTickCount());
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| 사용자 지정 지표 반복 함수 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- 틱을 계산하여 선의 스타일, 색상 및 너비 변경
ticks++;
//--- 틱의 임계 수가 누적된 경우
if(ticks>=N)
{
//--- 선 속성 변경
ChangeLineAppearance();
//--- 틱 카운터를 0으로 재설정
ticks=0;
}
//--- 지표 값 계산을 위한 블록
for(int i=0;i<rates_total;i++)
{
LineBuffer[i]=close[i];
}
//--- 함수의 다음 호출에 대해 prev_calculated 값을 반환
return(rates_total);
}
//+------------------------------------------------------------------+
//| 지표에 그려진 선 모양을 변경 |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- 라인 속성에 대한 정보를 구성하기 위한 문자열
string comm="";
//--- 선의 색상을 변경하기 위한 블록
//--- 난수 가져오기
int number=MathRand();
//--- 제수는 colors[] 배열의 크기와 같습니다
int size=ArraySize(colors);
//--- 정수 나눗셈의 나머지의 새로운 색상을 선택할 인덱스를 가져오기
int color_index=number%size;
//--- 색상을 PLOT_LINE_COLOR 속성으로 설정
PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- 선 색상 쓰기
comm=comm+(string)colors[color_index];
//--- 선 너비 변경 블록
number=MathRand();
//--- 정수 나눗셈의 나머지 너비 가져오기
int width=number%5; // 너비는 0 ~ 4로 설정됩니다
//--- 색상을 PLOT_LINE_WIDTH 속성으로 설정
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- 선 너비 쓰기
comm=comm+", Width="+IntegerToString(width);
//--- 선의 스타일을 변경하기 위한 블록
number=MathRand();
//--- 제수는 스타일 배열의 크기와 같습니다
size=ArraySize(styles);
//--- 정수 나눗셈의 나머지 항목으로 새 스타일을 선택할 인덱스를 가져오기
int style_index=number%size;
//--- 색상을 PLOT_LINE_COLOR 속성으로 설정
PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- 선 스타일 쓰기
comm=EnumToString(styles[style_index])+", "+comm;
//--- 설명을 사용하여 차트에 정보 표시
Comment(comm);
}
|