Référence MQL5Bibliothèque StandardMathematiquesLogique floueFonctions d'appartenanceCProductTwoSigmoidalMembershipFunctions

CProductTwoSigmoidalMembershipFunction

Classe d'implémentation d'une fonction d'appartenance sous la forme d'un produit de deux fonctions sigmoïdes avec les paramètres А1, А2, С1 et С2.

Description

Le produit de deux fonctions d'appartenance sigmoïdes est appliqué pour définir les fonctions asymétriques lisses. Elle permet de créer des fonctions d'appartenance avec des valeurs égales à 1 commençant avec la valeur de l'argument. De telles fonctions conviennent si vous avez besoin de définir des termes linguistiques tels que "short" ou "long".

fuzzy_prodsigmoidal_function

Un extrait de code dessinant un graphique est affiché plus bas.

Déclaration

class CProductTwoSigmoidalMembershipFuncion : public IMembershipFunction

Titre

#include <Math\Fuzzy\membershipfunction.mqh>

Hiérarchie d'héritage

CObject

IMembershipFunction

CProductTwoSigmoidalMembershipFunctions

Méthodes de classe

Méthode de classe	Description
A1	Retourne et définit le rapport de la pente de la première fonction d'appartenance.
A2	Retourne et définit le rapport de la pente de la deuxième fonction d'appartenance.
C1	Retourne le paramètre de la coordonnée d'inflexion de la première fonction d'appartenance.
C2	Retourne le paramètre de coordonnée d'inflexion de la deuxième fonction d'appartenance.
GetValue	Calcule la valeur de la fonction d'appartenance d'un argument donné.

Méthodes héritées de la classe CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Exemple

//+------------------------------------------------------------------+
//|                       ProductTwoSigmoidalMembershipFunctions.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Crée les fonctions membres
CProductTwoSigmoidalMembershipFunctions func1(2,1,-1,7);
CProductTwoSigmoidalMembershipFunctions func2(2,2,-4,7);
CProductTwoSigmoidalMembershipFunctions func3(2,3,-8,7);
//--- Crée les wrappers des fonctions membres
double ProductTwoSigmoidalMembershipFunctions1(double x) { return(func1.GetValue(x)); }
double ProductTwoSigmoidalMembershipFunctions2(double x) { return(func2.GetValue(x)); }
double ProductTwoSigmoidalMembershipFunctions3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Fonction de lancement du script                                  |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- crée le graphique
   CGraphic graphic;
   if(!graphic.Create(0,"ProductTwoSigmoidalMembershipFunctions",0,30,30,780,380))
     {
      graphic.Attach(0,"ProductTwoSigmoidalMembershipFunctions");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("ProductTwoSigmoidalMembershipFunctions");
   graphic.BackgroundMainSize(16);
//--- crée une courbe
   graphic.CurveAdd(ProductTwoSigmoidalMembershipFunctions1,0.0,10.0,0.1,CURVE_LINES,"[2, 1, -1, 7]");
   graphic.CurveAdd(ProductTwoSigmoidalMembershipFunctions2,0.0,10.0,0.1,CURVE_LINES,"[2, 2, -4, 7]");
   graphic.CurveAdd(ProductTwoSigmoidalMembershipFunctions3,0.0,10.0,0.1,CURVE_LINES,"[2, 3, -8, 7]");
//--- définit les propriétés de l'axe X
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- définit les propriétés de l'axe Y
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- dessin
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue