//--- 説明
#property description "Script draws \"Thumbs Up\" sign."
#property description "Anchor point coordinate is set in percentage of"
#property description "the chart window size."
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- スクリプト入力パラメータ
input string InpName="ThumbUp"; // 記号名
input int InpDate=75; // アンカーポイントの日付（ % ）
input int InpPrice=25; // アンカーポイントの価格（ % ）
input ENUM_ARROW_ANCHOR InpAnchor=ANCHOR_TOP; // アンカーの種類
input color InpColor=clrRed; // 記号の色
input ENUM_LINE_STYLE InpStyle=STYLE_DOT; // 境界線のスタイル
input int InpWidth=5; // 記号サイズ
input bool InpBack=false; // 背景の記号
input bool InpSelection=true; // 強調表示して移動
input bool InpHidden=true; // オブジェクトリストに隠す
input long InpZOrder=0; // マウスクリックの優先順位
//+------------------------------------------------------------------+
//| サムズアップ記号を作成する |
//+------------------------------------------------------------------+
bool ArrowThumbUpCreate(const long chart_ID=0, // チャート識別子
const string name="ThumbUp", // 記号名
const int sub_window=0, // サブウィンドウ番号
datetime time=0, // アンカーポイントの時刻
double price=0, // アンカーポイントの価格
const ENUM_ARROW_ANCHOR anchor=ANCHOR_BOTTOM, // アンカーの種類
const color clr=clrRed, // 記号の色
const ENUM_LINE_STYLE style=STYLE_SOLID, // 境界線のスタイル
const int width=3, // 記号サイズ
const bool back=false, // 背景で表示する
const bool selection=true, // 強調表示して移動
const bool hidden=true, // オブジェクトリストに隠す
const long z_order=0) // マウスクリックの優先順位
{
//--- 設定されてない場合アンカーポイントの座標を設定する
ChangeArrowEmptyPoint(time,price);
//--- エラー値をリセットする
ResetLastError();
//--- 記号を作成する
if(!ObjectCreate(chart_ID,name,OBJ_ARROW_THUMB_UP,sub_window,time,price))
{
Print(__FUNCTION__,
": failed to create \"Thumbs Up\" sign! Error code = ",GetLastError());
return(false);
}
//--- アンカーの種類を設定
ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor);
//--- 記号の色を設定
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 境界線のスタイルを設定
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 記号のサイズを設定
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 前景（false）または背景（true）に表示
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- マウスで記号を移動させるモードを有効（true）か無効（false）にする
//--- ObjectCreate 関数を使用してグラフィックオブジェクトを作成する際、オブジェクトは
//--- デフォルトではハイライトされたり動かされたり出来ない。このメソッド内では、選択パラメータは
//--- デフォルトでは true でハイライトと移動を可能にする。
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- オブジェクトリストのグラフィックオブジェクトを非表示（true）か表示（false）にする
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- チャートのマウスクリックのイベントを受信するための優先順位を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| アンカーポイントを移動する |
//+------------------------------------------------------------------+
bool ArrowThumbUpMove(const long chart_ID=0, // チャート識別子
const string name="ThumbUp", // オブジェクト名
datetime time=0, // アンカーポイントの時間座標
double price=0) // アンカーポイントの価格座標
{
//--- ポイントの位置が設定されていない場合、売値を有する現在足に移動する
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- エラー値をリセットする
ResetLastError();
//--- アンカーポイントを移動する
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": failed to move the anchor point! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| サムズアップ記号のアンカーの種類を変更する |
//+------------------------------------------------------------------+
bool ArrowThumbUpAnchorChange(const long chart_ID=0, // チャート識別子
const string name="ThumbUp", // オブジェクト名
const ENUM_ARROW_ANCHOR anchor=ANCHOR_TOP) // アンカーの種類
{
//--- エラー値をリセットする
ResetLastError();
//--- アンカーの種類を変更する
if(!ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,anchor))
{
Print(__FUNCTION__,
": failed to change anchor type! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| サムズアップ記号を削除する |
//+------------------------------------------------------------------+
bool ArrowThumbUpDelete(const long chart_ID=0, // チャート識別子
const string name="ThumbUp") // 記号名
{
//--- エラー値をリセットする
ResetLastError();
//--- 記号を削除する
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": failed to delete \"Thumbs Up\" sign! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| アンカーポイントの値をチェックして |
//| 空の物には初期値を設定する |
//+------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
{
//--- ポイントの時間が設定されていない場合、現在足になる
if(!time)
time=TimeCurrent();
//--- ポイントの価格が設定されていない場合、売値になる
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 入力パラメータの正しさをチェックする
if(InpDate<0 || InpDate>100 || InpPrice<0 || InpPrice>100)
{
Print("Error! Incorrect values of input parameters!");
return;
}
//--- チャートウィンドウで表示されているバーの数
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 価格配列サイズ
int accuracy=1000;
//--- アンカーポイントの座標の設定と変更に使用される日付と
//--- 価格の値を格納するための配列
datetime date[];
double price[];
//--- メモリ割り当て
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- 日付配列に書き込む
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Failed to copy time values! Error code = ",GetLastError());
return;
}
//--- 価格配列に書き込む
//--- チャートの最高値と最安値を見つける
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 価格の変更ステップを定義し、配列に書き込む
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- 記号描画のポイントを定義する
int d=InpDate*(bars-1)/100;
int p=InpPrice*(accuracy-1)/100;
//--- チャート上にサムズアップ記号を作成する
if(!ArrowThumbUpCreate(0,InpName,0,date[d],price[p],InpAnchor,InpColor,
InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- チャートを再描画して 1 秒待つ
ChartRedraw();
Sleep(1000);
//--- アンカーポイントを移動し、記号との相互位置を変更する
//--- ループカウンタ
int h_steps=bars/4;
//--- アンカーポイントを移動する
for(int i=0;i<h_steps;i++)
{
//--- 次の値を使用する
if(d>1)
d-=1;
//--- ポイントを移動する
if(!ArrowThumbUpMove(0,InpName,date[d],price[p]))
return;
//--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
if(IsStopped())
return;
//--- チャートを再描画する
ChartRedraw();
// 0.05 秒の遅れ
Sleep(50);
}
//--- 1 秒の遅れ
Sleep(1000);
//--- ループカウンタ
int v_steps=accuracy/4;
//--- アンカーポイントを移動する
for(int i=0;i<v_steps;i++)
{
//--- 次の値を使用する
if(p<accuracy-1)
p+=1;
//--- ポイントを移動する
if(!ArrowThumbUpMove(0,InpName,date[d],price[p]))
return;
//--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
if(IsStopped())
return;
//--- チャートを再描画する
ChartRedraw();
}
//--- 記号に相対したアンカーポイントの位置関係を変更する
ArrowThumbUpAnchorChange(0,InpName,ANCHOR_BOTTOM);
//--- チャートを再描画する
ChartRedraw();
//--- 1 秒の遅れ
Sleep(1000);
//--- チャートから記号を削除する
ArrowThumbUpDelete(0,InpName);
ChartRedraw();
//--- 1 秒の遅れ
Sleep(1000);
//---
}
|
