//--- 설명
#property description "스크립트는 차트에 우측 가격 레이블을 생성합니다."
#property description "고정점 좌표가 설정됨"
#property description "차트 창 크기의 백분율"
//--- 스크립트 실행 중 입력 매개변수의 표시 창
#property script_show_inputs
//--- 스크립트의 입력 매개변수
input string InpName="RightPrice"; // 가격 레이블 이름
input int InpDate=0; // 고정점 날짜(%)
input int InpPrice=90; // 고정점 가격(%)
input color InpColor=clrRed; // 가격 레이블 색상
input ENUM_LINE_STYLE InpStyle=STYLE_SOLID; // 테두리 선 스타일
input int InpWidth=2; // 가격 레이블 크기
input bool InpBack=false; // 배경 레이블
input bool InpSelection=true; // 이동하려면 강조 표시
input bool InpHidden=true; // 개체 목록에 숨겨짐
input long InpZOrder=0; // 마우스 클릭 우선 순위
//+------------------------------------------------------------------+
//| 우측 가격 레이블 생성 |
//+------------------------------------------------------------------+
bool ArrowRightPriceCreate(const long chart_ID=0, // 차트의 ID
const string name="RightPrice", // 가격 레이블 이름
const int sub_window=0, // 하위 창 인덱스
datetime time=0, // 고정점 시간
double price=0, // 고정점 가격
const color clr=clrRed, // 가격 레이블 색상
const ENUM_LINE_STYLE style=STYLE_SOLID, // 테두리 선 스타일
const int width=1, // 가격 레이블 크기
const bool back=false, // 배경에
const bool selection=true, // 이동하려면 강조 표시
const bool hidden=true, // 개체 목록에 숨겨짐
const long z_order=0) // 마우스 클릭 우선 순위
{
//--- 고정점 좌표를 설정하지 않은 경우
ChangeArrowEmptyPoint(time,price);
//--- 오류 값 재설정
ResetLastError();
//--- 가격 레이블 생성
if(!ObjectCreate(chart_ID,name,OBJ_ARROW_RIGHT_PRICE,sub_window,time,price))
{
Print(__FUNCTION__,
": 우측 가격 레이블 생성 실패! Error code = ",GetLastError());
return(false);
}
//--- 레이블 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 테두리 선 스타일 설정
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 레이블 크기 설정
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 전경(false) 또는 배경(true)에 표시
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 마우스를 사용하여 레이블 이동 모드 활성화(true) 또는 비활성화(false)
//--- ObjectCreate 함수를 사용하여 그래픽 개체를 만드는 경우 개체는
//--- 기본적으로 강조 표시되고 이동됩니다. 이 메서드 내에서 선택 매개변수
//--- 기본적으로 true이므로 개체를 강조 표시하고 이동할 수 있습니다.
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 개체 목록에서 그래픽 개체 이름 숨기기(true) 또는 표시(false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 차트에서 마우스 클릭 이벤트 수신 우선 순위 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 고정점 이동 |
//+------------------------------------------------------------------+
bool ArrowRightPriceMove(const long chart_ID=0, // 차트의 ID
const string name="RightPrice", // 레이블 이름
datetime time=0, // 고정점 시간 좌표
double price=0) // 고정점 가격 좌표
{
//--- 포인트 위치가 설정되지 않은 겨우 입찰 가격이 있는 현재 막대로 이동합니다
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 오류 값 재설정
ResetLastError();
//--- 고정점 이동
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": 고정점 이동 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 차트에서 우측 가격 레이블 삭제 |
//+------------------------------------------------------------------+
bool ArrowRightPriceDelete(const long chart_ID=0, // 차트의 ID
const string name="RightPrice") // 레이블 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 레이블 삭제
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": 우측 가격 레이블 삭제 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 고정점 값 확인 및 기본값 설정 |
//| 빈 곳의 경우 |
//+------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
{
//--- 점의 시간이 설정되지 않은 경우 현재 막대에 표시됩니다
if(!time)
time=TimeCurrent();
//--- 포인트 가격이 설정되지 않은 경우 입찰 값을 갖습니다
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 입력 매개변수의 정확성 확인
if(InpDate<0 || InpDate>100 || InpPrice<0 || InpPrice>100)
{
Print("오류! 입력 매개변수의 잘못된 값!");
return;
}
//--- 차트 창에 표시되는 막대 수
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 가격 배열 크기
int accuracy=1000;
//--- 사용할 날짜 및 가격 값을 저장하기 위한 배열
//--- 레이블 고정점 좌표 설정 및 변경
datetime date[];
double price[];
//--- 메모리 할당
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- 날짜 배열 채우기
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("시간 값 복사 실패! Error code = ",GetLastError());
return;
}
//--- 가격 배열 채우기
//--- 차트의 최고값과 최저값을 찾기
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 가격의 변경 단계를 정의 하고 배열 채우기
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- 레이블 그리기에 대한 점 정의
int d=InpDate*(bars-1)/100;
int p=InpPrice*(accuracy-1)/100;
//--- 차트에 우측 가격 레이블 생성
if(!ArrowRightPriceCreate(0,InpName,0,date[d],price[p],InpColor,
InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- 차트를 다시 그리고 1초 동안 대기
ChartRedraw();
Sleep(1000);
//--- 이제 고정점을 움직입니다
//--- 루프 카운터
int v_steps=accuracy*4/5;
//--- 고정점 이동
for(int i=0;i<v_steps;i++)
{
//--- 다음의 값 사용
if(p>1)
p-=1;
//--- 점 이동
if(!ArrowRightPriceMove(0,InpName,date[d],price[p]))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
}
//--- 1초 지연
Sleep(1000);
//--- 차트에서 레이블 삭제
ArrowRightPriceDelete(0,InpName);
ChartRedraw();
//--- 1초 지연
Sleep(1000);
//---
}
|
