Procedura guidata MQL5 - Segnali di trading basati su Dark Cloud Cover/Piercing Line + CCI - sistema esperto per MetaTrader 5

La procedura guidata MQL5 consente di creare Expert Advisor già pronti sulla base delle classi della libreria Standard fornite insieme al terminale client (vedere Creazione di Expert Advisor già pronti nella procedura guidata MQL5 per i dettagli). Consente di verificare rapidamente le tue idee di trading, tutto ciò di cui hai bisogno è creare la tua classe di segnali di trading. La struttura di questa classe ed esempio può essere trovata nell'articolo MQL5 Wizard: How to Create a Module of Trading Signals .

L'idea generica è la seguente: la classe dei segnali di trading è derivata da CExpertSignal , la successiva, è necessario sovrascrivere i metodi virtuali LongCondition() e ShortCondition() con i propri metodi.

C'è un libro "Strategie dei migliori trader " (in russo), ci sono molte strategie di trading che sono considerate lì, ci concentreremo sui modelli di candele di inversione, confermati dagli oscillatori Stochastic , CCI , MFI e RSI .

Il modo migliore è creare la classe separata, derivata da CExpertSignal per il controllo della formazione di pattern di candele. Per la conferma dei segnali di trading, generati da pattern candlestick, è sufficiente scrivere la classe, derivata da CCandlePattern e aggiungere lì le caratteristiche necessarie (ad esempio, conferma da oscillatori).

Qui prenderemo in considerazione i segnali, basati sul pattern di candele di inversione "Dark Cloud Cover/Piercing Line", confermati dall'indicatore CCI . Il modulo dei segnali di trading si basa sulla classe CCandlePattern , è un semplice esempio del suo utilizzo per la creazione di segnali di trading con pattern a candele.

1. Pattern di candele di inversione "Dark Cloud Cover" e "Piercing Line"

1.1. Dark Cloud Cover

È un'inversione ribassista della candela che si verifica alla fine del trend rialzista. Il primo giorno si forma una lunga candela bianca e il secondo giorno si crea un gap up. Tuttavia, il secondo giorno si chiude al di sotto della metà del primo giorno.

Fig. 1. Modello a candela "Dark Cloud Cover"

Il riconoscimento del pattern "Dark Cloud Cover" è implementato nel metodo CheckPatternDarkCloudCover() della classe CCandlePattern :

//+------------------------------------------------------------------+
//| Checks formation of "Dark Cloud Cover" candlestick pattern       |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternDarkCloudCover()
  {
//--- Dark Cloud Cover 
   if((Close(2)-Open(2)>AvgBody(1))  && // (long white)
      (Close(1)<Close(2))            && // 
      (Close(1)>Open(2))             && // (close within previous body)
      (MidOpenClose(2)>CloseAvg(1))  && // (uptrend)
      (Open(1)>High(2)))                // (open at new high)
      return(true);
//---
   return(false);
  }

1.2. Linea di piercing

Il gap down del secondo giorno perpetua il trend ribassista. Tuttavia, la chiusura del secondo giorno è al di sopra del punto medio del corpo del primo giorno. Questo suggerisce agli orsi che si potrebbe formare un minimo. Questa azione dei prezzi non è così distinguibile usando i grafici a barre come lo è con i grafici a candele. Maggiore è la penetrazione della chiusura del secondo giorno nel corpo del primo giorno, più è probabile che il segnale di inversione abbia successo.

Fig. 2. Modello a candela "Piercing Line"

Il riconoscimento del pattern "Piercing Line" è implementato nel metodo CheckPatternPiercingLine() della classe CCandlePattern :

//+------------------------------------------------------------------+
//| Checks formation of "Piercing Line" candlestick pattern          |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternPiercingLine()
  {
//--- Piercing Line
   if((Close(1)-Open(1)>AvgBody(1)) && // (long white)
      (Open(2)-Close(2)>AvgBody(1)) && // (long black)
      (Close(1)>Close(2))           && //  
      (Close(1)<Open(2))            && // (close inside previous body) 
      (MidOpenClose(2)<CloseAvg(2)) && // (downtrend)
      (Open(1)<Low(2)))                // (open lower than previous Low) 
      return(true);
//---
   return(false);
  }

2. Segnali di trading, confermati dall'indicatore CCI

I segnali di trading per aprire posizioni lunghe o corte devono essere confermati dall'indicatore CCI . Il valore del CCI deve essere maggiore/inferiore ai livelli critici (-50 per la posizione lunga e 50 per la posizione corta).

La chiusura della posizione aperta dipende dai valori di CCI. Si può fare in 2 casi:

1. se la linea CCI ha raggiunto il livello critico opposto (80 per la posizione lunga e -80 per la posizione corta)
2. se il segnale inverso non è confermato (quando il CCI raggiunge i seguenti livelli: -80 per posizione lunga e 80 per posizione corta)

Fig. 3. Modello "Dark Cloud Cover", confermato dall'indicatore CCI

• int CDC_PL_CCI::LongCondition() - verifica le condizioni per aprire la posizione lunga (restituisce 80) e chiudere la posizione corta (restituisce 40);
  
• int CDC_PL_CCI::ShortCondition() - verifica le condizioni per aprire la posizione corta (restituisce 80) e chiudere la posizione lunga (restituisce 40).

2.1. Aprire una posizione lunga/Chiudere una posizione corta

1. La formazione del pattern "Piercing Line" deve essere confermata dall'indicatore CCI : CCI(1)<-50 (il valore del CCI dell'ultima barra completata deve essere inferiore a -50).

2. La posizione corta deve essere chiusa se l' indicatore CCI ha superato al rialzo il livello critico -80 o al ribasso il livello critico 80.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CDC_PL_CCI::LongCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of Piercing Line pattern and CCI<-50
   if(CheckCandlestickPattern(CANDLE_PATTERN_PIERCING_LINE) && (CCI(1)<-50))
     result=80;
//--- checking of conditions to close short position
//--- signal line crossover of overbought/oversold levels (downward -80, downward -80)
   if(((CCI(1)>-80) && (CCI(2)<-80)) || ((CCI(1)<80) && (CCI(2)>80)))
     result=40;
//--- return result
   return(result);
  }

2.2. Aprire una posizione corta/Chiudere una posizione lunga

1. La formazione del pattern "Dark Cloud Cover" deve essere confermata dall'indicatore CCI : CCI(1)>50 (il valore dell'indicatore CCI dell'ultima barra completata deve essere maggiore di 50).

2. La posizione lunga deve essere chiusa se l' indicatore CCI ha attraversato al ribasso i livelli -80 o 80.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CDC_PL_CCI::ShortCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open short position
//--- formation of Dark Cloud Cover pattern and CCI>50
   if(CheckCandlestickPattern(CANDLE_PATTERN_DARK_CLOUD_COVER) && (CCI(1)>50))
     result=80;
//--- checking of conditions to close long position
//--- signal line crossover of overbought/oversold levels (downward -80, downward 80)
   if(((CCI(1)<80) && (CCI(2)>80)) || ((CCI(1)<-80) && (CCI(2)>-80)))
     result=40;
//--- return result
   return(result);
  }

2.3. Creazione di Expert Advisor utilizzando MQL5 Wizard

Per creare un Expert Advisor, avvia la procedura guidata MQL5 :

Fig. 4. Creazione di Expert Advisor utilizzando la procedura guidata MQL5

Specifichiamo il nome dell'Expert Advisor:

Fig. 5. Proprietà generali dell'Expert Advisor

Dopodiché dobbiamo selezionare i moduli dei segnali di trading utilizzati.

Fig. 6. Proprietà del segnale dell'Expert Advisor

Nel nostro caso utilizziamo solo un modulo di segnali di trading.

Aggiunta del modulo " Segnali basati su Dark Cloud Cover/Piercing Line confermato da CCI " dei segnali di trading:

Fig. 7. Proprietà del segnale dell'Expert Advisor

Modulo di segnali di trading aggiunto:

Fig. 8. Proprietà del segnale dell'Expert Advisor

Puoi selezionare qualsiasi proprietà di trascinamento, ma utilizzeremo "Trailing Stop non utilizzato":

Fig. 9. Proprietà di trascinamento dell'Expert Advisor

Per quanto riguarda le proprietà di gestione del capitale, utilizzeremo "Trading con volume di scambi fisso":

Fig. 10. Proprietà di gestione del capitale dell'Expert Advisor

Premendo il pulsante "Fine", otterremo il codice dell'Expert Advisor generato, che si trova in Expert_ADC_PL_CCI.mq5, verrà salvato in terminal_data_folder\MQL5\Experts\.

I parametri di input predefiniti dell'Expert Advisor generato:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0;   // Take Profit level (in points)

devono essere sostituiti con:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

I parametri di ingresso Signal_ThresholdOpen/Signal_ThresholdClose consentono di specificare i livelli di soglia per l'apertura e la chiusura delle posizioni.

Nel codice dei metodi LongCondition() e ShortCondition() della classe trade signal abbiamo specificato i valori fissi della soglia:

• Posizione aperta: 80;
• Posizione vicina: 40.
  

Il valore dei parametri di ingresso Signal_StopLevel e Signal_TakeLevel è impostato a 0, significa che la chiusura delle posizioni verrà eseguita solo quando le condizioni di chiusura saranno vere.

2.4. Risultati del backtest su dati storici

Si consideri il backtesting dell'Expert Advisor su dati storici (EURUSD H1, periodo di test: 2010.01.01-2011.03.16, 2010.01.01-2011.03.16, PeriodCCI=15, MA_period=19).

Nella creazione di Expert Advisor abbiamo utilizzato il volume fisso ( Trading Fixed Lot , 0.1), non viene utilizzato l'algoritmo Trailing Stop ( Trailing non utilizzato ).

Fig. 11. Risultati dei test dell'Expert Advisor, basati su Dark Cloud Cover/Piercing Line + CCI

Il miglior set di parametri di input può essere trovato utilizzando lo Strategy Tester del terminale client MetaTrader 5.

Il codice dell'Expert Advisor, creato da MQL5 Wizard è allegato in expert_adc_pl_cci.mq5.