//--- 説明
#property description "Script draws \"Sell\" signs in the chart window."
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- スクリプト入力パラメータ
input color InpColor=C'225,68,29'; // 記号の色
//+------------------------------------------------------------------+
//| 売りサインを作成する |
//+------------------------------------------------------------------+
bool ArrowSellCreate(const long chart_ID=0, // チャート識別子
const string name="ArrowSell", // 記号名
const int sub_window=0, // サブウィンドウ番号
datetime time=0, // アンカーポイントの時刻
double price=0, // アンカーポイントの価格
const color clr=C'225,68,29', // 記号の色
const ENUM_LINE_STYLE style=STYLE_SOLID, // 強調表示時の線のスタイル
const int width=1, // 強調表示時の線のサイズ
const bool back=false, // 背景で表示する
const bool selection=false, // 強調表示して移動
const bool hidden=true, // オブジェクトリストに隠す
const long z_order=0) // マウスクリックの優先順位
{
//--- 設定されてない場合アンカーポイントの座標を設定する
ChangeArrowEmptyPoint(time,price);
//--- エラー値をリセットする
ResetLastError();
//--- 記号を作成する
if(!ObjectCreate(chart_ID,name,OBJ_ARROW_SELL,sub_window,time,price))
{
Print(__FUNCTION__,
": failed to create \"Sell\" sign! Error code = ",GetLastError());
return(false);
}
//--- 記号の色を設定
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 強調表示時の線のスタイルを設定
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 強調表示時の線のサイズを設定
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 前景(false)または背景(true)に表示
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- マウスで記号を移動させるモードを有効(true)か無効(false)にする
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- オブジェクトリストのグラフィックオブジェクトを非表示(true)か表示(false)にする
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- チャートのマウスクリックのイベントを受信するための優先順位を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| アンカーポイントを移動する |
//+------------------------------------------------------------------+
bool ArrowSellMove(const long chart_ID=0, // チャート識別子
const string name="ArrowSell", // オブジェクト名
datetime time=0, // アンカーポイントの時間座標
double price=0) // アンカーポイントの価格座標
{
//--- ポイントの位置が設定されていない場合、売値を有する現在足に移動する
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- エラー値をリセットする
ResetLastError();
//--- アンカーポイントを移動する
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": failed to move the anchor point! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| 売りサインを作成する |
//+------------------------------------------------------------------+
bool ArrowSellDelete(const long chart_ID=0, // チャート識別子
const string name="ArrowSell") // 記号名
{
//--- エラー値をリセットする
ResetLastError();
//--- 記号を削除する
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": failed to delete \"Sell\" sign! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| アンカーポイントの値をチェックして |
//| 空の物には初期値を設定する |
//+------------------------------------------------------------------+
void ChangeArrowEmptyPoint(datetime &time,double &price)
{
//--- ポイントの時間が設定されていない場合、現在足になる
if(!time)
time=TimeCurrent();
//--- ポイントの価格が設定されていない場合、売値になる
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数 |
//+------------------------------------------------------------------+
void OnStart()
{
datetime date[]; // 表示中のバーの日付を格納するための配列
double low[]; // 表示中の足の安値を格納するための配列
double high[]; // 表示中の足の高値を格納するための配列
//--- チャートウィンドウで表示されているバーの数
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- メモリ割り当て
ArrayResize(date,bars);
ArrayResize(low,bars);
ArrayResize(high,bars);
//--- 日付配列に書き込む
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Failed to copy time values! Error code = ",GetLastError());
return;
}
//--- 安値の配列に書き込む
if(CopyLow(Symbol(),Period(),0,bars,low)==-1)
{
Print("Failed to copy the values of Low prices! Error code = ",GetLastError());
return;
}
//--- 高値の配列に書き込む
if(CopyHigh(Symbol(),Period(),0,bars,high)==-1)
{
Print("Failed to copy the values of High prices! Error code = ",GetLastError());
return;
}
//--- 表示された各足の高ポイントで売り記号を作成する
for(int i=0;i<bars;i++)
{
if(!ArrowSellCreate(0,"ArrowSell_"+(string)i,0,date[i],high[i],InpColor))
return;
//--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
if(IsStopped())
return;
//--- チャートを再描画する
ChartRedraw();
// 0.05 秒の遅れ
Sleep(50);
}
//--- 表示された各足の売り記号を低ポイントに移動する
for(int i=0;i<bars;i++)
{
if(!ArrowSellMove(0,"ArrowSell_"+(string)i,date[i],low[i]))
return;
//--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
if(IsStopped())
return;
//--- チャートを再描画する
ChartRedraw();
// 0.05 秒の遅れ
Sleep(50);
}
//--- 売りサインを削除する
for(int i=0;i<bars;i++)
{
if(!ArrowSellDelete(0,"ArrowSell_"+(string)i))
return;
//--- チャートを再描画する
ChartRedraw();
// 0.05 秒の遅れ
Sleep(50);
}
//---
}
|