DocumentationSections
Référence MQL5Bibliothèque StandardGraphiques ScientifiquesCAxisValuesFunctionFormat 

ValuesFunctionFormat (méthode Get)

Retourne un pointeur vers la fonction définissant le format d'affichage des valeurs sur l'axe.

DoubleToStringFunction  ValuesFunctionFormat()

Valeur de Retour

Pointeur vers la fonction définissant le format d'affichage des valeurs sur l'axe.

ValuesFunctionFormat (méthode Set)

Définit un pointeur vers la fonction définissant le format d'affichage des valeurs sur l'axe.

void  ValuesFunctionFormat(
   DoubleToStringFunction  func      // fonction pour convertir les valeurs numériques en chaînes de caractères
   )

Paramètres

func

[in]  Fonction personnalisée pour convertir les valeurs numériques en chaînes de caractères.

Exemple :

graphics_close

Le format d'affichage des valeurs de l'axe X a été changé avec le code suivant :

//+------------------------------------------------------------------+
//|                                              DateAxisGraphic.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Graphics\Graphic.mqh>
//--- tableau pour stocker les valeurs
double arrX[];
double arrY[];
//+------------------------------------------------------------------+
//| Fonction personnalisée pour créer les valeurs sur l'axe X        |
//+------------------------------------------------------------------+
string TimeFormat(double x,void *cbdata)
  {
   return(TimeToString((datetime)arrX[ArraySize(arrX)-(int)x-1]));
  }
//+------------------------------------------------------------------+
void OnStart()
  {
   MqlRates rates[];
   CopyRates(Symbol(),Period(),0,100,rates);
   ArraySetAsSeries(rates,true);
   int size=ArraySize(rates);
   ArrayResize(arrX,size);
   ArrayResize(arrY,size);
   for(int i=0; i<size;++i)
     {
      arrX[i]=(double)rates[i].time;
      arrY[i]=rates[i].close;
     }
//--- crée le graphique
   CGraphic graphic;
   if(!graphic.Create(0,"DateAxisGraphic",0,30,30,780,380))
     {
      graphic.Attach(0,"DateAxisGraphic");
     }
//--- crée la courbe
   CCurve *curve=graphic.CurveAdd(arrY,CURVE_LINES);
//--- récupère l'axe X
   CAxis *xAxis=graphic.XAxis();
//--- définit les propriétés de l'axe X
   xAxis.AutoScale(false);
   xAxis.Type(AXIS_TYPE_CUSTOM);
   xAxis.ValuesFunctionFormat(TimeFormat);
   xAxis.DefaultStep(20.0);
//--- dessin 
   graphic.CurvePlotAll();
   graphic.Update();
  }