DocumentationSections
Référence MQL5Information du MarchéSymbolSelect 

SymbolSelect

Choisit le symbole dans la fenêtre du Market Watch, ou enlève le symbole de la fenêtre.

bool  SymbolSelect(
   string  name,       // nom du symbole
   bool    select      // sélection ou suppression
   );

Paramètres

name

[in]  Le nom du symbole.

select

[in] La valeur de ce que l'on souhaite faire. Si false, le symbole doit être supprimé de la fenêtre du Market Watch. Dans le cas contraire, le symbole doit être sélectionné et ajouté dans la fenêtre du Market Watch. Le symbole ne peut pas être supprimé s'il y a des graphiques ouverts avec ce symbole, ou s'il y a des positions ouvertes sur ce symbole.

Valeur de retour

Retourne false en cas d'échec.

Exemple :

#define SYMBOL_NAME "GBPHKD"
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- vérifie la présence d'un symbole dans les listes. S'il n'est pas trouvé, on l'indique et le programme est terminé
   bool custom = false;
   if(!SymbolExist(SYMBOL_NAME, custom))
     {
      PrintFormat("'%s' symbol not found in the lists", SYMBOL_NAME);
      return;
     }
     
//--- ajoute le symbole dans la fenêtre du Market Watch
   ResetLastError();
   if(!SymbolSelect(SYMBOL_NAME, true))
     {
      Print("SymbolSelect() failed. Error ", GetLastError());
      return;
     }
//--- si le symbole est ajouté à la liste avec succès, obtient son indice dans la fenêtre du Market Watch et envoie le résultat dans le journal
   int index = SymbolIndex(SYMBOL_NAME);
   PrintFormat("The '%s' symbol has been added to the MarketWatch list. Symbol index in the list: %d", SYMBOL_NAME, index);
     
//--- supprime maintenant le symbole de la fenêtre du Market Watch
   ResetLastError();
   if(!SymbolSelect(SYMBOL_NAME, false))
     {
      Print("SymbolSelect() failed. Error ", GetLastError());
      return;
     }
//--- si le symbole est supprimé avec succès de la liste, son indice dans la fenêtre du Market Watch est -1, envoie le résultat de la suppression dans le journal
   index = SymbolIndex(SYMBOL_NAME);
   PrintFormat("The '%s' symbol has been removed from the MarketWatch list. Symbol index in the list: %d", SYMBOL_NAME, index);
   
   /*
   résultat :
   The 'GBPHKD' symbol has been added to the MarketWatch list. Symbol index in the list: 12
   The 'GBPHKD' symbol has been removed from the MarketWatch list. Symbol index in the list: -1
   */
  }
//+------------------------------------------------------------------+
//| Retourne l'indice du symbole dans la liste du Market Watch      |
//+------------------------------------------------------------------+
int SymbolIndex(const string symbol)
  {
   int total = SymbolsTotal(true);
   for(int i=0; i<total; i++)
     {
      string name = SymbolName(i, true);
      if(name == symbol)
         return i;
     }
   return(WRONG_VALUE);
  }