Caractéristiques du langage mql5, subtilités et techniques

Nikolai Semko 2023.11.14 19:45 #2351

Une implémentation plus rapide de la fonction standard PeriodSeconds() :

int PeriodSecondsFast(ENUM_TIMEFRAMES tf) {
   return (tf>>14==0)?(tf&0x0FFF)*60:(tf>>14==1)?(tf&0x0FFF)*60*60:(tf>>14==2)?60*60*24*7:2419200;
}

fxsaber 2023.11.14 20:09 #2352

Nikolai Semko #:
Une implémentation plus rapide de la fonction standard PeriodSeconds() :

J'ai regardé le format.

template <typename T>
bool IsCorrect( const int Index )
{
  ResetLastError();
  
  return((EnumToString((T)Index) != NULL) && !_LastError);
}

template <typename T>
string ToBits( const T Value )
{
  string Str = NULL;
  
  for(uint i = sizeof(T) << 3; (bool)i--;)
    Str += (string)(int)(!!(Value & (1 << i)));
    
  return(Str);
}

void OnStart()
{
  for (int i = 0; i < 1 e7; i++)
    if (IsCorrect<ENUM_TIMEFRAMES>(i))
      Print(ToBits(i) + " - " + EnumToString((ENUM_TIMEFRAMES)i) + ", " + (string)i);
}

00000000000000000000000000000000 - PERIOD_CURRENT, 0
00000000000000000000000000000001 - PERIOD_M1, 1
00000000000000000000000000000010 - PERIOD_M2, 2
00000000000000000000000000000011 - PERIOD_M3, 3
00000000000000000000000000000100 - PERIOD_M4, 4
00000000000000000000000000000101 - PERIOD_M5, 5
00000000000000000000000000000110 - PERIOD_M6, 6
00000000000000000000000000001010 - PERIOD_M10, 10
00000000000000000000000000001100 - PERIOD_M12, 12
00000000000000000000000000001111 - PERIOD_M15, 15
00000000000000000000000000010100 - PERIOD_M20, 20
00000000000000000000000000011110 - PERIOD_M30, 30
00000000000000000100000000000001 - PERIOD_H1, 16385
00000000000000000100000000000010 - PERIOD_H2, 16386
00000000000000000100000000000011 - PERIOD_H3, 16387
00000000000000000100000000000100 - PERIOD_H4, 16388
00000000000000000100000000000110 - PERIOD_H6, 16390
00000000000000000100000000001000 - PERIOD_H8, 16392
00000000000000000100000000001100 - PERIOD_H12, 16396
00000000000000000100000000011000 - PERIOD_D1, 16408
00000000000000001000000000000001 - PERIOD_W1, 32769
00000000000000001100000000000001 - PERIOD_MN1, 49153

Probablement pas plus rapide. J'ai cependant entendu parler de la merveilleuse vitesse de switch.

int PeriodSecondsFast( const ENUM_TIMEFRAMES tf )
{
  switch (tf)
  {
    case PERIOD_CURRENT: return(PeriodSecondsFast(_Period));      
    case PERIOD_M1:      return(60);
    case PERIOD_M2:      return(120);
    case PERIOD_M3:      return(180);
    case PERIOD_M4:      return(240);
    case PERIOD_M5:      return(300);
    case PERIOD_M6:      return(360);
    case PERIOD_M10:     return(600);
    case PERIOD_M12:     return(720);
    case PERIOD_M15:     return(900);
    case PERIOD_M20:     return(1200);
    case PERIOD_M30:     return(1800);
    case PERIOD_H1:      return(3600);
    case PERIOD_H2:      return(7200);
    case PERIOD_H3:      return(10800);
    case PERIOD_H4:      return(14400);
    case PERIOD_H6:      return(21600);
    case PERIOD_H8:      return(28800);
    case PERIOD_H12:     return(43200);
    case PERIOD_D1:      return(86400);
    case PERIOD_W1:      return(604800);
    case PERIOD_MN1:     return(2592000);
  }
  
  return(0);
}

Nikolai Semko 2023.11.14 20:35 #2353

fxsaber #:

J'ai regardé le format.

Il ne l'accélérera probablement pas. Mais j'ai entendu parler de la vitesse miraculeuse du changement.

Il semble plus long, mais je n'ai pas remarqué de différence de performance.

int PeriodSecondsFast2(ENUM_TIMEFRAMES tf) {
   ushort i_tf= ushort(tf);
   uchar _i =uchar(i_tf>>14);
   int n = i_tf & 0x0FFF;
   switch(_i) {
   case 0: // минуты
      return n*60;
   case 1: // часы
      return n*60*60;
   case 2: // недели
      return 60*60*24*7;
   case 3: // месяцы
      return 2592000;
   }
   return -1;
}

Je pense donc qu'une version à une ligne est toujours préférable.

int PeriodSecondsFast(ENUM_TIMEFRAMES tf) {
   return (tf>>14==0)?(tf&0x0FFF)*60:(tf>>14==1)?(tf&0x0FFF)*60*60:(tf>>14==2)?60*60*24*7:60*60*24*30;
}

fxsaber 2023.11.14 20:43 #2354

Nikolai Semko #:

semble plus long

int PeriodSecondsFast( const ENUM_TIMEFRAMES tf )
{
  static const int Mult[] = {60, 60 * 60, 60 * 60 * 24 * 7, 60 * 60 * 24 * 30};
  
  return((tf & 0xFF) * Mult[tf >> 14]);
}

Maxim Kuznetsov 2023.11.14 20:44 #2355

et maintenant de convertir tout cela en matrices et en ONX :-)

Nikolai Semko 2023.11.14 20:59 #2356

fxsaber #:

Oui, c'est possible. Plus lisible.
La performance sur mon ordinateur portable est la même.

Nikolai Semko 2023.11.14 21:06 #2357

fxsaber #:

int PeriodSecondsFast( const ENUM_TIMEFRAMES tf )
{
  static const int Mult[] = {60, 60 * 60, 60 * 60 * 24 * 7, 60 * 60 * 24 * 30};
  
  return((tf & 0xFF) * Mult[tf >> 14]);
}

Au fait, je me suis trompé dans mes messages précédents. Pour une raison quelconque, je pensais qu'il y avait 28 jours dans un mois, et non 30. Je ne comprends pas d'où je tiens cela.
Je ne peux plus corriger mes messages qui datent de plus d'une heure.

Ma version correcte est donc la suivante :

int PeriodSecondsFast(ENUM_TIMEFRAMES tf) {
   return (tf>>14==0)?(tf&0xFF)*60:(tf>>14==1)?(tf&0xFF)*60*60:(tf>>14==2)?60*60*24*7:60*60*24*30;
}

Personne n'a besoin des secondes du mois, cependant, puisque les mois sont de longueur différente

[Toute question de débutant, Experts en moyennes mobiles Combien coûte la rédaction

Alain Verleyen 2023.11.15 03:29 #2358

Nikolai Semko # :

Au fait, je me suis trompé dans mes messages précédents. Pour une raison quelconque, je pensais qu'il y avait 28 jours dans un mois, et non 30. Je ne comprends pas où je me suis trompé.
Je ne peux pas corriger mes messages qui datent de plus d'une heure.

Ma version correcte est donc la suivante :

Personne n'a besoin des secondes du mois, cependant, puisque les mois sont de longueur différente

Qu'est-ce qui vous fait penser que c'est plus rapide que PeriodSeconds(x) ?

Nikolai Semko 2023.11.15 03:36 #2359

Alain Verleyen #:
Qu'est-ce qui vous fait penser que c'est plus rapide que PeriodSeconds(x) ?

le test de cet article

il suffit de comparer les performances de getStartTimeOfBar() avec PeriodSeconds() et avec PeriodSecondsFast()

La comparaison doit être faite sur n'importe quelle TF à l'exception de MN1

La performance est supérieure d'environ 2 fois. Peut-être 3 fois si l'on tient compte du fait que nous mesurons l'ensemble de l'itération.

ou suffit-il de comparer ces deux valeurs ?

2023.11.14 22:44:52.581 timeToStartMonth (EURUSD,M1)    =====LOOP=10000========STEPS=100000 seconds======PERIOD_H8========
2023.11.14 22:44:52.581 timeToStartMonth (EURUSD,M1)    контрольная сумма - 12000623961600, время выполнения 1 иттерации = 6.80 наносекунд - Расчет через структуру MqlDateTime
2023.11.14 22:44:52.581 timeToStartMonth (EURUSD,M1)    контрольная сумма - 12000623961600, время выполнения 1 иттерации = 3.40 наносекунд - Быстрый расчет
2023.11.14 22:44:57.734 timeToStartMonth (EURUSD,M1)    контрольная сумма - 12000252960000, время выполнения 1 иттерации = 515301.20 наносекунд - Расчет через iBarShift
2023.11.14 22:44:57.734 timeToStartMonth (EURUSD,M1)    ========================================================================
2023.11.14 22:45:16.253 timeToStartMonth (EURUSD,M1)    60 ,120 ,180 ,240 ,300 ,360 ,600 ,720 ,900 ,1200 ,1800 ,3600 ,7200 ,10800 ,14400 ,21600 ,28800 ,43200 ,86400 ,604800 ,2592000 ,
2023.11.14 22:45:16.253 timeToStartMonth (EURUSD,M1)    =====LOOP=10000========STEPS=100000 seconds======PERIOD_M4========
2023.11.14 22:45:16.253 timeToStartMonth (EURUSD,M1)    контрольная сумма - 12000769600080, время выполнения 1 иттерации = 3.70 наносекунд - Расчет через структуру MqlDateTime
2023.11.14 22:45:16.253 timeToStartMonth (EURUSD,M1)    контрольная сумма - 12000769600080, время выполнения 1 иттерации = 1.90 наносекунд - Быстрый расчет
2023.11.14 22:45:16.471 timeToStartMonth (EURUSD,M1)    контрольная сумма - 12000394543440, время выполнения 1 иттерации = 21746.60 наносекунд - Расчет через iBarShift
2023.11.14 22:45:16.471 timeToStartMonth (EURUSD,M1)    ========================================================================
2023.11.14 22:45:57.038 timeToStartMonth (EURUSD,M1)    60 ,120 ,180 ,240 ,300 ,360 ,600 ,720 ,900 ,1200 ,1800 ,3600 ,7200 ,10800 ,14400 ,21600 ,28800 ,43200 ,86400 ,604800 ,2592000 ,
2023.11.14 22:45:57.038 timeToStartMonth (EURUSD,M1)    =====LOOP=10000========STEPS=100000 seconds======PERIOD_H1========
2023.11.14 22:45:57.038 timeToStartMonth (EURUSD,M1)    контрольная сумма - 12000751999200, время выполнения 1 иттерации = 5.30 наносекунд - Расчет через структуру MqlDateTime
2023.11.14 22:45:57.038 timeToStartMonth (EURUSD,M1)    контрольная сумма - 12000751999200, время выполнения 1 иттерации = 3.00 наносекунд - Быстрый расчет
2023.11.14 22:45:57.072 timeToStartMonth (EURUSD,M1)    контрольная сумма - 12000378405600, время выполнения 1 иттерации = 3410.10 наносекунд - Расчет через iBarShift
2023.11.14 22:45:57.072 timeToStartMonth (EURUSD,M1)    ========================================================================

10points 3.mq4 Ce que rapportent les [ARCHIVE] Toute question de

Alain Verleyen 2023.11.15 04:40 #2360

Nikolai Semko # :

le test de cet article

il suffit de comparer le travail de getStartTimeOfBar() avec PeriodSeconds() et avec PeriodSecondsFast()

La comparaison doit être faite sur n'importe quelle TF sauf MN1

La performance est supérieure d'environ 2 fois. Peut-être 3 fois si l'on tient compte du fait que nous mesurons l'ensemble de l'itération.

ou suffit-il de comparer ces deux valeurs ?

J'ai peut-être oublié quelque chose, mais j'ai utilisé votre script pour vérifier PeriodSeconds (uniquement).

Dossiers :

__.mq5 13 kb

Caractéristiques du langage mql5, subtilités et techniques - page 236