//--- 설명
#property description "스크립트는 \"편집\" 개체를 생성합니다."
//--- 스크립트 실행 중 입력 매개변수의 표시 창
#property script_show_inputs
//--- 스크립트의 입력 매개변수
input string InpName="Edit"; // 개체 이름
input string InpText="Text"; // 개체 텍스트
input string InpFont="Arial"; // 글꼴
input int InpFontSize=14; // 글꼴 크기
input ENUM_ALIGN_MODE InpAlign=ALIGN_CENTER; // 텍스트 정렬 유형
input bool InpReadOnly=false; // 편집 허용=
input ENUM_BASE_CORNER InpCorner=CORNER_LEFT_UPPER; // 고정하기 위한 차트 모서리
input color InpColor=clrBlack; // 텍스트 색상
input color InpBackColor=clrWhite; // 배경 색상
input color InpBorderColor=clrBlack; // 테두리 색상
input bool InpBack=false; // 배경 개체
input bool InpSelection=false; // 이동하려면 강조 표시
input bool InpHidden=true; // 개체 목록에 숨겨짐
input long InpZOrder=0; // 마우스 클릭 우선 순위
//+------------------------------------------------------------------+
//| 편집 개체 생성 |
//+------------------------------------------------------------------+
bool EditCreate(const long chart_ID=0, // 차트의 ID
const string name="Edit", // 개체 이름
const int sub_window=0, // 하위 창 인덱스
const int x=0, // X 좌표
const int y=0, // Y 좌표
const int width=50, // 너비
const int height=18, // 높이
const string text="Text", // 텍스트
const string font="Arial", // 글꼴
const int font_size=10, // 글꼴 크기
const ENUM_ALIGN_MODE align=ALIGN_CENTER, // 정렬 유형
const bool read_only=false, // 편집 능력
const ENUM_BASE_CORNER corner=CORNER_LEFT_UPPER, // 고정을 위한 차트 모서리
const color clr=clrBlack, // 텍스트 색상
const color back_clr=clrWhite, // background color
const color border_clr=clrNONE, // 테두리 색상
const bool back=false, // 배경에
const bool selection=false, // 이동하려면 강조 표시
const bool hidden=true, // 개체 목록에 숨겨짐
const long z_order=0) // 마우스 클릭 우선 순위
{
//--- 오류 값 재설정
ResetLastError();
//--- 편집 필드 생성
if(!ObjectCreate(chart_ID,name,OBJ_EDIT,sub_window,0,0))
{
Print(__FUNCTION__,
": \"편집\" 개체 생성 실패! Error code = ",GetLastError());
return(false);
}
//--- 개체 좌표 설정
ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x);
ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y);
//--- 개체 크기 설정
ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width);
ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height);
//--- 텍스트 설정
ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);
//--- 텍스트 글꼴 설정
ObjectSetString(chart_ID,name,OBJPROP_FONT,font);
//--- 글꼴 크기 설정
ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,font_size);
//--- 개체의 텍스트 정렬 유형 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ALIGN,align);
//--- 읽기 전용 모드의 활성화(true) 또는 비활성화(false) read-only mode
ObjectSetInteger(chart_ID,name,OBJPROP_READONLY,read_only);
//--- 지정된 개체 좌표를 기준으로 차트의 모서리 설정
ObjectSetInteger(chart_ID,name,OBJPROP_CORNER,corner);
//--- 텍스트 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 배경 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_BGCOLOR,back_clr);
//--- 테두리 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_BORDER_COLOR,border_clr);
//--- 전경(false) 또는 배경(true)에 표시
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 마우스를 사용하여 레이블 이동 모드 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 개체 목록에서 그래픽 개체 이름 숨기기(true) 또는 표시(false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 차트에서 마우스 클릭 이벤트 수신 우선 순위 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 편집 개체 이동 |
//+------------------------------------------------------------------+
bool EditMove(const long chart_ID=0, // 차트의 ID
const string name="Edit", // 개체 이름
const int x=0, // X 좌표
const int y=0) // Y 좌표
{
//--- 오류 값 재설정
ResetLastError();
//--- 개체 이동
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,x))
{
Print(__FUNCTION__,
": 개체의 X 좌표 이동 실패! Error code = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,y))
{
Print(__FUNCTION__,
": 개체의 Y 좌표 이동 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 편집 개체 크기 조정 |
//+------------------------------------------------------------------+
bool EditChangeSize(const long chart_ID=0, // 차트의 ID
const string name="Edit", // 개체 이름
const int width=0, // 너비
const int height=0) // 높이
{
//--- 오류 값 재설정
ResetLastError();
//--- 개체 크기 변경
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width))
{
Print(__FUNCTION__,
": 개체 너비 변경 실패! Error code = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height))
{
Print(__FUNCTION__,
": 개체 높이 변경 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 편집 개체의 텍스트 변경 |
//+------------------------------------------------------------------+
bool EditTextChange(const long chart_ID=0, // 차트의 ID
const string name="Edit", // 개체 이름
const string text="Text") // 텍스트
{
//--- 오류 값 재설정
ResetLastError();
//--- 개체 텍스트 변경
if(!ObjectSetString(chart_ID,name,OBJPROP_TEXT,text))
{
Print(__FUNCTION__,
": 텍스트 변경 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 편집 개체 텍스트 반환 |
//+------------------------------------------------------------------+
bool EditTextGet(string &text, // 텍스트
const long chart_ID=0, // 차트의 ID
const string name="Edit") // 개체 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 개체 텍스트 가져오기
if(!ObjectGetString(chart_ID,name,OBJPROP_TEXT,0,text))
{
Print(__FUNCTION__,
": 텍스트 가져오기 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 편집 개체 삭제 |
//+------------------------------------------------------------------+
bool EditDelete(const long chart_ID=0, // 차트의 ID
const string name="Edit") // 개체 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 레이블 삭제
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": \"편집\" 개체 삭제 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 차트 창 크기
long x_distance;
long y_distance;
//--- 창 크기 설정
if(!ChartGetInteger(0,CHART_WIDTH_IN_PIXELS,0,x_distance))
{
Print("차트 너비 가져오기 실패! Error code = ",GetLastError());
return;
}
if(!ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS,0,y_distance))
{
Print("차트 높이 가져오기 실패! Error code = ",GetLastError());
return;
}
//--- 편집 필드 변경 단계 지정
int x_step=(int)x_distance/64;
//--- 편집 필드 좌표 및 해당 크기 설정
int x=(int)x_distance/8;
int y=(int)y_distance/2;
int x_size=(int)x_distance/8;
int y_size=InpFontSize*2;
//--- 텍스트를 로컬 변수에 저장
string text=InpText;
//--- 편집 필드 생성
if(!EditCreate(0,InpName,0,x,y,x_size,y_size,InpText,InpFont,InpFontSize,InpAlign,InpReadOnly,
InpCorner,InpColor,InpBackColor,InpBorderColor,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- 차트를 다시 그리고 1초 동안 대기
ChartRedraw();
Sleep(1000);
//--- 편집 필드를 늘이기
while(x_size-x<x_distance*5/8)
{
//--- 편집 필드의 너비 증가
x_size+=x_step;
if(!EditChangeSize(0,InpName,x_size,y_size))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트를 다시 그리고 0.05 초 대기
ChartRedraw();
Sleep(50);
}
//--- 0.5초 지연
Sleep(500);
//--- 텍스트 변경
for(int i=0;i<20;i++)
{
//--- 시작과 끝에 "+"를 추가
text="+"+text+"+";
if(!EditTextChange(0,InpName,text))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트를 다시 그리고 0.1초 대기
ChartRedraw();
Sleep(100);
}
//--- 0.5초 지연
Sleep(500);
//--- 편집 필드 삭제
EditDelete(0,InpName);
ChartRedraw();
//--- 1초 동안 대기
Sleep(1000);
//---
}
|
