Domande dai principianti MQL5 MT5 MetaTrader 5 - pagina 1111

[Vladimir Karputov]

Roman Sharanov:

Non è cambiato nulla, mostra ancora e+321

Non hai mostrato il codice completo. Non si sa che tipo di matrice sia e quanto sia grande, in cui si ottengono dati dall'indicatore.

[Roman Sharanov]

Ai sono stato molto stupido, ho fatto un errore stupido nell'inizializzazione ed è per questo che non ha funzionato tutto, grazie per l'aiuto

[fxsaber]

Vitaly Muzichenko:

Funziona, è la soluzione più semplice!

void OnStart()
{
  double d = 1.5;
  
  Print((long)d == d ? (string)(long)d : (string)d);
}

[Vladimir Karputov]

Roman Sharanov:

Ecco un esempio: copia tre elementi - dalla barra #0, dalla barra #1 e dalla barra #2 da tutti i buffer degli indicatori.

Stampa il valore della barra #0 da ogni buffer:

//+------------------------------------------------------------------+
//|                                           Simple Heiken_Ashi.mq5 |
//|                              Copyright © 2019, Vladimir Karputov |
//|                                           http://wmua.ru/slesar/ |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2019, Vladimir Karputov"
#property link      "http://wmua.ru/slesar/"
#property version   "1.000"
/*
   barabashkakvn Trading engine 3.025
*/
int    handle_iCustom;              // variable for storing the handle of the iCustom indicator 
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- create handle of the indicator iCustom
   handle_iCustom=iCustom(Symbol(),Period(),"Examples\\Heiken_Ashi");
//--- if the handle is not created 
   if(handle_iCustom==INVALID_HANDLE)
     {
      //--- tell about the failure and output the error code 
      PrintFormat("Failed to create handle of the iCustom indicator for the symbol %s/%s, error code %d",
                  Symbol(),
                  EnumToString(Period()),
                  GetLastError());
      //--- the indicator is stopped early 
      return(INIT_FAILED);
     }
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   double heiken_ashi_open[],heiken_ashi_high[],heiken_ashi_low[],heiken_ashi_close[];
   ArraySetAsSeries(heiken_ashi_open,true);
   ArraySetAsSeries(heiken_ashi_high,true);
   ArraySetAsSeries(heiken_ashi_low,true);
   ArraySetAsSeries(heiken_ashi_close,true);
   int start_pos=0,count=3;
   if(!iGetArray(handle_iCustom,0,start_pos,count,heiken_ashi_open) || 
      !iGetArray(handle_iCustom,1,start_pos,count,heiken_ashi_high) || 
      !iGetArray(handle_iCustom,2,start_pos,count,heiken_ashi_low) || 
      !iGetArray(handle_iCustom,3,start_pos,count,heiken_ashi_close))
     {
      return;
     }
   Comment(DoubleToString(heiken_ashi_open[0],Digits()),"\n",
           DoubleToString(heiken_ashi_high[0],Digits()),"\n",
           DoubleToString(heiken_ashi_low[0],Digits()),"\n",
           DoubleToString(heiken_ashi_close[0],Digits()));
  }
//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- 

  }
//+------------------------------------------------------------------+
//| Get value of buffers                                             |
//+------------------------------------------------------------------+
double iGetArray(const int handle,const int buffer,const int start_pos,
                 const int count,double &arr_buffer[])
  {
   bool result=true;
   if(!ArrayIsDynamic(arr_buffer))
     {
      Print("This a no dynamic array!");
      return(false);
     }
   ArrayFree(arr_buffer);
//--- reset error code 
   ResetLastError();
//--- fill a part of the iBands array with values from the indicator buffer
   int copied=CopyBuffer(handle,buffer,start_pos,count,arr_buffer);
   if(copied!=count)
     {
      //--- if the copying fails, tell the error code 
      PrintFormat("Failed to copy data from the indicator, error code %d",GetLastError());
      //--- quit with zero result - it means that the indicator is considered as not calculated 
      return(false);
     }
   return(result);
  }
//+------------------------------------------------------------------+

[Vitaly Muzichenko]

fxsaber:

È proprio quello che ti serve, molto "leggero". Grazie!

[yiduwi]

Per favore, ditemi il percorso della cartella condivisa per i terminali MT5

//--- открытие файла для записи, с флагом совестного пользования для чтения
   int han=FileOpen(subfolder+"\\experts\\files\\"+folder+".csv",FILE_WRITE|FILE_SHARE_READ|FILE_ANSI,",");
   if(han!=INVALID_HANDLE)// если файл открыт удачно
     {
      //ЗДЕСЬ ПРОЦЕДУРА ЗАПИСИ В ФАЙЛ
     }

[Artyom Trishkin]

yiduwi:

Per favore, ditemi il percorso della cartella condivisa per i terminali MT5

Il flag FILE_COMMON è responsabile della cartella condivisa di tutti i terminali client.

[Igor Makanu]

yiduwi:

Dimmi il percorso della cartella condivisa per i terminali MT5

Aggiungere FILE_COMMON

https://www.mql5.com/ru/docs/constants/io_constants/fileflags

trovare la cartella: nel terminale: file-open data directory - in Windows Explorer un livello sopra e sarà la cartella \Common\Files

[yiduwi]

Grazie

[Олег Юдин]

Buon pomeriggio, colleghi programmatori! Perdonami per la domanda più stupida, ma mi ha dato fastidio. Come viene eseguito il programma, o meglio come il terminale legge le linee, qual è la sequenza della loro esecuzione, o c'è qualche video per vedere e capire come avviene il tutto? perché imparare una lingua senza sapere come viene letta da un programma è difficile!!!!